• Articolo

@@ERROR (Transact-SQL)

Restituisce il numero di errore per l'ultima istruzione Transact-SQL eseguita.

Icona di collegamento a un argomentoConvenzioni della sintassi Transact-SQL

Sintassi

@@ERROR

Tipi restituiti

integer

Osservazioni

Restituisce 0 se nell'istruzione Transact-SQL precedente non è stato rilevato alcun errore.

Restituisce un numero di errore se nell'istruzione precedente è stato rilevato un errore. Se l'errore rilevato è descritto nella vista del catalogo sys.messages, la funzione @@ERROR include il valore riportato nella colonna sys.messages.message_id per tale errore. È possibile esaminare il testo associato a un numero di errore di @@ERROR in sys.messages.

Poiché la funzione @@ERROR viene cancellata e reimpostata ogni volta che viene eseguita un'istruzione, è necessario controllarne il valore subito dopo l'esecuzione dell'istruzione da verificare oppure salvarla in una variabile locale che è possibile controllare in un secondo momento.

Il costrutto TRY...CATCH viene utilizzato per la gestione degli errori. Il costrutto TRY...CATCH supporta inoltre funzioni di sistema aggiuntive (ERROR_LINE, ERROR_MESSAGE, ERROR_PROCEDURE, ERROR_SEVERITY e ERROR_STATE) che restituiscono un maggior numero di informazioni sull'errore rispetto a @@ERROR. TRY...CATCH supporta anche una funzione ERROR_NUMBER che non si limita a restituire il numero di errore nell'istruzione immediatamente successiva a quella in cui è stato generato un errore. Per ulteriori informazioni, vedere TRY...CATCH (Transact-SQL).

Esempi

A. Utilizzo di @@ERROR per individuare un errore specifico

In questo esempio la funzione @@ERROR viene utilizzata per rilevare una violazione di vincolo CHECK (errore numero 547) in un'istruzione UPDATE.

USE AdventureWorks;
GO
UPDATE HumanResources.EmployeePayHistory
    SET PayFrequency = 4
    WHERE EmployeeID = 1;
IF @@ERROR = 547
    PRINT N'A check constraint violation occurred.';
GO

B. Utilizzo di @@ERROR per uscire da una procedura in modo condizionale

L'istruzione IF...ELSE di questo esempio verifica il valore della funzione @@ERROR dopo l'esecuzione di un'istruzione INSERT in una stored procedure. Il valore della variabile @@ERROR determina il codice restituito inviato al programma chiamante per segnalare se la procedura ha avuto esito positivo o negativo.

USE AdventureWorks;
GO
-- Drop the procedure if it already exists.
IF OBJECT_ID(N'HumanResources.usp_DeleteCandidate', N'P') IS NOT NULL
    DROP PROCEDURE HumanResources.usp_DeleteCandidate;
GO
-- Create the procedure.
CREATE PROCEDURE HumanResources.usp_DeleteCandidate 
    (
    @CandidateID INT
    )
AS
-- Execute the DELETE statement.
DELETE FROM HumanResources.JobCandidate
    WHERE JobCandidateID = @CandidateID;
-- Test the error value.
IF @@ERROR <> 0 
    BEGIN
        -- Return 99 to the calling program to indicate failure.
        PRINT N'An error occurred deleting the candidate information.';
        RETURN 99;
    END
ELSE
    BEGIN
        -- Return 0 to the calling program to indicate success.
        PRINT N'The job candidate has been deleted.';
        RETURN 0;
    END;
GO

D. Utilizzo di @@ERROR con @@ROWCOUNT

In questo esempio la funzione @@ERROR viene utilizzata insieme alla funzione @@ROWCOUNT per convalidare l'esecuzione di un'istruzione UPDATE. Il valore di @@ERROR viene controllato per verificare la presenza di errori, mentre la funzione @@ROWCOUNT viene utilizzata per assicurare che l'aggiornamento di una riga della tabella sia stato eseguito correttamente.

USE AdventureWorks;
GO
IF OBJECT_ID(N'Purchasing.usp_ChangePurchaseOrderHeader',N'P')IS NOT NULL
    DROP PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader;
GO
CREATE PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader
    (
    @PurchaseOrderID INT
    ,@EmployeeID INT
   )
AS
-- Declare variables used in error checking.
DECLARE @ErrorVar INT;
DECLARE @RowCountVar INT;

-- Execute the UPDATE statement.
UPDATE PurchaseOrderHeader 
    SET EmployeeID = @EmployeeID 
    WHERE PurchaseOrderID = @PurchaseOrderID;

-- Save the @@ERROR and @@ROWCOUNT values in local 
-- variables before they are cleared.
SELECT @ErrorVar = @@ERROR
    ,@RowCountVar = @@ROWCOUNT;

-- Check for errors. If an invalid @EmployeeID was specified
-- the UPDATE statement returns a foreign-key violation error #547.
IF @ErrorVar <> 0
    BEGIN
        IF @ErrorVar = 547
            BEGIN
                PRINT N'ERROR: Invalid ID specified for new employee.';
                 RETURN 1;
            END
        ELSE
            BEGIN
                PRINT N'ERROR: error '
                    + RTRIM(CAST(@ErrorVar AS NVARCHAR(10)))
                    + N' occurred.';
                RETURN 2;
            END
    END

-- Check the row count. @RowCountVar is set to 0 
-- if an invalid @PurchaseOrderID was specified.
IF @RowCountVar = 0
    BEGIN
        PRINT 'Warning: The EmployeeID specified is not valid';
        RETURN 1;
    END
ELSE
    BEGIN
        PRINT 'Purchase order updated with the new employee';
        RETURN 0;
    END;
GO