?. e ?() - Operatori condizionali Null (Visual Basic)
Testa il valore dell'operando sul lato sinistro per i valori Null (Nothing) prima di eseguire un accesso ai membri (?.) o un'operazione (?()) di indicizzazione; restituisce Nothing se l'operando sul lato sinistro restituisce Nothing. Si noti che nelle espressioni che restituiscono in genere tipi di valore, l'operatore condizionale Null restituisce un oggetto Nullable<T>.
Questi operatori consentono di scrivere meno codice per gestire i controlli null, soprattutto per l'ordinamento decrescente delle strutture di dati. Ad esempio:
' Nothing if customers is Nothing
Dim length As Integer? = customers?.Length
' Nothing if customers is Nothing
Dim first As Customer = customers?(0)
' Nothing if customers, the first customer, or Orders is Nothing
Dim count As Integer? = customers?(0)?.Orders?.Count()
Per il confronto, il codice alternativo per la prima di queste espressioni senza un operatore condizionale Null è:
Dim length As Integer?
If customers IsNot Nothing Then
length = customers.Length
Else
length = Nothing
End If
A volte è necessario eseguire un'azione su un oggetto che può essere Null, in base al valore di un membro booleano su tale oggetto (ad esempio la proprietà booleana IsAllowedFreeShipping nell'esempio seguente):
Dim customer = FindCustomerByID(123) 'customer will be Nothing if not found.
If customer IsNot Nothing AndAlso customer.IsAllowedFreeShipping Then
ApplyFreeShippingToOrders(customer)
End If
È possibile abbreviare il codice ed evitare di verificare manualmente la presenza di valori Null usando l'operatore condizionale Null come indicato di seguito:
Dim customer = FindCustomerByID(123) 'customer will be Nothing if not found.
If customer?.IsAllowedFreeShipping Then ApplyFreeShippingToOrders(customer)
Gli operatori condizionali Null causano corto circuiti. Se un'operazione in una catena di operazioni condizionali di indice e accesso ai membri restituisce Nothing, l'esecuzione delle altre operazioni della catena viene interrotta. Nell'esempio seguente C(E) non viene valutato se A, Bo C restituisce Nothing.
A?.B?.C?(E)
Si noti che se Not someStr?.Contains("some string") o qualsiasi altro valore valutato come Boolean? ha il valore di nothing o HasValue=false, il blocco else viene eseguito. La valutazione segue la valutazione SQL in cui null/nothing non è uguale a nulla, neanche a un altro null/nothing.
L'accesso ai membri con condizione Null viene usato anche per chiamare delegati in modo thread-safe scrivendo molto meno codice. L'esempio seguente definisce due tipi, NewsBroadcaster e NewsReceiver. Gli elementi di notizie vengono inviati al destinatario dal NewsBroadcaster.SendNews delegato.
Public Module NewsBroadcaster
Dim SendNews As Action(Of String)
Public Sub Main()
Dim rec As New NewsReceiver()
Dim rec2 As New NewsReceiver()
SendNews?.Invoke("Just in: A newsworthy item...")
End Sub
Public Sub Register(client As Action(Of String))
SendNews = SendNews.Combine({SendNews, client})
End Sub
End Module
Public Class NewsReceiver
Public Sub New()
NewsBroadcaster.Register(AddressOf Me.DisplayNews)
End Sub
Public Sub DisplayNews(newsItem As String)
Console.WriteLine(newsItem)
End Sub
End Class
Se nell'elenco chiamate SendNews non sono presenti elementi, il delegato SendNews genera un'eccezione NullReferenceException. Prima degli operatori condizionali Null, il codice simile al seguente ha verificato che l'elenco chiamate del delegato non fosse Nothing:
SendNews = SendNews.Combine({SendNews, client})
If SendNews IsNot Nothing Then
SendNews("Just in...")
End If
Ora tutto è molto più semplice:
SendNews = SendNews.Combine({SendNews, client})
SendNews?.Invoke("Just in...")
Il codice creato in questo modo è thread-safe perché il compilatore genera il codice per valutare SendNews una sola volta, mantenendo il risultato in una variabile temporanea. È necessario chiamare esplicitamente il metodo Invoke perché non esiste una sintassi di chiamata dei delegati con condizione Null SendNews?(String).
