接続品質データを収集してクエリを実行する

接続品質は優れたユーザー エクスペリエンスに不可欠であるため、接続で可能性のある問題を監視し、発生した問題のトラブルシューティングを行えることが重要です。 Azure Virtual Desktop には、デプロイの接続の正常性を監視するのに役立つ Log Analytics などのツールと統合されています。 この記事では、接続品質データを収集し、特定のパラメーターのデータのクエリを実行できるように、診断設定を構成する方法について説明します。

前提条件

接続品質データの収集を始めるには、Azure Virtual Desktop で使用する Log Analytics ワークスペースを設定する必要があります。

診断設定の構成

Azure portal で診断設定を確認および変更するには:

1. Azure portal にサインインし、 Azure Virtual Desktop にアクセスして、ホストプールを選択します。

2. ネットワークデータを収集するホストプールを選択します。

3. 診断設定を選択し、まだ診断設定を構成していない場合は、新しい設定を作成します。 診断設定が既に構成されている場合は、設定の編集を選択します。

4. すべてのテーブルのデータを収集する場合は、allLogs を選びます。 allLogsパラメーターは、将来的に自動的に新しいテーブルをデータテーブルに追加します。

   特定のテーブルを見たい場合は、最初に [Network Data Logs] (ネットワーク データ ログ) と [Connection Graphics Data Logs Preview] (接続グラフィックス データ ログ プレビュー) を選んでから、表示する他のテーブルの名前を選びます。

5. 収集したデータを送信する場所を選択します。 Azure Virtual Desktop インサイトユーザーは、Log Analytics ワークスペースを選択する必要があります。

6. [保存] を選択して変更を保存します。

7. 測定する他のすべてのホストプールについて、このプロセスを繰り返します。

8. ネットワーク データを確認するには、ホストプールのリソース ページに戻り、ログを選択し、Azure Log Analytics のサンプル クエリでクエリの 1 つを実行します。 クエリで結果を取得するには、ホストプールに、以前セッションに接続したアクティブなユーザーが含まれている必要があります。 Azure portal にネットワークデータが表示されるまでに最大15分かかる場合があることに注意してください。

Azure Log Analytics のサンプル クエリ: ネットワーク データ

このセクションでは、接続の品質に関する情報を確認するのに役立つクエリのリストを用意しています。 これらのクエリは、Log Analytics クエリ エディターで実行できます。

平均 RTT と帯域幅を問い合わせます

ラウンドトリップの平均時間と帯域幅を調べるには:

// 90th, 50th, 10th Percentile for RTT in 10 min increments
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90),RTTP50=percentile(EstRoundTripTimeInMs,50),RTTP10=percentile(EstRoundTripTimeInMs,10) by bin(TimeGenerated,10m)
| render timechart
// 90th, 50th, 10th Percentile for BW in 10 min increments
WVDConnectionNetworkData
| summarize BWP90=percentile(EstAvailableBandwidthKBps,90),BWP50=percentile(EstAvailableBandwidthKBps,50),BWP10=percentile(EstAvailableBandwidthKBps,10) by bin(TimeGenerated,10m)
| render timechart

接続あたりのラウンドトリップ時間と帯域幅を調べるには:

// RTT and BW Per Connection Summary
// Returns P90 Round Trip Time (ms) and Bandwidth (KBps) per connection with connection details.
WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90),BWP90=percentile(EstAvailableBandwidthKBps,90),StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=leftouter (
WVDConnections
| extend Protocol = iff(UdpUse in ("0","<>"),"TCP","UDP")
| distinct CorrelationId, SessionHostName, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion, UserName
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

特定のユーザーのデータを照会します

特定のユーザーの帯域幅を調べるには：

let user = "alias@domain";
WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| where UserName == user
| project EstAvailableBandwidthKBps, TimeGenerated
| render columnchart  

特定のユーザーのラウンドトリップ時間を調べるには：

let user = "alias@domain";
WVDConnectionNetworkData
| join kind=leftouter (
WVDConnections
| distinct CorrelationId, UserName
) on CorrelationId
| where UserName == user
| project EstRoundTripTimeInMs, TimeGenerated
| render columnchart  

ラウンドトリップ時間が最も長いユーザー上位10名を調べる場合:

WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=avg(EstRoundTripTimeInMs),RTT_P95=percentile(EstRoundTripTimeInMs,95) by UserName
| top 10 by AvgRTT desc

帯域幅が最も低い10人のユーザーを調べる場合:

WVDConnectionNetworkData
| join kind=leftouter (
    WVDConnections
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps),BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

次の手順

接続品質について詳しくは、Azure Virtual Desktop での接続品質に関する記事をご覧ください。