Grammatica consolidata

Grammatica lessicale

lexical-unit:
      lexical-elements_opt
lexical-elements:
      lexical-element lexical-elements_opt
lexical-element:
      whitespace
      token
      comment

Spazi vuoti

whitespace:
      Qualsiasi carattere con classe Unicode Zs
      Carattere di tabulazione orizzontale (U+0009)
      Carattere di tabulazione verticale (U+000B)
      Carattere di avanzamento carta (U+000C)
      Carattere di ritorno a capo (U+000D) seguito dal carattere di avanzamento riga (U+000A) new-line-character
new-line-character:
      Carattere di ritorno a capo (U+000D)
      Carattere di avanzamento riga (U+000A)
      Carattere di nuova riga (U+0085)
      Carattere separatore di riga (U+2028)
      Carattere separatore di paragrafo (U+2029)

Commento

comment:
      single-line-comment
      delimited-comment
single-line-comment:
      // single-line-comment-characters_opt
single-line-comment-characters:
      single-line-comment-character single-line-comment-characters_opt
single-line-comment-character:
      Qualsiasi carattere Unicode ad eccezione di new-line-character
delimited-comment:
      /* delimited-comment-text_opt asterisks /
delimited-comment-text:
      delimited-comment-section delimited-comment-text_opt
delimited-comment-section:
      /
      asterisks_opt not-slash-or-asterisk
asterisks:
      * asterisks_opt
not-slash-or-asterisk:
      Qualsiasi carattere Unicode ad eccezione di * o /

OAuth

token:
      identificatore
      keyword
      literal
      operator-or-punctuator

Sequenze di escape dei caratteri

character-escape-sequence:
      #( escape-sequence-list )
escape-sequence-list:
      single-escape-sequence
      escape-sequence-list , single-escape-sequence
single-escape-sequence:
      long-unicode-escape-sequence
      short-unicode-escape-sequence
      control-character-escape-sequence
      escape-escape
long-unicode-escape-sequence:
      hex-digit hex-digit hex-digit hex-digit hex-digit hex-digit hex-digit hex-digit
short-unicode-escape-sequence:
      hex-digit hex-digit hex-digit hex-digit
control-character-escape-sequence:
      control-character
control-character:
      cr
      lf
      tab
escape-escape:
      #

Letterali

literal:
      logical-literal
      number-literal
      text-literal
      null-literal
      verbatim-literal
logical-literal:
      true
      false
number-literal:
      decimal-number-literal
      hexadecimal-number-literal
decimal-digits:
      decimal-digit decimal-digits_opt
decimal-digit: uno tra
      0 1 2 3 4 5 6 7 8 9
hexadecimal-number-literal:
      0x hex-digits
      0X hex-digits
hex-digits:
      hex-digit hex-digits_opt
hex-digit: one of
      0 1 2 3 4 5 6 7 8 9 A B C D E F a b c d e f
decimal-number-literal:
      decimal-digits . decimal-digits exponent-part_opt
      . decimal-digits exponent-part_opt
      decimal-digits exponent-part_opt
exponent-part:
      e sign_opt decimal-digits
      E sign_opt decimal-digits
sign: uno tra
      + -
text-literal:
      " text-literal-characters_opt "
text-literal-characters:
      text-literal-character text-literal-characters_opt
text-literal-character:
      single-text-character
      character-escape-sequence
      double-quote-escape-sequence
single-text-character:
      Qualsiasi carattere ad eccezione di " (U+0022) o # (U+0023), seguito da ( (U+0028)
double-quote-escape-sequence:
      "" (U+0022, U+0022)
null-literal:
      null
verbatim-literal:
      #!" text-literal-characters_opt "

Identifiers

identifier:
      regular-identifier
      quoted-identifier
regular-identifier:
      available-identifier
      available-identifier dot-character regular-identifier
available-identifier:
      Un elemento keyword-or-identifierdiverso da keyword
keyword-or-identifier:
      letter-character
      underscore-character
      identifier-start-character identifier-part-characters
identifier-start-character:
      letter-character
      underscore-character
identifier-part-characters:
      identifier-part-character identifier-part-characters_opt
identifier-part-character:
      letter-character
      decimal-digit-character
      underscore-character
      connecting-character
      combining-character
      formatting-character
generalized-identifier:
      generalized-identifier-part
      generalized-identifier separati solo da spazi vuoti (U+0020) generalized-identifier-part
generalized-identifier-part:
      generalized-identifier-segment
      decimal-digit-character generalized-identifier-segment
generalized-identifier-segment:
      keyword-or-identifier
      keyword-or-identifier dot-character keyword-or-identifier
dot-character:
      . (U+002E)
underscore-character:
      _ (U+005F)
letter-character:_
      Carattere Unicode di classe Lu, Ll, Lt, Lm, Lo o Nl
combining-character:
      Carattere Unicode di classe Mn o Mc
decimal-digit-character:
      Carattere Unicode di classe Nd
connecting-character:
      Carattere Unicode di classe Pc
formatting-character:
      Carattere Unicode di classe Cf
quoted-identifier:
      #" text-literal-characters_opt "

Parole chiave e identificatori predefiniti

Non è possibile ridefinire le parole chiave e gli identificatori predefiniti. Un identificatore tra virgolette può essere usato per gestire gli identificatori che altrimenti sarebbero in conflitto con le parole chiave o gli identificatori predefiniti.

keyword: una tra
and as each else error false if in is let meta not null or otherwise
      section shared then true try type #binary #date #datetime
      #datetimezone #duration #infinity #nan #sections #shared #table #time

Operatori e segni di punteggiatura

operator-or-punctuator: uno tra
      , ; = < <= > >= <> + - * / & ( ) [ ] { } @ ? ?? => .. ...

Grammatica sintattica

Documenti

document:
      section-document
      expression-document

Documenti di sezione

section-document:
      section
section:
      literal-attributes_opt section section-name ; section-members_opt
section-name:
      identificatore
section-members:
      section-member section-members_opt
section-member:
      literal-attributes_opt shared_opt section-member-name = expression ;
section-member-name:
      identifier

Documenti di espressione

Espressioni

expression-document:
      expression
expression:
      logical-or-expression
each-expression
      function-expression
      let-expression
      if-expression
      error-raising-expression
      error-handling-expression

Espressioni logiche

logical-or-expression:
      logical-and-expression
      logical-and-expression or logical-or-expression
logical-and-expression:
      is-expression
      logical-and-expression and is-expression

Espressione is

is-expression:
      as-expression
      is-expression is nullable-primitive-type
nullable-primitive-type:
      nullable_opt primitive-type

Espressione as

as-expression:
      equality-expression
      as-expression as nullable-primitive-type

Espressione di uguaglianza

equality-expression:
      relational-expression
      relational-expression = equality-expression
      relational-expression <> equality-expression

Espressione relazionale

relational-expression:
      additive-expression
      additive-expression < relational-expression
      additive-expression > relational-expression
      additive-expression <= relational-expression
      additive-expression >= relational-expression

Espressioni aritmetiche

additive-expression:
      multiplicative-expression
      multiplicative-expression + additive-expression
      multiplicative-expression - additive-expression
      multiplicative-expression & _additive-expression
multiplicative-expression:
      metadata-expression
      metadata-expression * multiplicative-expression
      metadata-expression / multiplicative-expression

Espressione di metadati

metadata-expression:
      unary-expression
      unary-expression meta unary-expression

Espressione unaria

unary-expression:
      type-expression
      + unary-expression
      - unary-expression
      not unary-expression

Espressione primaria

primary-expression:
      literal-expression
      list-expression
      record-expression
      identifier-expression
      section-access-expression
      parenthesized-expression
      field-access-expression
      item-access-expression
      invoke-expression
      not-implemented-expression

Espressione letterale

literal-expression:
      literal

Espressione identificatore

identifier-expression:
      identifier-reference
identifier-reference:
      exclusive-identifier-reference
      inclusive-identifier-reference
exclusive-identifier-reference:
      identificatore
inclusive-identifier-reference:
      @ identifier

Espressione di accesso alla sezione

section-access-expression:
      identifier ! identifier

Espressione racchiusa tra parentesi

parenthesized-expression:
      ( expression )

Espressione non implementata

not-implemented-expression:
      ...

Espressione invoke

invoke-expression:
      primary-expression ( argument-list_opt )
argument-list:
      expression
      expression , argument-list

Espressione list

list-expression:
      { item-list_opt }
item-list:
      oggetto
      item , item-list
item:
      expression
      expression .. expression

Espressione di record

record-expression:
      [ _{field-listopt ]
field-list:
      campo
      field , field-list
field:
      field-name = expression
field-name:
      generalized-identifier
      quoted-identifier}

Espressione di accesso agli elementi

item-access-expression:
      item-selection
      optional-item-selection
item-selection:
primary-expression { item-selector }
optional-item-selection:
      primary-expression { item-selector } ?
item-selector:
      expression

Espressioni di accesso ai campi

field-access-expression:
      field-selection
      implicit-target-field-selection
      proiezione
      implicit-target-projection
field-selection:
      primary-expression field-selector
field-selector:
      required-field-selector
      optional-field-selector
required-field-selector:
      [ field-name ]
optional-field-selector:
      [ field-name ] ?
implicit-target-field-selection:
      field-selector
projection:
      primary-expression required-projection
      primary-expression optional-projection
required-projection:_
      [ required-selector-list ]
optional-projection:
      [ required-selector-list ] ?
required-selector-list:
      required-field-selector
      required-field-selector , required-selector-list
implicit-target-projection:
      required-projection
      optional-projection

Espressione di funzione

function-expression:
      ( parameter-list_opt ) return-type_opt => function-body
function-body:
      expression
parameter-list:
      fixed-parameter-list
      fixed-parameter-list , optional-parameter-list
      optional-parameter-list
fixed-parameter-list:
      parameter
      parameter , fixed-parameter-list
parameter:
      parameter-name primitive-parameter-type_opt
parameter-name:
      identificatore
primitive-parameter-type:
      primitive-assertion
return-type:
      primitive-assertion
primitive-assertion:
      as nullable-primitive-type
optional-parameter-list:
      optional-parameter
      optional-parameter , optional-parameter-list
optional-parameter:
      optional parameter

Espressione each

each-expression:
      each each-expression-body
each-expression-body:
      function-body

Espressione let

let-expression:
      let variable-list in expression
variable-list:
      Variabile
      variable , variable-list
variable:
      variable-name = expression
variable-name:
      identifier

Espressione if

if-expression:
      if if-condition then true-expression else false-expression
if-condition:
      expression
true-expression:
      expression
false-expression:
      expression

Espressione tipo

type-expression:
      primary-expression
      type primary-type
type:
      primary-expression
      primary-type
primary-type:
      primitive-type
      record-type
      list-type
      function-type
      table-type
      nullable-type
primitive-type: uno tra
      any anynonnull binary date datetime datetimezone duration function
      list logical none null number record table text time type
record-type:
      [ open-record-marker ]
      [ field-specification-list_opt ]
      [ field-specification-list , open-record-marker ]
field-specification-list:
      field-specification
      field-specification, field-specification-list
field-specification:
      optional_opt field-name field-type-specification_opt
field-type-specification:
      = field-type
field-type:
      Tipo
open-record-marker:
      ...
list-type:
      { item-type }
item-type:
      Tipo
function-type:
      function ( parameter-specification-list_opt ) return-type
parameter-specification-list:
      required-parameter-specification-list
      required-parameter-specification-list , optional-parameter-specification-list
      optional-parameter-specification-list
required-parameter-specification-list:
      required-parameter-specification
      required-parameter-specification , required-parameter-specification-list
required-parameter-specification:
      parameter-specification
optional-parameter-specification-list:
      optional-parameter-specification
      optional-parameter-specification , optional-parameter-specification-list
optional-parameter-specification:
      optional parameter-specification
parameter-specification:
      parameter-name parameter-type
parameter-type:
      assertion
assertion:
      as type
table-type:
      table row-type
row-type:
      [ field-specification-list_opt ]
nullable-type:
      nullable type

Espressione di generazione errore

error-raising-expression:
      error expression_

Espressione di gestione errore

error-handling-expression:
      try protected-expression error-handler_opt
protected-expression:
      expression
error-handler:
      otherwise-clause
      catch-clause
otherwise-clause:
      otherwise default-expression
default-expression:
      expression
catch-clause:
      catch catch-function
catch-function:
      (parameter-name_opt) => function-body

Attributi letterali

literal-attributes:
      record-literal
record-literal:
      [ literal-field-list_opt ]
literal-field-list:
      literal-field
      literal-field , literal-field-list
literal-field:
      field-name = any-literal
list-literal:
      { literal-item-list_opt }
literal-item-list:
      any-literal
      any-literal , literal-item-list
any-literal:
      record-literal
      list-literal
      logical-literal
      number-literal
      text-literal
      null-literal