sp_updateextendedproperty (Transact-SQL)

  • Articolo

Si applica a: SQL Server database SQL di Azure Istanza gestita di SQL di Azure

Aggiorna il valore di una proprietà estesa esistente.

Convenzioni relative alla sintassi Transact-SQL

Sintassi

sp_updateextendedproperty
    [ @name = ] N'name'
    [ , [ @value = ] value ]
    [ , [ @level0type = ] 'level0type' ]
    [ , [ @level0name = ] N'level0name' ]
    [ , [ @level1type = ] 'level1type' ]
    [ , [ @level1name = ] N'level1name' ]
    [ , [ @level2type = ] 'level2type' ]
    [ , [ @level2name = ] N'level2name' ]
[ ; ]

Argomenti

[ @name = ] N'name'

Nome della proprietà da aggiornare. @name è sysname, senza impostazione predefinita.

[ @value = ] value

Valore associato alla proprietà . @value è sql_variant, con il valore predefinito NULL. Le dimensioni del valore non possono essere superiori a 7.500 byte.

[ @level0type = ] 'level0type'

Tipo definito dall'utente o dall'utente. @level0type è varchar(128), con il valore predefinito NULL. Gli input validi sono:

  • ASSEMBLY
  • CONTRACT
  • EVENT NOTIFICATION
  • FILEGROUP
  • MESSAGE TYPE
  • PARTITION FUNCTION
  • PARTITION SCHEME
  • PLAN GUIDE
  • REMOTE SERVICE BINDING
  • ROUTE
  • SCHEMA
  • SERVICE
  • USER
  • TRIGGER
  • TYPE
  • NULL

Importante

USER e TYPE come tipi di livello 0 verranno rimossi in una versione futura di SQL Server. Evitare pertanto di utilizzarle in un nuovo progetto di sviluppo e prevedere interventi di modifica nelle applicazioni in cui sono state implementate. Usare SCHEMA come tipo di livello 0 anziché USER. Per TYPE, usare SCHEMA come tipo di livello 0 e TYPE come tipo di livello 1 .

[ @level0name = ] N'level0name'

Nome del tipo di oggetto di livello 0 specificato. @level0name è sysname, con un valore predefinito .NULL

[ @level1type = ] 'level1type'

Tipo di oggetto di livello 1. @level1type è varchar(128), con il valore predefinito NULL. Gli input validi sono:

  • ASSEMBLY
  • CONTRACT
  • EVENT NOTIFICATION
  • FILEGROUP
  • MESSAGE TYPE
  • PARTITION FUNCTION
  • PARTITION SCHEME
  • PLAN GUIDE
  • REMOTE SERVICE BINDING
  • ROUTE
  • SCHEMA
  • SERVICE
  • USER
  • TRIGGER
  • TYPE
  • NULL

[ @level1name = ] N'level1name'

Nome del tipo di oggetto di livello 1 specificato. @level1name è sysname, con un valore predefinito .NULL

[ @level2type = ] 'level2type'

Tipo di oggetto di livello 2. @level2type è varchar(128), con il valore predefinito NULL. Gli input validi sono:

  • COLUMN
  • CONSTRAINT
  • EVENT NOTIFICATION
  • INDEX
  • PARAMETER
  • TRIGGER
  • NULL

[ @level2name = ] N'level2name'

Nome del tipo di oggetto di livello 2 specificato. @level2name è sysname, con un valore predefinito .NULL

Valori del codice restituito

0 (esito positivo) o 1 (errore).

Osservazioni:

Quando si specificano proprietà estese, gli oggetti in un database di SQL Server vengono classificati in tre livelli (0, 1 e 2). Il livello 0 è il livello più alto e viene definito come oggetti inclusi nell'ambito del database. Gli oggetti di livello 1 sono inclusi nell'ambito di uno schema o utente, mentre gli oggetti di livello 2 sono contenuti dagli oggetti di livello 1. È possibile definire le proprietà estese per gli oggetti di qualsiasi livello. È necessario qualificare i riferimenti a un oggetto in un livello mediante i nomi degli oggetti proprietari di livello superiore o che li contengono.

Dato un @name e un @value validi, se tutti i tipi di oggetto e i nomi sono NULL, la proprietà aggiornata appartiene al database corrente.

Autorizzazioni

I membri del db_owner e db_ddladmin ruoli predefiniti del database possono aggiornare le proprietà estese di qualsiasi oggetto con l'eccezione seguente: db_ddladmin non può aggiungere proprietà al database stesso o a utenti o ruoli.

Gli utenti possono aggiornare le proprietà estese agli oggetti di cui sono proprietari o in cui dispongono di autorizzazioni ALTER o CONTROL.

Esempi

R. Aggiornare una proprietà estesa in una colonna

Nell'esempio seguente viene aggiornato il valore della proprietà Caption nella colonna ID della tabella T1.

USE AdventureWorks2022;
GO

CREATE TABLE T1 (id INT, name CHAR(20));
GO

EXEC sp_addextendedproperty @name = N'Caption',
    @value = N'Employee ID',
    @level0type = 'SCHEMA',
    @level0name = N'dbo',
    @level1type = 'TABLE',
    @level1name = N'T1',
    @level2type = 'COLUMN',
    @level2name = N'id';
GO

--Update the extended property.
EXEC sp_updateextendedproperty @name = N'Caption',
    @value = 'Employee ID must be unique.',
    @level0type = 'SCHEMA',
    @level0name = N'dbo',
    @level1type = 'TABLE',
    @level1name = N'T1',
    @level2type = 'COLUMN',
    @level2name = N'id';
GO

B. Aggiornare una proprietà estesa in un database

Nell'esempio seguente viene innanzitutto creata una proprietà estesa nel database di esempio AdventureWorks2022 e quindi il valore di tale proprietà viene aggiornato.

USE AdventureWorks2022;
GO

EXEC sp_addextendedproperty @name = N'NewCaption',
    @value = 'AdventureWorks Sample OLTP Database';
GO

USE AdventureWorks2022;
GO

EXEC sp_updateextendedproperty @name = N'NewCaption',
    @value = 'AdventureWorks Sample Database';
GO

Contenuto correlato