Query per la tabella ACSCallRecordingSummary

Articolo
11/05/2024

Per informazioni sull'uso di queste query nella portale di Azure, vedere Esercitazione su Log Analytics. Per l'API REST, vedere Query.

Istogramma durata registrazione chiamata

Produce un istogramma di durate di registrazione delle chiamate in secondi.

ACSCallRecordingSummary
| distinct RecordingId, RecordingLength
// Count call duration bins (60 second intervals)
| summarize duration_counts=count() by bin(RecordingLength, 6000)
| order by RecordingLength asc
| render columnchart with (xcolumn = RecordingLength, title="Recording duration histogram")

Percentili della durata della registrazione delle chiamate

Calcola la durata media della registrazione delle chiamate in secondi, nonché i percentili di durata delle chiamate del 50%, del 90% e del 99%.

ACSCallRecordingSummary
// Get the distinct combinations of RecordingId, RecordingLength
| distinct RecordingId, RecordingLength
// Calculate average and percentiles (50%, 90%, and 99%) of call durations (in seconds)
| summarize avg(RecordingLength), percentiles(RecordingLength, 50, 90, 99)

Rapporto di fine della registrazione delle chiamate

Produce un grafico a torta della percentuale di motivo finale della registrazione delle chiamate.

ACSCallRecordingSummary
// Count distinct calls (dcount(CorrelationId)) per call type
| summarize call_types=dcount(RecordingId) by RecordingEndReason
| render piechart title="Recording End Reason Ratio"

Registrazioni di chiamate giornaliere

Produce un istogramma di registrazioni effettuate al giorno nell'ultima settimana.

ACSCallRecordingSummary
// To filter out recordings made over a week ago, uncomment the next line
// | where TimeGenerated > ago(7d)
// Get the distinct combinations of RecordingId and CallStartTime
| distinct RecordingId, TimeGenerated
// Adds a new column with the call start day
| extend day = floor(TimeGenerated, 1d)
// Count the number of calls per day
| summarize event_count=count() by day
| sort by day asc
| render columnchart title="Number of recordings per day"

Registrazioni di chiamate orarie

Produce un istogramma di registrazioni effettuate all'ora nell'ultimo giorno.

    ACSCallRecordingSummary
    // To filter out recordings made over a day ago, uncomment the next line
    | where TimeGenerated > ago(1d)
    // Get the distinct combinations of RecordingId and TimeGenerated
    | distinct RecordingId, TimeGenerated
    // Adds a new column with the call start hour
    | extend hour = floor(TimeGenerated, 1h)
    // Count the number of calls per hour
    | summarize event_count=count() by hour
    | sort by hour asc
    | render columnchart title="Number of recordings per hour in last day"

Rapporto modalità registrazione chiamata

Produce un grafico a torta della proporzione di modalità di registrazione (tipi di contenuto/formato).

ACSCallRecordingSummary
| summarize count() by ContentType, FormatType
| extend ContentFormat = strcat(ContentType, "/", FormatType)
| project ContentFormat, count_
| render piechart title="Recording by mode (content/format types)"

Condividi tramite