sp_helptracertokens (Transact-SQL)

  • Articolo

Si applica a: SQL Server Istanza gestita di SQL di Azure

Restituisce una riga per ogni token di traccia inserito in una pubblicazione per determinare la latenza. Questa stored procedure viene eseguita nel database di pubblicazione del server di pubblicazione o nel database di distribuzione del server di distribuzione.

Convenzioni relative alla sintassi Transact-SQL

Sintassi

sp_helptracertokens
    [ @publication = ] N'publication'
    [ , [ @publisher = ] N'publisher' ]
    [ , [ @publisher_db = ] N'publisher_db' ]
[ ; ]

Argomenti

[ @publication = ] N'publication'

Nome della pubblicazione in cui sono stati inseriti i token di traccia. @publication è sysname, senza impostazione predefinita.

[ @publisher = ] N'publisher'

Nome del server di pubblicazione. @publisher è sysname, con un valore predefinito .NULL

@publisher deve essere specificato solo per server di pubblicazione non SQL Server.

[ @publisher_db = ] N'publisher_db'

Nome del database di pubblicazione. @publisher_db è sysname, con il valore predefinito NULL. @publisher_db viene ignorato se la stored procedure viene eseguita nel server di pubblicazione.

Set di risultati

Nome colonna Tipo di dati Descrizione
tracer_id int Identifica un record di token di traccia.
publisher_commit datetime Data e ora in cui è stato eseguito il commit del record del token nel database di pubblicazione del server di pubblicazione.

Valori del codice restituito

0 (esito positivo) o 1 (errore).

Osservazioni:

sp_helptracertokens viene usato nella replica transazionale.

sp_helptracertokens viene usato per ottenere gli ID token di traccia durante l'esecuzione di sp_helptracertokenhistory.

Esempi

DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

USE [AdventureWorks2022]

-- Insert a new tracer token in the publication database.
EXEC sys.sp_posttracertoken 
  @publication = @publication,
  @tracer_token_id = @tokenID OUTPUT;
SELECT 'The ID of the new tracer token is ''' + 
    CONVERT(varchar,@tokenID) + '''.'
GO

-- Wait 10 seconds for the token to make it to the Subscriber.
WAITFOR DELAY '00:00:10';
GO

-- Get latency information for the last inserted token.
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

CREATE TABLE #tokens (tracer_id int, publisher_commit datetime)

-- Return tracer token information to a temp table.
INSERT #tokens (tracer_id, publisher_commit)
EXEC sys.sp_helptracertokens @publication = @publication;
SET @tokenID = (SELECT TOP 1 tracer_id FROM #tokens
ORDER BY publisher_commit DESC)
DROP TABLE #tokens

-- Get history for the tracer token.
EXEC sys.sp_helptracertokenhistory 
  @publication = @publication, 
  @tracer_id = @tokenID;
GO

Autorizzazioni

Solo i membri del ruolo predefinito del server sysadmin, il ruolo predefinito del database di db_owner nel database di pubblicazione o db_owner ruoli predefiniti del database o del replmonitor nel database di distribuzione possono eseguire sp_helptracertokenhistory.

Contenuto correlato