クイックスタート： Bicep を使用した Azure マネージド アプリケーション定義のデプロイ

このクイックスタートでは、Bicep を使用してサービス カタログから Azure マネージド アプリケーション定義をデプロイする方法について説明します。 サービス カタログ内の定義は、組織のメンバーが使用できます。

サービス カタログからマネージド アプリケーション定義をデプロイするには、次のタスクを行う必要があります。

• Bicep を使用して、マネージド アプリケーション定義をデプロイするテンプレートを作成します。
• デプロイ用のパラメーター ファイルを作成します。
• サービス カタログからマネージド アプリケーション定義をデプロイします。

前提条件

この記事のタスクを完了するには、次のものが必要です。

• 「クイック スタート: Bicep を使用して Azure マネージド アプリケーションの定義を作成および発行する」を使用してデプロイ済みの定義。
• アクティブなサブスクリプションが含まれる Azure アカウント。 アカウントをお持ちでない場合は、開始する前に無料アカウントを作成してください。
• Visual Studio Code と最新の Azure Resource Manager ツール拡張機能。 Bicep ファイルの場合は、Visual Studio Code 用の Bicep 拡張機能をインストールします。
• 最新バージョンの Azure PowerShell または Azure CLI。

マネージド アプリケーション定義を取得する

Connect-AzAccount

Get-AzManagedApplicationDefinition -ResourceGroupName bicepDefinitionGroup

Get-AzManagedApplicationDefinition -ResourceGroupName bicepDefinitionGroup | Select-Object -Property Name, ResourceGroupName

az login

az managedapp definition list --resource-group bicepDefinitionGroup

az managedapp definition list --resource-group bicepDefinitionGroup --query "[].{Name:name, ResourcGroup:resourceGroup}"

Bicep ファイルを作成する

Visual Studio Code を開き、deployServiceCatalog.bicep という名前のファイルを作成します。 次のコードをコピーし、ファイルに貼り付けて保存します。

@description('Region where the resources are deployed.')
param location string = resourceGroup().location

@description('Resource group name where the definition is stored.')
param definitionRG string

@description('Name of the service catalog definition.')
param definitionName string

// Parameters for the managed application's resource deployment
@description('Name of the managed application.')
param managedAppName string

@description('Name for the managed resource group.')
param mrgName string

@maxLength(40)
@description('Service plan name with maximum 40 alphanumeric characters and hyphens. Must be unique within a resource group in your subscription.')
param appServicePlanName string

@maxLength(47)
@description('Globally unique across Azure. Maximum of 47 alphanumeric characters or hyphens.')
param appServiceNamePrefix string

@maxLength(11)
@description('Use only lowercase letters and numbers and a maximum of 11 characters.')
param storageAccountNamePrefix string

@allowed([
  'Premium_LRS'
  'Standard_LRS'
  'Standard_GRS'
])
@description('The options are Premium_LRS, Standard_LRS, or Standard_GRS')
param storageAccountType string

@description('Resource ID for the managed application definition.')
var appResourceId = resourceId('${definitionRG}', 'Microsoft.Solutions/applicationdefinitions', '${definitionName}')

@description('Creates the path for the managed resource group. The resource group is created during deployment.')
var mrgId = '${subscription().id}/resourceGroups/${mrgName}'

resource bicepServiceCatalogApp 'Microsoft.Solutions/applications@2021-07-01' = {
  name: managedAppName
  kind: 'ServiceCatalog'
  location: location
  properties: {
    applicationDefinitionId: appResourceId
    managedResourceGroupId: mrgId
    parameters: {
      appServicePlanName: {
        value: appServicePlanName
      }
      appServiceNamePrefix: {
        value: appServiceNamePrefix
      }
      storageAccountNamePrefix: {
        value: storageAccountNamePrefix
      }
      storageAccountType: {
        value: storageAccountType
      }
    }
  }
}

リソースの種類の詳細については、「Microsoft.Solutions/applications」を参照してください。

パラメーター ファイルを作成する

Visual Studio Code を開き、deployServiceCatalog.parameters.bicepparam という名前のパラメーター ファイルを作成します。 次のコードをコピーし、ファイルに貼り付けて保存します。

using './deployServiceCatalog.bicep'

param definitionName = 'sampleBicepManagedApplication'
param definitionRG = 'bicepDefinitionGroup'
param managedAppName = 'sampleBicepManagedApp'
param mrgName = 'placeholder for managed resource group name'
param appServicePlanName = 'demoAppServicePlan'
param appServiceNamePrefix = 'demoApp'
param storageAccountNamePrefix = 'demostg1234'
param storageAccountType = 'Standard_LRS'

マネージド アプリケーションをデプロイするには、いくつかのパラメーターを指定する必要があります。

次のコマンドを実行して、マネージド リソース グループの名前を作成できます。

$mrgprefix = 'mrg-sampleBicepManagedApplication-'
$mrgtimestamp = Get-Date -UFormat "%Y%m%d%H%M%S"
$mrgname = $mrgprefix + $mrgtimestamp
$mrgname

mrgprefix='mrg-sampleBicepManagedApplication-'
mrgtimestamp=$(date +%Y%m%d%H%M%S)
mrgname="${mrgprefix}${mrgtimestamp}"
echo $mrgname

$mrgprefix 変数と $mrgtimestamp 変数は連結され、$mrgname 変数に格納されます。 変数の値は mrg-sampleBicepManagedApplication-20230512103059 の形式です。 $mrgname 変数の値は、マネージド アプリケーションをデプロイするときに使用します。

マネージド アプリケーションのデプロイ

Azure PowerShell または Azure CLI を使用して、リソース グループの作成とマネージド アプリケーションのデプロイを行います。

New-AzResourceGroup -Name bicepApplicationGroup -Location westus

$deployparms = @{
  ResourceGroupName = "bicepApplicationGroup"
  TemplateFile = "deployServiceCatalog.bicep"
  TemplateParameterFile = "deployServiceCatalog-parameters.bicepparam"
  Name = "deployServiceCatalogApp"
}

New-AzResourceGroupDeployment @deployparms

az group create --name bicepApplicationGroup --location westus

az deployment group create \
  --resource-group bicepApplicationGroup \
  --template-file deployServiceCatalog.bicep \
  --parameters deployServiceCatalog-parameters.bicepparam \
  --name deployServiceCatalogApp

デプロイ時に、managedResourceGroupId プロパティにリソース ID が必要であることを示す Bicep リンター警告が表示される場合があります。 マネージド リソース グループはデプロイ中に作成されるため、このプロパティに使用できるリソース ID はありません。

結果の表示

サービス カタログ マネージド アプリケーションをデプロイした後には、2 つの新しいリソース グループが作成されています。 1 つのリソース グループには、マネージド アプリケーションが含まれます。 もう 1 つのリソース グループには、デプロイされたマネージド リソースが含まれます。 この例では、App Service、App Service プラン、およびストレージ アカウントです。

マネージド アプリケーション

デプロイが完了したら、マネージド アプリケーションの状態を確認できます。

Get-AzManagedApplication -Name sampleBicepManagedApp -ResourceGroupName bicepApplicationGroup

Get-AzManagedApplication -Name sampleBicepManagedApp -ResourceGroupName bicepApplicationGroup | Select-Object -ExpandProperty Properties

az managedapp show --name sampleBicepManagedApp  --resource-group bicepApplicationGroup

az managedapp show --name sampleBicepManagedApp --resource-group bicepApplicationGroup --query "{Name:name, provisioningState:provisioningState}"

マネージド リソース

管理対象リソース グループにデプロイされたリソースを表示できます。

Get-AzResource -ResourceGroupName $mrgname

Get-AzRoleAssignment -ResourceGroupName $mrgname

Get-AzRoleAssignment -ResourceGroupName $mrgname -RoleDefinitionName Owner

Get-AzDenyAssignment -ResourceGroupName $mrgname

az resource list --resource-group $mrgname

az resource list --resource-group $mrgname --query "[].{Name:name, Type:type, provisioningState:provisioningState}"

az role assignment list --resource-group $mrgname

az role assignment list --resource-group $mrgname --role Owner --query "[].{ResourceGroup:resourceGroup, GroupName:principalName, RoleDefinition:roleDefinitionId, Role:roleDefinitionName}"

リソースをクリーンアップする

マネージド アプリケーションを終了したら、リソース グループを削除でき、これにより作成したすべてのリソースが削除されます。 たとえば、リソース グループ bicepApplicationGroup と、プレフィックス mrg-bicepManagedApplication を持つマネージド リソース グループを作成したとします。

bicepApplicationGroup リソース グループを削除すると、マネージド アプリケーション、マネージド リソース グループ、およびすべての Azure リソースが削除されます。

Remove-AzResourceGroup -Name bicepApplicationGroup

az group delete --resource-group bicepApplicationGroup --no-wait

マネージド アプリケーション定義を削除する場合は、作成した packageStorageGroup と bicepDefinitionGroup という名前のリソース グループを削除します。

次のステップ

• Azure PowerShell、Azure CLI、またはポータルを使用してマネージド アプリケーションの定義ファイルを作成および発行する方法を学習するには、「クイック スタート: Azure Managed Applications の定義を作成して発行する」を参照してください。
• 独自のストレージを使って、マネージド アプリケーションの定義ファイルを作成して発行するには、「クイック スタート: 独自のストレージを使用して Azure Managed Applications の定義を作成および発行する」を参照してください。