クイックスタート: Bicep を使って Azure App Configuration ストアを作成する
このクイックスタートでは、Bicep を使って次のことを行う方法について説明します。
- App Configuration ストアをデプロイする。
- App Configuration ストア内にキーと値を作成する。
- App Configuration ストア内のキーと値を読み取る。
Bicep は、宣言型の構文を使用して Azure リソースをデプロイするドメイン固有言語 (DSL) です。 簡潔な構文、信頼性の高いタイプ セーフ、およびコードの再利用のサポートが提供されます。 Bicep により、Azure のコード ソリューションとしてのインフラストラクチャに最適な作成エクスペリエンスが実現します。
前提条件
Azure サブスクリプションをお持ちでない場合は、開始する前に 無料アカウント を作成してください。
承認
Bicep ファイルを使用して Azure App Configuration リソースを管理するには、共同作成者や所有者などの Azure Resource Manager ロールが必要です。 Azure App Configuration データ (キー値、スナップショット) にアクセスするには、構成ストアの ARM 認証モードをパススルーに設定するときに、Azure Resource Manager ロールと追加の Azure App Configuration データ プレーン ロールが必要です。
重要
ARM 認証モードを構成するには、App Configuration コントロール プレーン API バージョン 2023-08-01-preview
以降が必要です。
Bicep ファイルを確認する
このクイックスタートで使用される Bicep ファイルは、Azure クイックスタート テンプレートからのものです。
Note
Bicep ファイルには、ARM テンプレートと同じ基本エンジンが使用されています。 ARM テンプレートのクイック スタートに記載されているすべてのヒント、注意事項、重要な情報は、すべてここに適用されます。 Bicep ファイルを使用する場合は、この情報を参照することをお勧めします。
@description('Specifies the name of the App Configuration store.')
param configStoreName string
@description('Specifies the Azure location where the app configuration store should be created.')
param location string = resourceGroup().location
@description('Specifies the names of the key-value resources. The name is a combination of key and label with $ as delimiter. The label is optional.')
param keyValueNames array = [
'myKey'
'myKey$myLabel'
]
@description('Specifies the values of the key-value resources. It\'s optional')
param keyValueValues array = [
'Key-value without label'
'Key-value with label'
]
@description('Specifies the content type of the key-value resources. For feature flag, the value should be application/vnd.microsoft.appconfig.ff+json;charset=utf-8. For Key Value reference, the value should be application/vnd.microsoft.appconfig.keyvaultref+json;charset=utf-8. Otherwise, it\'s optional.')
param contentType string = 'the-content-type'
@description('Adds tags for the key-value resources. It\'s optional')
param tags object = {
tag1: 'tag-value-1'
tag2: 'tag-value-2'
}
resource configStore 'Microsoft.AppConfiguration/configurationStores@2021-10-01-preview' = {
name: configStoreName
location: location
sku: {
name: 'standard'
}
}
resource configStoreKeyValue 'Microsoft.AppConfiguration/configurationStores/keyValues@2021-10-01-preview' = [for (item, i) in keyValueNames: {
parent: configStore
name: item
properties: {
value: keyValueValues[i]
contentType: contentType
tags: tags
}
}]
output reference_key_value_value string = configStoreKeyValue[0].properties.value
output reference_key_value_object object = {
name: configStoreKeyValue[1].name
properties: configStoreKeyValue[1].properties
}
Bicep ファイルには、次の 2 つの Azure リソースが定義されています。
- Microsoft.AppConfiguration/configurationStores: App Configuration ストアを作成します。
- Microsoft.AppConfiguration/configurationStores/keyValues: App Configuration ストア内にキー値を作成します。
この Bicep ファイルを使って、2 つの異なる値を持つ 1 つのキーを作成します。その一方には一意のラベルが付いています。
Bicep ファイルをデプロイする
Bicep ファイルを main.bicep としてローカル コンピューターに保存します。
Azure CLI または Azure PowerShell のどちらかを使用して Bicep ファイルをデプロイします。
az group create --name exampleRG --location eastus az deployment group create --resource-group exampleRG --template-file main.bicep --parameters configStoreName=<store-name>
注意
<store-name> を App Configuration ストアの名前に置き換えます。
デプロイが完了すると、デプロイが成功したことを示すメッセージが表示されます。
デプロイされているリソースを確認する
Azure CLI または Azure PowerShell を使用して、リソース グループ内のデプロイ済みリソースを一覧表示します。
az resource list --resource-group exampleRG
Azure portal を使って、リソースを一覧表示することもできます。
- Azure portal にサインインします。
- 検索ボックスに「App Configuration」と入力し、一覧から [App Configuration] を選びます。
- 新しく作成した App Configuration リソースを選択します。
- [操作] の [構成エクスプローラー] を選びます。
- 2 つのキー値が存在することを確認します。
リソースをクリーンアップする
不要になったら、Azure CLI または Azure PowerShell を使用して、リソース グループとそのリソースを削除します。
az group delete --name exampleRG
Azure portal を使って、リソース グループを削除することもできます。
- リソース グループに移動します。
- [リソース グループの削除] を選択します。
- タブが表示されます。 リソース グループの名前を入力し、[削除] を選択します。
次のステップ
App Configuration ストアに機能フラグや Key Vault 参照を追加する方法については、ARM テンプレートの例を参照してください。