Metodo Enumerator.ReadItem

Recupera un elemento dalla risorsa e restituisce una rappresentazione XML dell'elemento.

Sintassi

Enumerator.ReadItem( _
  ByVal resource _
)

Parametri

resource

URI dell'elemento.

Valore restituito

Rappresentazione XML dell'elemento.

Commenti

Per limitare il numero di elementi letti, impostare la proprietà Session.BatchItems .

Si noti che la liberazione dell'oggetto di enumerazione pulisce tutte le richieste di enumerazione in sospeso.

Il metodo Session.Enumerate non ottiene una raccolta nello stesso modo in cui una query WMI, ad esempio SELECT * from Win32_LogicalDisk, restituisce una raccolta in un oggetto SWbemObjectSet. Per leggere un file come flusso di testo, creare l'oggetto TextStream di scripting e chiamare il metodo TextStream.Readline per leggere ogni riga del file. In modo analogo, chiamare il metodo Session.Enumerate per ottenere un oggetto Enumerator e quindi chiamare il metodo Enumerator.ReadItem . Come durante la lettura dal file di testo, è possibile controllare la proprietà Enumerator.AtEndOfStream per verificare se è stata raggiunta la fine degli elementi di dati.

Esempio

Nell'esempio di VBScript seguente viene chiamato il metodo Session.Enumerate per ottenere un elenco di processi pianificati. La subroutine DisplayOutput usa il file di trasformazione XML dello strumento da riga di comando Winrm (WsmTxt.xsl) per restituire i dati in un formato tabulare.

Const RemoteComputer = "servername.domain.com"

Set objWsman = CreateObject( "WSMan.Automation" )
Set objSession = objWsman.CreateSession( "https://" & RemoteComputer )

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" &_
              "wmi/root/cimv2/Win32_ScheduledJob"

Set objResultSet = objSession.Enumerate( strResource )
NumOfJobs = 0

While Not objResultSet.AtEndOfStream
    NumOfJobs = NumOfJobs + 1
    DisplayOutput( objResultSet.ReadItem ) 
Wend

Wscript.Echo "There are " & NumOfJobs & " jobs scheduled."

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Requisiti

Vedi anche

Enumeratore

Enumerazione o elenco di tutte le istanze di una risorsa