ASCDeviceEvents テーブルのクエリ

  • [アーティクル]

Azure portal でこれらのクエリを使用する方法については、 Log Analytics のチュートリアルを参照してください。 REST API については、「 Query」を参照してください。

Azure Sphere デバイスの認証と構成証明の失敗

過去 1 週間の Azure Sphere デバイス認証と構成証明エラーの一覧を時間順に並べ替えます。

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and
        Properties.EventType == "DeviceAttestationFailure" or Properties.EventType == "DeviceCertificateEvent" and
        ResultType == "Failure" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| project TimeGenerated, DeviceId, Properties, ResultDescription, Location
| sort by TimeGenerated desc
| limit 100

Azure Sphere デバイス イベントのタイムライン

予期しないエラーを監視およびトラブルシューティングするために、先週の間に Azure Sphere デバイスによって生成されたすべてのイベントの並べ替えられたタイムライン。

ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" or Properties.DeviceTelemetryEventCategory == "AppCrash" // Remove/Add filters to see all/specific events. Filter data by Device by adding " | where DeviceId == "Your Device ID" " 
| project TimeGenerated, OperationName, ResultType, ResultDescription, Properties, Location
| sort by TimeGenerated desc
| limit 100

Azure Sphere デバイスハートビート イベントのタイムチャート

デバイスの正常性を継続的に監視し、傾向を確認するために、過去 1 週間に Azure Sphere デバイスによって開始されたすべての証明書生成イベントのタイムチャート。

let Interval = timespan(1d); // Interval for the Chart 
ASCDeviceEvents
| where OperationName == "DeviceCertificateEvent" and 
        Properties.EventType == "DeviceCertificatesGenerate" and 
        ResultType == "Success"
| summarize Device_Heartbeat_Events=count() by bin(TimeGenerated, Interval)
| render timechart

Azure Sphere デバイスが最新の OS に更新されない

過去 1 週間に最新の OS バージョンに更新されていない Azure Sphere デバイスの一覧。

ASCDeviceEvents
| where OperationName == "DeviceUpdateEvent" and  
        todouble(Properties.InstalledOSVersion) != todouble(Properties.TargetedOSVersion) // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize by DeviceId
| limit 100

Azure Sphere デバイス テレメトリ イベントの概要

過去 1 週間に Azure Sphere Devices によって生成された各イベント カテゴリの共有をまとめた円グラフ。デバイスの全体的な正常性を監視します。

ASCDeviceEvents
| where OperationName == "DeviceTelemetryEvent" // Filter by time by adding " | where TimeGenerated > ago(7d) " for last 7 days of data or using time picker in the UI
| summarize count() by tostring(Properties.DeviceTelemetryEventCategory)
| render piechart