StorageBlobLogs テーブルのクエリ

  • [アーティクル]

Azure portal でこれらのクエリを使用する方法については、 Log Analytics のチュートリアルを参照してください。 REST API については、「 Query」を参照してください。

最も一般的なエラー

過去 3 日間の最も一般的なエラーを 10 件一覧表示します。

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by StatusText
| top 10 by count_ desc

最も多かったエラーを引き起こした操作

過去 3 日間でエラーが最も多い上位 10 件の操作を一覧表示します。

StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText !contains "Success"
| summarize count() by OperationName
| top 10 by count_ desc

待機時間が最も長い操作

過去 3 日間の最も長いエンド ツー エンド待機時間を含む上位 10 件の操作を一覧表示します。

StorageBlobLogs
| where TimeGenerated > ago(3d)
| top 10 by DurationMs desc
| project TimeGenerated, OperationName, DurationMs, ServerLatencyMs, ClientLatencyMs = DurationMs - ServerLatencyMs

サーバー側の調整を引き起こした操作

過去 3 日間でサーバー側の調整エラーを引き起こしたすべての操作を一覧表示します。

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and StatusText contains "ServerBusy"
| project TimeGenerated, OperationName, StatusCode, StatusText, _ResourceId

匿名要求を表示する

過去 3 日間の匿名アクセスによるすべての要求を一覧表示します。

// To create an alert for this query, click '+ New alert rule'
StorageBlobLogs
| where TimeGenerated > ago(3d) and AuthenticationType == "Anonymous"
| project TimeGenerated, OperationName, AuthenticationType, Uri, _ResourceId

頻繁に行われる操作のグラフ

過去 3 日間に使用された操作の円グラフ。

StorageBlobLogs
| where TimeGenerated > ago(3d)
| summarize count() by OperationName
| sort by count_ desc 
| render piechart