LAQueryLogs テーブルのクエリ

  • [アーティクル]

Azure portal でこれらのクエリを使用する方法については、 Log Analytics のチュートリアルを参照してください。 REST API については、「 Query」を参照してください。

要求された最も多くの ResourceId

過去 24 時間で最も要求されたリソースです。

LAQueryLogs
| extend reqContext = parse_json(RequestContext)
| extend datasources = array_concat(reqContext["resources"], reqContext["workspaces"], reqContext["applications"])
| mv-expand datasources
| summarize reqCount = count() by tostring(datasources)
| order by reqCount desc

未承認ユーザー

過去 24 時間の要求数を持つ承認されていないユーザーの一覧を取得します。

LAQueryLogs
| where ResponseCode == "403"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

調整されたユーザー

調整されたユーザーの一覧を過去 24 時間の要求数と共に取得します。

LAQueryLogs
| where ResponseCode == "429"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

ResponseCode 別の要求数

過去 1 時間以内に 1 分のバケット内の応答コード別の要求数。

LAQueryLogs
| where TimeGenerated > ago(1h)
| summarize count() by tostring(ResponseCode), bin(TimeGenerated, 1m)
| render columnchart with (kind=stacked)

リソースを集中的に使用する上位 10 件のクエリ

過去 24 時間のリソースのインテシブ クエリ (CPU 消費量に基づく) の上位 10 個を取得します。

LAQueryLogs
| top 10 by StatsCPUTimeMs desc nulls last

時間の範囲が長い上位 10 件のクエリ

過去 24 時間でスキャンした時間の範囲が長い上位 10 件のクエリを取得します。

LAQueryLogs
| extend DataProcessedTimeRange = format_timespan(StatsDataProcessedEnd - StatsDataProcessedStart, 'dd.hh:mm:ss:FF')
| top 10 by DataProcessedTimeRange desc nulls last