Come creare un pacchetto usando un modello di file di definizione del pacchetto

Nell'esempio seguente viene illustrato come creare un pacchetto e un programma usando un modello di file di definizione del pacchetto in Configuration Manager. Il modello di file di definizione del pacchetto contiene i valori predefiniti usati per creare SMS_Package oggetti e SMS_Program . Nell'esempio seguente vengono utilizzati la SMS_PDF_Package classe e il GetPDFData metodo per caricare le informazioni sul modello di file di definizione del pacchetto e per creare un pacchetto e i programmi correlati.

Per creare un pacchetto usando un modello di file di definizione del pacchetto

1. Configurare una connessione al provider SMS.

2. Creare il nuovo oggetto pacchetto usando la SMS_PDF_Package classe .

3. Popolare eventuali proprietà aggiuntive del pacchetto.

4. Caricare le informazioni del programma e associare ogni programma al pacchetto.

Esempio

Il metodo di esempio seguente crea un nuovo pacchetto usando un file di definizione del pacchetto.

Per informazioni sulla chiamata del codice di esempio, vedere Chiamata di frammenti di codice Configuration Manager.

Sub SWDCreatePDFPackage(connection, existingPDF_ID, newPackageSourceFlag, newPackageSourcePath)  
    ' The PDF_ID must be passed in.  
    ' The PDF_ID can be identified through the SMS_PDF_Package class.  

    Dim newPDFPackage  
    Dim returnCode  
    Dim newPackage  
    Dim newPackagePath  
    Dim packageID  
    Dim program  
    Dim arrayOfPrograms  

    ' Package Creation  
    ' ----------------       
    ' Create new SMS_PDF_Package instance.  
    Set newPDFPackage = connection.Get("SMS_PDF_Package")  

    ' Load the Package Definition File data using the GetPDFData method.  
    returnCode = newPDFPackage.GetPDFData(existingPDF_ID, newPackage, arrayOfPrograms)  

    ' Assign any additional package properties.  
    newPackage.PkgSourceFlag = newPackageSourceFlag  
    newPackage.PkgSourcePath = newPackageSourcePath  

    ' Save the package path and get the Package ID.  
    Set newPackagePath = newPackage.Put_  
    packageID = newPackagePath.Keys("PackageID")  

    ' Program Creation   
    ' -----------------      
    ' Enumerate through the program array and create the programs.  
    For Each program In arrayOfPrograms  
        program.PackageID = packageID  
        program.Put_  
    Next  

End Sub  

Il metodo di esempio include i parametri seguenti:

Programmazione efficiente

Per altre informazioni sulla gestione degli errori, vedere Informazioni sugli errori di Configuration Manager.

Vedere anche

Panoramica della distribuzione softwareSMS_SCI_Component classe WMI del server