ACSCallRecordingIncomingOperations テーブルのクエリ

  • [アーティクル]

Azure portal でこれらのクエリを使用する方法については、 Log Analytics のチュートリアルを参照してください。 REST API については、「 Query」を参照してください。

通話記録操作

通話記録操作とバージョン ペアのすべての個別の組み合わせを返します。

ACSCallRecordingIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

通話記録操作の時間パーセンタイルの計算

各呼び出し記録操作の実行時間の 90 パーセンタイル、95 パーセンタイル、および 99 パーセンタイルをミリ秒単位で計算します。 1 回の操作または他のパーセンタイルに対して実行するようにカスタマイズできます。

ACSCallRecordingIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

通話記録操作あたり上位 5 つの IP アドレス

すべての通話記録操作について、その操作を最も多く呼び出した 5 つの IP アドレスをフェッチします。

ACSCallRecordingIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

通話記録の操作エラー

すべての呼び出し記録エラーを順に一覧表示します。

ACSCallRecordingIncomingOperations
| where ResultType == "Failure"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature
| order by TimeGenerated desc
| limit 100

通話記録操作の結果の数

すべての通話記録操作について、返された結果の種類をカウントします。

ACSCallRecordingIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

ID による通話記録ログ

特定の呼び出し接続 ID または関連付け ID の通話記録ログを照会します。

ACSCallRecordingIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
//| where CallConnectionId == "<callConnectionId>" // This can be uncommented to filter on a specific call connection ID
| project CorrelationId, CallConnectionId, OperationName, OperationVersion
| limit 100