プライベート エンドポイントおよび VNet 統合と安全に接続された 2 つの Web アプリを作成する
この記事では、プライベート エンドポイントとリージョン VNet 統合を使用して、次の terraform 構成で 2 つの Web アプリ (フロントエンドとバックエンド) を安全に接続する例を示します。
- VNet をデプロイします
- 統合用の最初のサブネットを作成します
- プライベート エンドポイント用の 2 番目のサブネットを作成します。特定のパラメーターを設定して、ネットワーク ポリシーを無効にする必要があります
- プライベート エンドポイント機能に必要な、Basic、Standard、プレミアムV2、プレミアムV3、IsolatedV2、Functions プレミアム (Elastic プレミアム プランとも呼ばれます) の 1 つの App Service プランをデプロイする
- プライベート DNS ゾーンを使用する特定のアプリ設定を使用して、フロントエンド Web アプリを作成します。詳細はこちらを参照してください
- フロントエンド Web アプリを統合サブネットに接続します
- バックエンド Web アプリを作成します
- Web アプリのプライベート リンク ゾーンの名前 (privatelink.azurewebsites.net) を使用して、DNS プライベート ゾーンを作成します
- このゾーンを VNet にリンクします
- エンドポイント サブネットでバックエンド Web アプリ用のプライベート エンドポイントを作成し、前に作成した DNS プライベート ゾーンに DNS 名 (Web サイトと SCM) を登録します
Azure で Terraform を使用する方法
Azure で Terraform を使用する方法については、Azure のドキュメントを参照してください。
完全な Terraform ファイル
このファイルを使用するには、プレースホルダー <unique-frontend-app-name> と <unique-backend-app-name> を置き換えます (アプリ名は、世界全域で一意の DNS 名を形成するために使用されます)。
terraform {
required_providers {
azurerm = {
source = "hashicorp/azurerm"
version = "~>3.0"
}
}
}
provider "azurerm" {
features {}
}
resource "azurerm_resource_group" "rg" {
name = "appservice-rg"
location = "francecentral"
}
resource "azurerm_virtual_network" "vnet" {
name = "vnet"
location = azurerm_resource_group.rg.location
resource_group_name = azurerm_resource_group.rg.name
address_space = ["10.0.0.0/16"]
}
resource "azurerm_subnet" "integrationsubnet" {
name = "integrationsubnet"
resource_group_name = azurerm_resource_group.rg.name
virtual_network_name = azurerm_virtual_network.vnet.name
address_prefixes = ["10.0.1.0/24"]
delegation {
name = "delegation"
service_delegation {
name = "Microsoft.Web/serverFarms"
}
}
}
resource "azurerm_subnet" "endpointsubnet" {
name = "endpointsubnet"
resource_group_name = azurerm_resource_group.rg.name
virtual_network_name = azurerm_virtual_network.vnet.name
address_prefixes = ["10.0.2.0/24"]
private_endpoint_network_policies_enabled = true
}
resource "azurerm_service_plan" "appserviceplan" {
name = "appserviceplan"
location = azurerm_resource_group.rg.location
resource_group_name = azurerm_resource_group.rg.name
os_type = "Windows"
sku_name = "P1v2"
}
resource "azurerm_windows_web_app" "frontwebapp" {
name = "<unique-frontend-app-name>"
location = azurerm_resource_group.rg.location
resource_group_name = azurerm_resource_group.rg.name
service_plan_id = azurerm_service_plan.appserviceplan.id
site_config {}
app_settings = {
"WEBSITE_DNS_SERVER": "168.63.129.16",
"WEBSITE_VNET_ROUTE_ALL": "1"
}
}
resource "azurerm_app_service_virtual_network_swift_connection" "vnetintegrationconnection" {
app_service_id = azurerm_windows_web_app.frontwebapp.id
subnet_id = azurerm_subnet.integrationsubnet.id
}
resource "azurerm_windows_web_app" "backwebapp" {
name = "<unique-backend-app-name>"
location = azurerm_resource_group.rg.location
resource_group_name = azurerm_resource_group.rg.name
service_plan_id = azurerm_service_plan.appserviceplan.id
site_config {}
}
resource "azurerm_private_dns_zone" "dnsprivatezone" {
name = "privatelink.azurewebsites.net"
resource_group_name = azurerm_resource_group.rg.name
}
resource "azurerm_private_dns_zone_virtual_network_link" "dnszonelink" {
name = "dnszonelink"
resource_group_name = azurerm_resource_group.rg.name
private_dns_zone_name = azurerm_private_dns_zone.dnsprivatezone.name
virtual_network_id = azurerm_virtual_network.vnet.id
}
resource "azurerm_private_endpoint" "privateendpoint" {
name = "backwebappprivateendpoint"
location = azurerm_resource_group.rg.location
resource_group_name = azurerm_resource_group.rg.name
subnet_id = azurerm_subnet.endpointsubnet.id
private_dns_zone_group {
name = "privatednszonegroup"
private_dns_zone_ids = [azurerm_private_dns_zone.dnsprivatezone.id]
}
private_service_connection {
name = "privateendpointconnection"
private_connection_resource_id = azurerm_windows_web_app.backwebapp.id
subresource_names = ["sites"]
is_manual_connection = false
}
}