MicrosoftDataShareReceivedSnapshotLog テーブルのクエリ

  • [アーティクル]

Azure portal でこれらのクエリを使用する方法については、 Log Analytics のチュートリアルを参照してください。 REST API については、「 Query」を参照してください。

受信したスナップショットを期間別に一覧表示する

過去 7 日間の期間で並べ替えられたスナップショットの一覧。

MicrosoftDataShareReceivedSnapshotLog
| where TimeGenerated > ago(7d)  
| where StartTime != "" and EndTime  != ""
| project StartTime , EndTime , DurationSeconds =(todatetime(EndTime)-todatetime(StartTime))/1s, ResourceName = split(_ResourceId,"/accounts/",1)// use split to get a part of the _ResourceId  
| sort by DurationSeconds desc nulls last

失敗した受信スナップショットの数

過去 7 日間に失敗したスナップショットの数。

MicrosoftDataShareReceivedSnapshotLog
| where TimeGenerated > ago(7d)  
| where Status == "Failed" 
| summarize count() by _ResourceId

受信したスナップショットで頻繁に発生するエラー

過去 7 日間で最も頻繁に発生したエラーの上位 10 件。

MicrosoftDataShareReceivedSnapshotLog 
| where TimeGenerated > ago(7d)  
| where Status == "Failed" 
| summarize count() by _ResourceId, DataSetType // Counting failed logs per datasettype
| top 10 by count_ desc nulls last

毎日受信したスナップショットのグラフ

過去 1 週間の毎日のスナップショット数の時間グラフ。

// Failed, In Progress and Succeeded Received Snapshots
MicrosoftDataShareReceivedSnapshotLog 
| where TimeGenerated > ago(7d)  
| summarize count() by bin(TimeGenerated, 1d), Status , _ResourceId // Aggregating by day //Click "Table" to see resource's name.
| render timechart