Bicep でのインポート

  • [アーティクル]

この記事では、共有機能のエクスポートとインポートに使用する構文と、Bicep 拡張機能の名前空間について説明します。

エクスポート型、変数、および関数

@export() デコレーターは、そのステートメントが別のファイルからインポートできることを示すものです。 このデコレーターは、型、変数、関数ステートメントでのみ有効です。 @export() でマークされた変数ステートメントは、コンパイル時定数である必要があります。

他の Bicep ファイルで使用する機能をエクスポートするための構文は次のとおりです：

@export()
<statement_to_export>

型、変数、関数のインポート

別の Bicep ファイルから機能をインポートするための構文は次のとおりです：

import {<symbol_name>, <symbol_name>, ...} from '<bicep_file_name>'

シンボルの名前を変更するためのオプションのエイリアスを使用する場合:

import {<symbol_name> as <alias_name>, ...} from '<bicep_file_name>'

ワイルドカード インポート構文の使用:

import * as <alias_name> from '<bicep_file_name>'

上記の構文を混在させ、一致させることができます。 ワイルドカード構文を使用してインポートされたシンボルにアクセスするには、 . 演算子 <alias_name>.<exported_symbol>を使用する必要があります。

参照されているファイル内の エクスポートされた ステートメントのみをインポートできます。

別のファイルからインポートされた機能は、制限なく使用できます。 たとえば、インポートされた変数は、ファイル内で宣言された変数が通常有効などの任意の場所でも使用できます。

例

exports.bicep

@export()
type myObjectType = {
  foo: string
  bar: int
}

@export()
var myConstant = 'This is a constant value'

@export()
func sayHello(name string) string => 'Hello ${name}!'

main.bicep

import * as myImports from 'exports.bicep'
import {myObjectType, sayHello} from 'exports.bicep'

param exampleObject myObjectType = {
  foo: myImports.myConstant
  bar: 0
}

output greeting string = sayHello('Bicep user')
output exampleObject myImports.myObjectType = exampleObject

名前空間と拡張機能のインポート (プレビュー)

Note

この機能を使用するには、実験的フィーチャー extensibilityはBicep 構成ファイル から有効にする必要があります。

名前空間をインポートするための構文は次のとおりです：

import 'az@1.0.0'
import 'sys@1.0.0'

az と sys はどちらも Bicep 組み込みの名前空間です。 これらは既定でインポートされます。 az と sys で定義されているデータ型と関数の詳細については、「データ型」と「Bicep 関数」を参照してください。

Bicep 拡張機能をインポートするための構文は次のとおりです。

import '<extension-name>@<extension-version>'

構成を必要とする Bicep 拡張機能をインポートするための構文は次のとおりです：

import '<extension-name>@<extension-version>' with {
  <extension-properties>
}

例については、「Bicep Kubernetes 拡張機能」を参照してください。

次のステップ