Configuring COM+ Services in IIS

Articolo
06/16/2017

IIS uses some COM+ services to extend available features. For example, IIS can include COM+ transaction support in Web applications to protect eCommerce applications and allow them to back out of changes if an error occurs during a client session. This topic describes how to configure transaction support and other COM+ services that can be used by IIS.

Note

In IIS version 4.0, Microsoft Transaction Server (MTS) provided transaction support. In IIS version 5.0 and later versions, COM+ services provides all the transaction support of MTS, in addition to a number of other component development and deployment features.

Isolation of Web Application Processes

IIS defines Web applications as a collection of resource files that are grouped into a logical namespace. By grouping resources into applications, you gain the ability to share data throughout the namespace and to run the application in an isolated or pooled process.

For more information, see Configuring Applications and Configuring Servers for Applications in IIS Help.

Accessing COM+ Services from ASP Applications

IIS uses the COM+ CServiceConfig object to access certain COM+ services without having to internally create a COM+ component. When an ASP application starts, IIS populates the properties of an instance of the CServiceConfig object with application information from the IIS metabase such as what threading model to use, whether to enable side-by-side (SxS) assemblies, COM+ partitioning, or COM+ tracking. Using the CServiceConfig object allows the ASP application to run as if in a COM+ context even though no COM+ components are required.

For more information, see Using COM+ Services.

Apartment Model Selection

IIS 5.1 and earlier: Apartment model selection is not available.

ASP is now capable of running all of its threads in a multi-threaded apartment (MTA). If your COM components are primarily free-threaded or both-threaded, running the ASP threads as MTA can improve performance significantly.

To enable an ASP application to run in an MTA, you can use the metabase setting, AspExecuteInMTA, at the application level. This means that you can have one application running on ASP MTA threads and a second application running on ASP STA (single-threaded apartment) threads. The default for ASP threads continues to be STA.

When you switch an ASP application from running in STA to MTA (or from MTA to STA), the impersonation token becomes obsolete. This can cause the application to run with no impersonation, effectively letting it run with the identity of the process which might allow access to other resources. If you must switch threading models, disable the application and unload it before you make the change.

The following example sets the Default Web Site application (W3SVC/1/ROOT) to execute in MTA:

On Error Resume Next 
set providerObj = GetObject("winmgmts://MyMachine/root/MicrosoftIISv2") 
' Get a reference to the ASP application called Default Web Site 
set IIsWebVirtualDirSettingObj = providerObj.get("IIsWebVirtualDirSetting='W3SVC/1/ROOT'") 
WScript.Echo "Before: AspExecuteInMTA = " & IIsWebVirtualDirSettingObj.AspExecuteInMTA 
' Set the ASP application to execute in MTA 
IIsWebVirtualDirSettingObj.AspExecuteInMTA = 1 
IIsWebVirtualDirSettingObj.Put_() 
WScript.Echo "After: AspExecuteInMTA = " & IIsWebVirtualDirSettingObj.AspExecuteInMTA

Side-by-side Assemblies

IIS 5.1 and earlier: Side-by-side assemblies are not available.

Side-by-side (SxS) assemblies allow ASP applications to specify which version of a SxS-supported system DLL to use, such as MSVCRT, MSXML, COMCTL, GDIPLUS, and so on. For example, if your ASP application relies on MSVCRT version 2.0, you can ensure that your application still uses MSVCRT version 2.0 even after service packs are applied to the server. Any new version of MSVCRT is still installed on the computer, but version 2.0 remains and is used by your application. SxS-supported DLLs are stored in %WINDIR%\WinSxS.

Configuring SxS assemblies requires that you know the path to the DLL, and that the COM+ manifest file exists in every virtual directory that needs to use the DLL. The COM+ manifest is an XML file that has information about where a DLL is installed. IIS does not verify that the manifest exists. A manifest looks like the following file excerpt:

A manifest looks like the following file excerpt:

<?xml version="1.0" encoding="UTF-8" standalone="yes"?> 
<assembly xmlns="urn:schemas-microsoft-com:asm.v1" manifestVersion="1.0"> 
<assemblyIdentity publicKeyToken="75e377300ab7b886" type="win32" name="Test4Dir" version="1.0.0.0" processorArchitecture="x86"/> 
<file name="DirComp.dll" hash="35ca6f27b11ed948ac6e50b75566355f0991d5d9" hashalg="SHA1"> 
<comClass clsid="{6C6CC20E-0F85-49C0-A14D-D09102BD7CDC}" progid="DirComp.PathInfo" threadingModel="apartment"/> 
<typelib tlbid="{AA56D6B8-9ADB-415D-9E10-16DD68447319}" version="1.0" helpdir=""/> 
</file> 
</assembly>

You can enable side-by-side assemblies on the IIS side programmatically or by using IIS Manager.

To enable side-by-side assemblies by using IIS Manager, use the following procedure

Right-click a Web site or virtual directory and click Properties.
Click the Virtual Directory tab, and click Configuration. If the configuration button is not enabled, it is because you have not created an application for this virtual directory. Click Create to create an application.
In the Application Configuration dialog box, click the Options tab, and select Enable Side by Side assemblies.
In the Manifest file name box, type the location of the COM+ manifest file name, and click OK twice.

To enable side-by-side assemblies programmatically, set the AspEnableSxs flag of the AspAppServiceFlags metabase property. Also set the AspSxsName metabase property to the name of the COM+ manifest name. Set both metabase properties at the application level.

Only one version of a system DLL can be used in any application pool, even though this feature is configurable at the application level. For example, if application App1 uses MDAC version 2.5 and application App2 uses MDAC version 2.4, then App1 and App2 should not be in the same application pool. If they are, the application that is loaded first has its version of MDAC loaded, and the other application is forced to use it until the applications are unloaded.

The following example enables side-by-side assemblies on the Default Web Site application (W3SVC/1/ROOT). Notice that after setting only the AspEnableTracker property, the AspAppServiceFlags property changes as well:

On Error Resume Next 
set providerObj = GetObject("winmgmts://MyMachine/root/MicrosoftIISv2") 
' Get a reference to the ASP application called Default Web Site 
set IIsWebVirtualDirSettingObj = providerObj.get("IIsWebVirtualDirSetting='W3SVC/1/ROOT'") 
WScript.Echo "Before: AspEnableSxs = " & IIsWebVirtualDirSettingObj.AspEnableSxs 
WScript.Echo "        AspSxsName = " & IIsWebVirtualDirSettingObj.AspSxsName 
WScript.Echo "        AspAppServiceFlags = " & IIsWebVirtualDirSettingObj.AspAppServiceFlags 
' Set the ASP application to enable COM+ side-by-side assemblies 
IIsWebVirtualDirSettingObj.AspEnableSxs = 1 
' Set the AspSxsName property 
IIsWebVirtualDirSettingObj.AspSxsName = "VersionInfo" 
' Save the values to the IIS metabase 
IIsWebVirtualDirSettingObj.Put_() 
' Get the reference again in order to refresh the AspAppServiceFlags property. 
set IIsWebVirtualDirSettingObj = Nothing 
set IIsWebVirtualDirSettingObj = providerObj.get("IIsWebVirtualDirSetting='W3SVC/1/ROOT'") 
WScript.Echo "After: AspEnableSxs = " & IIsWebVirtualDirSettingObj.AspEnableSxs 
WScript.Echo "       AspSxsName = " & IIsWebVirtualDirSettingObj.AspSxsName 
WScript.Echo "       AspAppServiceFlags = " & IIsWebVirtualDirSettingObj.AspAppServiceFlags

COM+ Partitions

IIS 5.1 and earlier: Partitions are not available.

COM+ Partitions can be used to isolate Web applications into their own COM+ partitions. This is useful to prevent one Web application from accessing the private COM+ applications, configuration information, and data of another Web application. COM+ partitions can hold different versions of your own custom COM components. For example, if you host Web sites for two competing companies who both use COM+ in their Web applications, you can use COM+ partitions to ensure that one company's Web application cannot access the COM+ components in the other company's Web applications. If one of those companies asks you to change certain features in a COM+ application that they both use, you can isolate the new version of that COM+ application in the partition that is linked to their Web application.

To enable COM+ partitions on the IIS side, set the AspUsePartition flag of the AspAppServiceFlags metabase property at the application level. The partition is identified by a GUID (created using the Component Services Manager snap-in) which can be set at the AspPartitionID metabase property. If no partition is specified, the default system partition is used. For more information, please see the topic titled Creating and Configuring COM+ Partitions in the COM+ SDK or online at COM+ (Component Services).

Only one version of a COM+ component can be used in any application pool, even though this feature is configurable at the application level. For example, if application App1 uses version 1.0 of a custom COM+ application called Shop.dll, and application App2 uses version 2.0 of Shop.dll, then App1 and App2 should not be in the same application pool. If they are, the application that is loaded first has its version of Shop.dll loaded, and the other application is forced to use it until the applications are unloaded.

The following example enables partitions on the Default Web Site application (W3SVC/1/ROOT). Notice that after setting only the AspEnableTracker property, the AspAppServiceFlags property changes as well:

On Error Resume Next 
set providerObj = GetObject("winmgmts://MyMachine/root/MicrosoftIISv2") 
' Get a reference to the ASP application called Default Web Site 
set IIsWebVirtualDirSettingObj = providerObj.get("IIsWebVirtualDirSetting='W3SVC/1/ROOT'") 
WScript.Echo "Before: AspUsePartition = " & IIsWebVirtualDirSettingObj.AspUsePartition 
WScript.Echo "        AspPartitionID = " & IIsWebVirtualDirSettingObj.AspPartitionID 
WScript.Echo "        AspAppServiceFlags = " & IIsWebVirtualDirSettingObj.AspAppServiceFlags 
' Set the ASP application to enable COM+ partitioning 
IIsWebVirtualDirSettingObj.AspUsePartition = 1 
' Set the AspPartitionID property to the GUID configured in Component Services Manager 
' when you created the COM+ partition 
IIsWebVirtualDirSettingObj.AspPartitionID = "{00000000-0000-0000-0000-000000000000}" 
' Save the values to the IIS metabase 
IIsWebVirtualDirSettingObj.Put_() 
' Get the reference again in order to refresh the AspAppServiceFlags property. 
set IIsWebVirtualDirSettingObj = Nothing 
set IIsWebVirtualDirSettingObj = providerObj.get("IIsWebVirtualDirSetting='W3SVC/1/ROOT'") 
WScript.Echo "After: AspUsePartition = " & IIsWebVirtualDirSettingObj.AspUsePartition 
WScript.Echo "       AspPartitionID = " & IIsWebVirtualDirSettingObj.AspPartitionID 
WScript.Echo "       AspAppServiceFlags = " & IIsWebVirtualDirSettingObj.AspAppServiceFlags

Tracker

IIS 5.1 and earlier: Tracker is not available.

COM+ tracker allows administrators or developers to debug ASP applications. For example, if a Web application is causing problems on your server, you can enable COM+ tracker to determine when ASP pages are being loaded, when COM components are loaded, and when threads leave a page. Once you have debugged your application, you can disable COM+ tracker to return your application to normal performance speed.

To enable COM+ tracker on the IIS side, set the AspEnableTracker flag of the AspAppServiceFlags metabase property at the application level.

The following example enables tracking on the Default Web Site application (W3SVC/1/ROOT). Notice that after setting only the AspEnableTracker property, the AspAppServiceFlags property changes as well:

On Error Resume Next 
set providerObj = GetObject("winmgmts://MyMachine/root/MicrosoftIISv2") 
' Get a reference to the ASP application called Default Web Site 
set IIsWebVirtualDirSettingObj = providerObj.get("IIsWebVirtualDirSetting='W3SVC/1/ROOT'") 
WScript.Echo "Before: AspEnableTracker = " & IIsWebVirtualDirSettingObj.AspEnableTracker 
WScript.Echo "        AspAppServiceFlags = " & IIsWebVirtualDirSettingObj.AspAppServiceFlags 
' Set the ASP application to enable COM+ tracking 
IIsWebVirtualDirSettingObj.AspEnableTracker = 1 
IIsWebVirtualDirSettingObj.Put_() 
' Get the reference again in order to refresh the AspAppServiceFlags property. 
set IIsWebVirtualDirSettingObj = Nothing 
set IIsWebVirtualDirSettingObj = providerObj.get("IIsWebVirtualDirSetting='W3SVC/1/ROOT'") 
WScript.Echo "After: AspEnableTracker = " & IIsWebVirtualDirSettingObj.AspEnableTracker 
WScript.Echo "       AspAppServiceFlags = " & IIsWebVirtualDirSettingObj.AspAppServiceFlags

Condividi tramite