BasicAuthenticationSection クラス

  • [アーティクル]

基本認証を構成します。

構文

class BasicAuthenticationSection : ConfigurationSection

メソッド

次の表に、BasicAuthenticationSection クラスによって公開されるメソッドの一覧を示します。

名前 説明
GetAllowDefinition (ConfigurationSection から継承。)
GetAllowLocation (ConfigurationSection から継承。)
RevertToParent (ConfigurationSection から継承。)
SetAllowDefinition (ConfigurationSection から継承。)
SetAllowLocation (ConfigurationSection から継承。)

プロパティ

次の表は、BasicAuthenticationSection クラスによって公開されるプロパティの一覧です。

名前 説明
DefaultLogonDomain クライアントがログオン ダイアログ ボックスでドメインを指定しなかった場合に、サーバーがユーザーの認証に使用する既定のドメインを指定する読み取り/書き込みの string 値。
Enabled 読み取り/書き込みの boolean 値。 基本認証が有効になっている場合は true、そうでない場合は false。 既定値は、false です。
Location (ConfigurationSection から継承。)キー プロパティ。
LogonMethod ローカル ユーザーの既定のログオン方法を指定する読み取り/書き込みの sint32 列挙型。 ログオンの種類によって、結果のトークンをリモートでも使用できるかどうかが決まります。 使用できる値の一覧は、後述の「注釈」セクションに示します。
Path (ConfigurationSection から継承。)キー プロパティ。
Realm クライアントが資格情報のキャッシュに使用する領域の名前を含む読み取り/書き込みの string 値。
SectionInformation (ConfigurationSection から継承。)

サブクラス

このクラスにはサブクラスが含まれていません。

解説

次の表に、LogonMethod プロパティとして使用できる値を示します。 既定値は 3 (ClearText) です。 詳細については、LogonUserEx 関数を参照してください。

Value キーワード 説明
0 Interactive このログオンの種類は、コンピューターを対話的に使用するユーザーを対象としています。
1 Batch このログオンの種類は、ユーザーが直接介入することなく、ユーザーの代わりにプロセスが実行される、バッチ サーバーを対象としています。 このログオンの種類の資格情報はキャッシュされません。
2 Network このログオンの種類は、プレーンテキスト パスワードを認証するハイ パフォーマンス サーバー向けです。 このログオンの種類の資格情報はキャッシュされません。
3 ClearText このログオンの種類では、名前とパスワードを認証パッケージに保持します。これにより、サーバーはクライアントを偽装しつつ他のネットワーク サーバーに接続できます。

例

次の例では、既定の Web サイトの BasicAuthenticationSection 構成を示します。

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = _  
    GetObject("winmgmts:root\WebAdministration")  
  
' Get the Basic authentication section for the default Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "BasicAuthenticationSection", oBasicAuth  
  
' Display the path and location.  
WScript.Echo "Basic Authentication Settings"  
WScript.Echo "-----------------------------"  
WScript.Echo "Path: " & oBasicAuth.Path  
WScript.Echo "Location: " & oBasicAuth.Location  
WScript.Echo   
  
' Display the Enabled, DefaultLogonDomain, Realm, and   
' LogonMethod properties.  
WScript.Echo "Enabled: " & _  
    "[" & oBasicAuth.Enabled & "]"  
  
WScript.Echo "DefaultLogonDomain: " & _  
    "[" & oBasicAuth.DefaultLogonDomain & "]"  
  
WScript.Echo "Realm: " & "[" & oBasicAuth.Realm & "]"  
  
WScript.Echo "LogonMethod: " &  _  
    "[" & GetLogonMethodText(oBasicAuth.LogonMethod) & "]"  
  
' Translate the LogonMethod enumeration values to text.  
Function GetLogonMethodText(LogonMethodValue)  
    Select Case LogonMethodValue  
        Case 0  
            GetLogonMethodText = "Interactive"  
        Case 1  
            GetLogonMethodText = "Batch"  
        Case 2  
            GetLogonMethodText = "Network"  
        Case 3  
            GetLogonMethodText = "ClearText"  
        Case Else  
            GetLogonMethodText = "Undefined enumeration."  
    End Select  
End Function

継承階層

ConfigurationSection

BasicAuthenticationSection

要件

型 説明
クライアント - Windows Vista 上の IIS 7.0
- Windows 7 上の IIS 7.5
- Windows 8 上の IIS 8.0
- Windows 10 上の IIS 10.0
[サーバー] - Windows Server 2008 上の IIS 7.0
- Windows Server 2008 R2 上の IIS 7.5
- Windows Server 2012 上の IIS 8.0
- Windows Server 2012 R2 上の IIS 8.5
- Windows Server 2016 上の IIS 10.0
Product - IIS 7.0、IIS 7.5、IIS 8.0、IIS 8.5、IIS 10.0
MOF ファイル WebAdministration.mof

参照

AnonymousAuthenticationSection クラス
AuthenticationSection クラス
ClientCertificateMappingAuthenticationSection クラス
DigestAuthenticationSection クラス
FormsAuthenticationConfiguration クラス
FormsAuthenticationCredentials クラス
FormsAuthenticationUser クラス
IisClientCertificateMappingAuthenticationSection クラス
PassportAuthentication クラス
WindowsAuthenticationSection クラス
LogonUserEx