Visualizzare il contenuto XML nei file di personalizzazione dello Strumento di personalizzazione di Office

Panoramica di Windows Script Host

Per eseguire lo script, utilizzare Microsoft Windows Script Host (WSH), un host di scripting indipendente dal linguaggio per motori di script compatibili con Windows Script. WSH consente di eseguire script sia dal desktop di Windows che dal prompt dei comandi.

Per eseguire script da Windows, WScript.exe prevede una finestra di dialogo basata su Windows per l'impostazione delle proprietà degli script. Per eseguire script dal prompt dei comandi, CScript.exe prevede opzioni della riga di comando per l'impostazione delle proprietà degli script.

WSH prevede il supporto del trascinamento della selezione per gli script. Questo significa che è possibile trascinare file in uno script WSH. I nomi dei file vengono convertiti in argomenti sulla riga di comando.

Per ulteriori informazioni su WSH, vedere le risorse seguenti sul sito Web MSDN:

• Nozioni fondamentali di Windows Script Host (informazioni in lingua inglese) (https://go.microsoft.com/fwlink/?linkid=100317\&clcid=0x410) (informazioni in lingua inglese)

• Esecuzione dei script (informazioni in lingua inglese) (https://go.microsoft.com/fwlink/?linkid=100319\&clcid=0x410) (informazioni in lingua inglese)

Script ExtractOctXml.vbs di esempio

Nelle sezioni seguenti vengono riportati uno script di Visual Basic di esempio, ExtractOctXml.vbs, e le istruzioni da seguire per utilizzarlo per estrarre metadati XML dai file di personalizzazione MSP dello Strumento di personalizzazione di Office.

Per salvare lo script di esempio, aprire un editor di testo come Blocco note e copiare e incollare in un file il codice dello script riportato in questa sezione. Salvare il file di script come ExtractOctXml.vbs.

' Utility to extract the metadata from an Office 2007 customization patch 
' For use with Windows Scripting Host, CScript.exe or WScript.exe
' Copyright (c) Microsoft Corporation. All rights reserved.
'
Option Explicit

Const msiOpenDatabaseModePatchFile = 32
Const msiOpenDatabaseModeReadOnly     = 0
Const msiReadStreamBytes = 1

Const ForWriting = 2
Const TristateTrue = -1

Dim pathOCT_Patch 'As String
Dim pathMetadataXml 'As String
Dim sMetadata 'As String
Dim wshShell 'As Wscript.Shell
Dim fso 'As FileSystemObject
Dim fileOutput 'As File
Dim sErrSection ' As String


sErrSection = "ArgCheck"
' Check arg count, and display help if argument not present or contains ?
Dim argCount:argCount = Wscript.Arguments.Count
If argCount > 0 Then If InStr(1, Wscript.Arguments(0), "?", vbTextCompare) > 0 Then argCount = 0
If (argCount = 0) Then
    Wscript.Echo "Office 2007 OCT Metadata Extract utility" & _
        vbNewLine & " You must supply the location of the Office 2007 customization patch " & _
        vbNewLine & _
        vbNewLine & "Copyright (C) Microsoft Corporation.  All rights reserved."
    Wscript.Quit 1
Else
    pathOCT_Patch = Trim(Wscript.Arguments(0))
End If


sErrSection = "FSO"
' Create FileSystemObject and verify file exists
Set fso = CreateObject("Scripting.FileSystemObject") : CheckError
If Not fso.FileExists(pathOCT_Patch) Then Err = 2 : CheckError


sErrSection = "WI"
' Connect to Windows Installer object
On Error Resume Next
Dim wi : Set wi = Nothing
Set wi = Wscript.CreateObject("WindowsInstaller.Installer") : CheckError


sErrSection = "Read Metadata"
' Open OCT patch and read the metadata stream
Dim wiStorage, vw, rec
Set wiStorage = wi.OpenDatabase(pathOCT_Patch, msiOpenDatabaseModePatchFile) : CheckError
Set vw = wiStorage.OpenView("SELECT * FROM _Streams WHERE `Name`='metadata' ") : CheckError
vw.Execute
Set rec = vw.Fetch
If Not rec Is Nothing Then
    sMetadata = rec.ReadStream(2, rec.DataSize(2), msiReadStreamBytes)
Else
    Wscript.Echo "No Metadata stream was found in this file: " & pathOCT_Patch
    Wscript.Quit 2
End If

Set wiStorage = Nothing
Set rec = Nothing: Set vw = Nothing
Set wi = Nothing


sErrSection = "Write Metadata"
' Write the metadata stream to a temp file
Set wshShell = CreateObject("WScript.Shell") : CheckError
pathMetadataXml = wshShell.ExpandEnvironmentStrings("%temp%") & "\" & fso.GetFileName(pathOCT_Patch) & ".xml"
Set fileOutput = fso.OpenTextFile(pathMetadataXml, ForWriting, True, -1) : CheckError
fileOutput.WriteLine sMetadata 
fileOutput.Close

Set fileOutput = Nothing: Set fso = Nothing

sErrSection = "Show Metadata"
' Launch Metadata in IE
wshShell.Run "iexplore.exe " & pathMetadataXml 

    
    
Sub CheckError
Dim sMsg, errRec
    If Err = 0 Then Exit Sub
    sMsg = sErrSection & vbNewLine & Err.Source & " " & Hex(Err) & ": " & Err.Description
    If Not wi Is Nothing Then
    Set errRec = wi.LastErrorRecord
        If Not errRec Is Nothing Then sMsg = sMsg & vbNewLine & errRec.FormatText
    End If
    Wscript.Echo sMsg
    Wscript.Quit 2
End Sub

Sub NoMetadata
End Sub

Vedere anche

Concetti

Strumento di personalizzazione di Office in Office System 2007