BETWEEN (Transact-SQL)
Specifica un intervallo da testare.
.gif "Icona di collegamento a un argomento")
Sintassi
test_expression [ NOT ] BETWEEN begin_expression AND end_expression
Argomenti
test_expression
Espressione da testare nell'intervallo definito da begin_expressione end_expression. Il tipo di dati di test_expression deve essere uguale al tipo di dati di begin_expression e end_expression.NOT
Specifica che il risultato del predicato viene negato.begin_expression
Qualsiasi espressione valida. Il tipo di dati di begin_expression deve essere uguale al tipo di dati di test_expression e end_expression.end_expression
Qualsiasi espressione valida. Il tipo di dati di end_expression deve essere uguale al tipo di dati di test_expressione begin_expression.AND
Segnaposto che indica che test_expression deve essere compreso nell'intervallo specificato da begin_expression e end_expression.
Tipi restituiti
Boolean
Valore restituito
BETWEEN restituisce TRUE se il valore di test_expression è maggiore o uguale al valore di begin_expression e minore o uguale al valore di end_expression.
NOT BETWEEN restituisce TRUE se il valore di test_expression è minore del valore di begin_expression o maggiore del valore di end_expression.
Osservazioni
Per specificare un intervallo esclusivo, utilizzare gli operatori maggiore di (>) e minore di (<). Se l'input per il predicato BETWEEN o NOT BETWEEN è NULL, il risultato è UNKNOWN.
Esempi
A. Utilizzo di BETWEEN
Nell'esempio seguente vengono restituiti i dipendenti di Adventure Works Cycles che percepiscono una paga oraria compresa tra 27 e 30.
USE AdventureWorks;
GO
SELECT e.FirstName, e.LastName, ep.Rate
FROM HumanResources.vEmployee e
JOIN HumanResources.EmployeePayHistory ep
ON e.EmployeeID = ep.EmployeeID
WHERE ep.Rate BETWEEN 27 AND 30
ORDER BY ep.Rate;
GO
Set di risultati:
FirstName LastName Rate
----------- ------------------ ------------------
Paula Barreto de Mattos 27.1394
Janaina Bueno 27.4038
Dan Bacon 27.4038
Ramesh Meyyappan 27.4038
Karen Berg 27.4038
David Bradley 28.7500
Hazem Abolrous 28.8462
Ovidiu Cracium 28.8462
Rob Walters 29.8462
Sheela Word 30.0000
(10 row(s) affected)
B. Utilizzo di > e < al posto di BETWEEN
Nell'esempio seguente vengono utilizzati gli operatori maggiore di (>) e minore di (<) e, poiché non sono operatori inclusivi, vengono restituite nove righe anziché le dieci restituite nell'esempio precedente.
USE AdventureWorks;
GO
SELECT e.FirstName, e.LastName, ep.Rate
FROM HumanResources.vEmployee e
JOIN HumanResources.EmployeePayHistory ep
ON e.EmployeeID = ep.EmployeeID
WHERE ep.Rate > 27 AND ep.Rate < 30
ORDER BY ep.Rate;
GO
Set di risultati:
FirstName LastName Rate
--------- ------------------- ---------
Paula Barreto de Mattos 27.1394
Janaina Bueno 27.4038
Dan Bacon 27.4038
Ramesh Meyyappan 27.4038
Karen Berg 27.4038
David Bradley 28.7500
Hazem Abolrous 28.8462
Ovidiu Cracium 28.8462
Rob Walters 29.8462
(9 row(s) affected)
C. Utilizzo di NOT BETWEEN
Nell'esempio seguente vengono trovate tutte le righe che non rientrano nell'intervallo da 27 a 30.
USE AdventureWorks;
GO
SELECT e.FirstName, e.LastName, ep.Rate
FROM HumanResources.vEmployee e
JOIN HumanResources.EmployeePayHistory ep
ON e.EmployeeID = ep.EmployeeID
WHERE ep.Rate NOT BETWEEN 27 AND 30
ORDER BY ep.Rate;
GO
D. Utilizzo di BETWEEN tra valori datetime
Nell'esempio seguente vengono recuperate le righe con valori datetime tra '19971212' e '19980105', inclusi.
USE AdventureWorks
GO
SELECT EmployeeID, RateChangeDate
FROM HumanResources.EmployeePayHistory
WHERE RateChangeDate BETWEEN '19971212' AND '19980105'
Set di risultati:
EmployeeID RateChangeDate
----------- -----------------------
3 1997-12-12 00:00:00.000
4 1998-01-05 00:00:00.000
La query recupera le righe previste poiché i valori di data nella query e i valori datetime archiviati nella colonna RateChangeDate sono stati specificati senza la parte della data relativa all'ora. Quando la parte relativa all'ora viene omessa, il valore predefinito corrisponde a 0.00. Una riga contenente una parte dell'ora successiva all'ora 0.00 del 5 gennaio 1998 non verrà restituita dalla query, poiché non inclusa nell'intervallo.