Disabilitare il backup gestito di SQL Server in Microsoft Azure

  • Articolo

Si applica a: SQL Server

Questo argomento descrive come disabilitare o sospendere il backup gestito di SQL Server in Microsoft Azure a livello di database e di istanza.

Disabilitare il backup gestito di SQL Server in Microsoft Azure per un database

È possibile disabilitare le impostazioni del backup gestito di SQL Server in Microsoft Azure usando la stored procedure di sistema managed_backup.sp_backup_config_basic (Transact-SQL). Il parametro @enable_backup consente di abilitare e disabilitare le configurazioni del backup gestito di SQL Server in Microsoft Azure per un database specifico. Il valore 1 abilita e il valore 0 disabilita le impostazioni di configurazione.

Per disabilitare il backup gestito di SQL Server in Microsoft Azure per un database specifico:

  1. Connettersi al motore di database di .

  2. Dalla barra Standard fare clic su Nuova query.

  3. Copiare e incollare l'esempio seguente nella finestra Query, quindi fare clic su Esegui.

EXEC msdb.managed_backup.sp_backup_config_basic  
                @database_name = 'TestDB'   
                ,@enable_backup = 0;  
GO

Nota

Potrebbe anche essere necessario impostare il parametro @container_url in base alla configurazione.

Disabilitare il backup gestito di SQL Server in Microsoft Azure per tutti i database nell'istanza

La procedura seguente viene utilizzata quando si desidera disabilitare le impostazioni di configurazione del backup gestito di SQL Server in Microsoft Azure da tutti i database con il backup gestito di SQL Server in Microsoft Azure abilitato attualmente nell'istanza. Le impostazioni di configurazione come l'URL di archiviazione, la memorizzazione e le credenziali SQL rimarranno nei metadati ed è possibile usarle se si abilita il backup gestito di SQL Server in Microsoft Azure per il database in un secondo momento. Se si vuole sospendere solo temporaneamente i servizi del backup gestito di SQL Server in Microsoft Azure, è possibile usare l'opzione master descritta nelle sezioni successive di questo argomento.

Per disabilitare il backup gestito di SQL Server in Microsoft Azure per tutti i database:

  1. Connettersi al motore di database di .

  2. Dalla barra Standard fare clic su Nuova query.

  3. Copiare e incollare l'esempio seguente nella finestra Query, quindi fare clic su Esegui. L'esempio seguente identifica se il backup gestito di SQL Server in Microsoft Azure è configurato a livello di istanza e se tutti i database di backup gestito di SQL Server per Microsoft Azure sono abilitati nell'istanza ed esegue la stored procedure di sistema sp_backup_config_basic per disabilitare il backup gestito di SQL Server in Microsoft Azure.

-- Create a working table to store the database names  
Declare @DBNames TABLE  
  
       (  
             RowID int IDENTITY PRIMARY KEY  
             ,DBName varchar(500)  
  
       )  
-- Define the variables  
DECLARE @rowid int  
DECLARE @dbname varchar(500)  
DECLARE @SQL varchar(2000)  
-- Get the database names from the system function  
  
INSERT INTO @DBNames (DBName)  
  
SELECT db_name  
       FROM   
  
       msdb.managed_backup.fn_backup_db_config (NULL)  
       WHERE is_managed_backup_enabled = 1 
       AND is_dropped = 0
  
       --Select DBName from @DBNames  
  
       select @rowid = min(RowID)  
       FROM @DBNames  
  
       WHILE @rowID IS NOT NULL  
       Begin  
  
             Set @dbname = (Select DBName From @DBNames Where RowID = @rowid)  
             Begin  
             Set @SQL = 'EXEC msdb.managed_backup.sp_backup_config_basic    
                @database_name= '''+'' + @dbname+ ''+''',   
                @enable_backup=0'  
  
            EXECUTE (@SQL)  
  
             END  
             Select @rowid = min(RowID)  
             From @DBNames Where RowID > @rowid  
  
       END

Per verificare le impostazioni di configurazione per tutti i database nell'istanza, utilizzare la query seguente:

Use msdb;  
GO  
SELECT * FROM managed_backup.fn_backup_db_config (NULL);  
GO

Disabilitare le impostazioni predefinite di Backup gestito di SQL Server in Microsoft Azure per l'istanza

Le impostazioni predefinite a livello di istanza vengono applicate a tutti i nuovi database creati nell'istanza in questione. Se le impostazioni predefinite non sono più necessarie o richieste, è possibile disabilitare questa configurazione usando la stored procedure di sistema managed_backup.sp_backup_config_basic con il parametro @database_name impostato su NULL. La disabilitazione non comporta la rimozione delle altre impostazioni di configurazione come l'URL di archiviazione, l'impostazione di memorizzazione o il nome delle credenziali SQL. Queste impostazioni verranno utilizzate se il backup gestito di SQL Server in Microsoft Azure viene abilitato per l'istanza in un secondo momento.

Per disabilitare le impostazioni di configurazione predefinite del backup gestito di SQL Server in Microsoft Azure:

  1. Connettersi al motore di database di .

  2. Dalla barra Standard fare clic su Nuova query.

  3. Copiare e incollare l'esempio seguente nella finestra Query, quindi fare clic su Esegui.

    EXEC msdb.managed_backup.sp_backup_config_basic  
                @enable_backup = 0;  
GO

Sospendere il backup gestito di SQL Server in Microsoft Azure a livello di istanza

In alcuni casi è possibile che sia necessario sospendere temporaneamente i servizi di backup gestito di SQL Server in Microsoft Azure per un breve periodo. La stored procedure di sistema managed_backup.sp_backup_master_switch consente di disabilitare il servizio di backup gestito di SQL Server in Microsoft Azure a livello di istanza. La stessa stored procedure viene usata per riprendere il backup gestito di SQL Server in Microsoft Azure. Il parametro @state viene utilizzato per definire se il backup gestito di SQL Server in Microsoft Azure deve essere disabilitato o abilitato.

Per sospendere i servizi del backup gestito di SQL Server in Microsoft Azure tramite Transact-SQL:

  1. Connettersi al motore di database di .

  2. Dalla barra Standard fare clic su Nuova query.

  3. Copiare e incollare l'esempio seguente nella finestra Query, quindi fare clic su Esegui.

Use msdb;  
GO  
EXEC managed_backup.sp_backup_master_switch @new_state=0;  
Go

Per riprendere il backup gestito di SQL Server in Microsoft Azure tramite Transact-SQL

  1. Connettersi al motore di database di .

  2. Dalla barra Standard fare clic su Nuova query.

  3. Copiare e incollare l'esempio seguente nella finestra Query, quindi fare clic su Esegui.

Use msdb;  
Go  
EXEC managed_backup.sp_backup_master_switch @new_state=1;  
GO

Vedi anche

Abilitare il backup gestito di SQL Server in Microsoft Azure