IteratorStateMachineAttribute Classe

Definizione

public ref class IteratorStateMachineAttribute sealed : System::Runtime::CompilerServices::StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
[System.Serializable]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
[<System.Serializable>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

Public NotInheritable Class IteratorStateMachineAttribute
Inherits StateMachineAttribute

Ereditarietà

Object

Attribute

StateMachineAttribute

IteratorStateMachineAttribute

Attributi

AttributeUsageAttribute SerializableAttribute

Esempio

Nell'esempio seguente viene illustrato come determinare se un metodo è un metodo iteratore. Nell'esempio viene IsIteratorMethod eseguita la procedura seguente:

• Ottiene un MethodInfo oggetto per il nome del metodo usando Type.GetMethod.

• Ottiene un Type oggetto per l'attributo usando GetType Operator.

• Ottiene un oggetto attributo per il metodo e il tipo di attributo usando MethodInfo.GetCustomAttribute. Se GetCustomAttribute restituisce Nothing (Visual Basic), il metodo non contiene l'attributo.

Imports System.Collections.Generic
Imports System.Reflection
Imports System.Threading.Tasks
Imports System.Runtime.CompilerServices


Module Module1

    ' This class is used by the code below to discover method attributes.
    Public Class TheClass
        Public Async Function AsyncMethod() As Task(Of Integer)
            Await Task.Delay(5)
            Return 1
        End Function

        Public Iterator Function IteratorMethod() As IEnumerable(Of Integer)
            Yield 1
            Yield 2
        End Function

        Public Function RegularMethod() As Integer
            Return 0
        End Function
    End Class


    Private Function IsAsyncMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(AsyncStateMachineAttribute)

        Dim attrib = CType(method.GetCustomAttribute(attType), AsyncStateMachineAttribute)
        ' The above variable contains the StateMachineType property.

        Return (attrib IsNot Nothing)
    End Function

    Private Function IsIteratorMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(IteratorStateMachineAttribute)

        ' Obtain the custom attribute for the method.
        ' The value returned contains the StateMachineType property.
        ' Nothing is returned if the attribute isn't present for the method.
        Dim attrib = CType(method.GetCustomAttribute(attType), IteratorStateMachineAttribute)

        Return (attrib IsNot Nothing)
    End Function

    Private Sub ShowResult(classType As Type, methodName As String)
        Console.Write((methodName & ": ").PadRight(16))

        If IsAsyncMethod(classType, methodName) Then
            Console.WriteLine("Async method")
        ElseIf IsIteratorMethod(classType, methodName) Then
            Console.WriteLine("Iterator method")
        Else
            Console.WriteLine("Regular method")
        End If

        ' Note: The IteratorStateMachineAttribute applies to Visual Basic methods
        ' but not C# methods.
    End Sub

    Sub Main()
        ShowResult(GetType(TheClass), "AsyncMethod")
        ShowResult(GetType(TheClass), "IteratorMethod")
        ShowResult(GetType(TheClass), "RegularMethod")

        Console.ReadKey()
    End Sub

    '   AsyncMethod:    Async method
    '   IteratorMethod: Iterator method
    '   RegularMethod:  Regular method

End Module

Commenti

Non è consigliabile applicare l'attributo IteratorStateMachine ai metodi nel codice. Per i metodi in Visual Basic che dispongono del modificatore Iterator , il compilatore applicherà l'attributo IteratorStateMachine nell'istanza di IL che genera.

Quando un metodo (MethodName) in Visual Basic ha il Iterator modificatore, il compilatore genera IL che include una struttura di computer a stato. Tale struttura contiene il codice nel metodo . Il SERVIZIO contiene anche un metodo stub (MethodName) che chiama nel computer di stato. Il compilatore aggiunge l'attributo IteratorStateMachine al metodo stub in modo che gli strumenti possano identificare il computer di stato corrispondente. I dettagli dell'emesso IL potrebbero cambiare nelle versioni future dei compilatori.

Un metodo iteratore esegue un'iterazione personalizzata su una raccolta usando l'istruzione Yield (Visual Basic) per restituire ogni elemento una alla volta. Per altre informazioni, vedere Iteratori.

Costruttori

Proprietà

Metodi

Implementazioni dell'interfaccia esplicita

Si applica a

Vedi anche

• AsyncStateMachineAttribute
• StateMachineType