Enterprise.ServicePrivateKeyProtectionInformation property

The ServicePrivateKeyProtectionInformation property retrieves an object that contains information about the server licensor private key.

This property is read-only.

Syntax

Enterprise.ServicePrivateKeyProtectionInformation

Property value

This property returns a ServicePrivateKeyProtectionInformation object.

Remarks

You can use a ServicePrivateKeyProtectionInformation object to retrieve the names of the cryptographic provider and key container and to determine whether the provider is implemented entirely in software.

Examples

DIM config_manager
DIM admin_role

' *******************************************************************
' Create and initialize a ConfigurationManager object.

SUB InitObject()

  CALL WScript.Echo( "Create ConfigurationManager object...")
  SET config_manager = CreateObject _
    ("Microsoft.RightsManagementServices.Admin.ConfigurationManager")      
  CheckError()
    
  CALL WScript.Echo( "Initialize...")
  admin_role=config_manager.Initialize(false,"localhost",80,"","","")
  CheckError()

END SUB

' *******************************************************************
' Retrieve information about the server licensor private  key.

SUB GetKeyInfo()

  DIM keyInfo
  Dim isSoftware

  ' Retrieve the ServicePrivateKeyProtectionInformation object.
  SET keyInfo = _
    config_manager.Enterprise.ServicePrivateKeyProtectionInformation
  CheckError()

  ' Retrieve the name of the cryptographic provider.
  CALL WScript.Echo("CSP name: " _
                    & keyInfo.CryptographicServiceProviderName)
  CheckError()

  ' Retrieve the name of the key container.
  CALL WScript.Echo("Container name: " & keyInfo.KeyContainer)
  CheckError()

  ' Retrieve a value that specifies whether the cryptographic
  ' provider is implemented entirely in software.
  isSoftware = "True"
  If keyInfo.IsServicePrivateKeySoftwareBased <> True Then
    isSoftware = "False"
  End If
  CALL WScript.Echo("IsSoftwareBased: " & isSoftware)
 
END SUB

' *******************************************************************
' Error checking function.

FUNCTION CheckError()
  CheckError = Err.number
  IF Err.number <> 0 THEN
    CALL WScript.Echo( vbTab & "*****Error Number: " _
                       & Err.number _
                       & " Desc:" _
                       & Err.Description _
                       & "*****")
    WScript.StdErr.Write(Err.Description)
    WScript.Quit( Err.number )
  END IF
END FUNCTION

Requirements

See also

Enterprise