クイック スタート: Terraform を使用してインスタンスを作成する - Azure SQL Managed Instance

次の Terraform と Terraform プロバイダーのバージョンでテストされた記事:

• Terraform v1.3.5
• AzureRM Provider v.3.0.0

この記事では、Terraform を使用して、ルート テーブルとネットワーク セキュリティ グループに関連付けられている仮想ネットワーク (vNet) とサブネットに Azure SQL Managed Instance をデプロイする方法について説明します。

Terraform を使用すると、クラウド インフラストラクチャの定義、プレビュー、およびデプロイを行うことができます。 Terraform を使用する際は、HCL 構文を使って構成ファイルを作成します。 HCL 構文では、Azure などのクラウド プロバイダーと、クラウド インフラストラクチャを構成する要素を指定できます。 構成ファイルを作成したら、"実行プラン" を作成します。これにより、インフラストラクチャの変更をデプロイ前にプレビューすることができます。 変更を確認したら、実行プランを適用してインフラストラクチャをデプロイします。

この記事では、次のことについて説明します。

• SQL Managed Instance を実行するためのすべてのサポート サービスを作成する
• SQL マネージド インスタンスをデプロイする

前提条件

• Azure サブスクリプション:Azure サブスクリプションをお持ちでない場合は、開始する前に 無料アカウント を作成してください。

• Terraform のインストールと構成

Terraform コードを実装する

1. サンプル Terraform コードをテストして実行するディレクトリを作成し、それを現在のディレクトリにします。

2. providers.tf という名前のファイルを作成し、次のコードを挿入します。

   terraform {
     required_version = ">= 1.0"
   
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = ">= 3.0, < 4.0"
       }
       random = {
         source  = "hashicorp/random"
         version = ">= 3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {
       resource_group {
         prevent_deletion_if_contains_resources = false
       }
     }
   }
   

3. main.tf という名前のファイルを作成し、次のコードを挿入します。

   # TODO set the variables below either enter them in plain text after = sign, or change them in variables.tf
   #  (var.xyz will take the default value from variables.tf if you don't change it)
   
   # Create resource group
   resource "azurerm_resource_group" "example" {
     name     = "${random_pet.prefix.id}-rg"
     location = var.location
   }
   
   # Create security group
   resource "azurerm_network_security_group" "example" {
     name                = "${random_pet.prefix.id}-nsg"
     location            = azurerm_resource_group.example.location
     resource_group_name = azurerm_resource_group.example.name
   }
   
   # Create a virtual network
   resource "azurerm_virtual_network" "example" {
     name                = "${random_pet.prefix.id}-vnet"
     resource_group_name = azurerm_resource_group.example.name
     address_space       = ["10.0.0.0/24"]
     location            = azurerm_resource_group.example.location
   }
   
   # Create a subnet
   resource "azurerm_subnet" "example" {
     name                 = "${random_pet.prefix.id}-subnet"
     resource_group_name  = azurerm_resource_group.example.name
     virtual_network_name = azurerm_virtual_network.example.name
     address_prefixes     = ["10.0.0.0/27"]
   
     delegation {
       name = "managedinstancedelegation"
   
       service_delegation {
         name = "Microsoft.Sql/managedInstances"
         actions = [
           "Microsoft.Network/virtualNetworks/subnets/join/action",
           "Microsoft.Network/virtualNetworks/subnets/prepareNetworkPolicies/action",
           "Microsoft.Network/virtualNetworks/subnets/unprepareNetworkPolicies/action"
         ]
       }
     }
   }
   
   # Associate subnet and the security group
   resource "azurerm_subnet_network_security_group_association" "example" {
     subnet_id                 = azurerm_subnet.example.id
     network_security_group_id = azurerm_network_security_group.example.id
   }
   
   # Create a route table
   resource "azurerm_route_table" "example" {
     name                          = "${random_pet.prefix.id}-rt"
     location                      = azurerm_resource_group.example.location
     resource_group_name           = azurerm_resource_group.example.name
     disable_bgp_route_propagation = false
   }
   
   # Associate subnet and the route table
   resource "azurerm_subnet_route_table_association" "example" {
     subnet_id      = azurerm_subnet.example.id
     route_table_id = azurerm_route_table.example.id
   
     depends_on = [azurerm_subnet_network_security_group_association.example]
   }
   
   # Create managed instance
   resource "azurerm_mssql_managed_instance" "main" {
     name                         = "${random_pet.prefix.id}-mssql"
     resource_group_name          = azurerm_resource_group.example.name
     location                     = azurerm_resource_group.example.location
     subnet_id                    = azurerm_subnet.example.id
     administrator_login          = "${replace(random_pet.prefix.id, "-", "")}admin"
     administrator_login_password = random_password.password.result
     license_type                 = var.license_type
     sku_name                     = var.sku_name
     vcores                       = var.vcores
     storage_size_in_gb           = var.storage_size_in_gb
   
     depends_on = [azurerm_subnet_route_table_association.example]
   }
   
   resource "random_password" "password" {
     length      = 20
     min_lower   = 1
     min_upper   = 1
     min_numeric = 1
     min_special = 1
     special     = true
   }
   
   resource "random_pet" "prefix" {
     prefix = var.prefix
     length = 1
   }
   

4. variables.tf という名前のファイルを作成し、次のコードを挿入します。

   variable "prefix" {
     type        = string
     default     = "mi"
     description = "Prefix of the resource name"
   }
   
   variable "location" {
     type        = string
     description = "Enter the location where you want to deploy the resources"
     default     = "eastus"
   }
   
   variable "sku_name" {
     type        = string
     description = "Enter SKU"
     default     = "GP_Gen5"
   }
   
   variable "license_type" {
     type        = string
     description = "Enter license type"
     default     = "BasePrice"
   }
   
   variable "vcores" {
     type        = number
     description = "Enter number of vCores you want to deploy"
     default     = 8
   }
   
   variable "storage_size_in_gb" {
     type        = number
     description = "Enter storage size in GB"
     default     = 32
   }
   

Terraform を初期化する

terraform init を実行して、Terraform のデプロイを初期化します。 このコマンドによって、Azure リソースを管理するために必要な Azure プロバイダーがダウンロードされます。

terraform init -upgrade

重要なポイント:

• -upgrade パラメーターは、必要なプロバイダー プラグインを、構成のバージョン制約に準拠する最新バージョンにアップグレードします。

Terraform 実行プランを作成する

terraform plan を実行して、実行プランを作成します。

terraform plan -out main.tfplan

重要なポイント:

• terraform plan コマンドは、実行プランを作成しますが、実行はしません。 代わりに、構成ファイルに指定された構成を作成するために必要なアクションを決定します。 このパターンを使用すると、実際のリソースに変更を加える前に、実行プランが自分の想定と一致しているかどうかを確認できます。
• 省略可能な -out パラメーターを使用すると、プランの出力ファイルを指定できます。 -out パラメーターを使用すると、レビューしたプランが適用内容とまったく同じであることが確実になります。

Terraform 実行プランを適用する

terraform apply を実行して、クラウド インフラストラクチャに実行プランを適用します。

terraform apply main.tfplan

重要なポイント:

• terraform apply コマンドの例は、以前に terraform plan -out main.tfplan が実行されたことを前提としています。
• -out パラメーターに別のファイル名を指定した場合は、terraform apply の呼び出しで同じファイル名を使用します。
• -out パラメーターを使用しなかった場合は、パラメーターを指定せずに terraform apply を呼び出します。

結果を確認する

Azure portal 内の結果を確認するには、新しいリソース グループを参照します。 新しいインスタンスは、デプロイ後に新しいリソース グループに配置されます。 デプロイの進行状況を確認するには、PowerShell を開いたままにするか、Azure portal に移動し、SQL Managed Instance を検索してから、状態ですべてのインスタンスをフィルター処理します。

リソースをクリーンアップする

Terraform を使用して作成したリソースが不要になった場合は、次の手順を実行します。

1. terraform plan を実行して、destroy フラグを指定します。

   terraform plan -destroy -out main.destroy.tfplan
   

   重要なポイント:

   • terraform plan コマンドは、実行プランを作成しますが、実行はしません。 代わりに、構成ファイルに指定された構成を作成するために必要なアクションを決定します。 このパターンを使用すると、実際のリソースに変更を加える前に、実行プランが自分の想定と一致しているかどうかを確認できます。
   • 省略可能な -out パラメーターを使用すると、プランの出力ファイルを指定できます。 -out パラメーターを使用すると、レビューしたプランが適用内容とまったく同じであることが確実になります。

2. terraform apply を実行して、実行プランを適用します。

   terraform apply main.destroy.tfplan
   

Azure での Terraform のトラブルシューティング

Azure で Terraform を使用する場合の一般的な問題のトラブルシューティング

次のステップ