ACSAuthIncomingOperations テーブルのクエリ

  • [アーティクル]

Azure portal でこれらのクエリを使用する方法については、 Log Analytics のチュートリアルを参照してください。 REST API については、「 Query」を参照してください。

個別の認証操作を一覧表示する

認証操作とバージョンのペアのすべての個別の組み合わせを返します。

ACSAuthIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

認証操作の期間の百分位数を計算する

各認証操作の実行時間の 90 パーセンタイル、95 パーセンタイル、および 99 パーセンタイルをミリ秒単位で計算します。 1 回の操作または他のパーセンタイルに対して実行するようにカスタマイズできます。

ACSAuthIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

認証操作あたり上位 5 つの IP アドレス

認証操作ごとに、その操作を最も多く呼び出した 5 つの IP アドレスをフェッチします。

ACSAuthIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

認証操作エラー

すべての認証エラーを再順序付けして一覧表示します。

ACSAuthIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100

認証操作の結果の数

認証操作ごとに、返された結果の種類をカウントします。

ACSAuthIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100