CentralBinaryLogFile Class1

サーバー上の集中バイナリ ログの設定を構成します。

構文

class CentralBinaryLogFile : EmbeddedObject  

メソッド

このクラスにはメソッドが含まれていません。

プロパティ

次の表は、CentralBinaryLogFile クラスによって公開されるプロパティの一覧です。

サブクラス

このクラスにはサブクラスが含まれていません。

解説

このクラスのインスタンスは、LogSection クラスの CentralBinaryLogFile プロパティに含まれています。

次の表に、Period プロパティとして使用できる値の一覧を示します。 既定値は 1 (Daily) です。

例

次のコード例では、ログ ファイル モードを CentralBinary に設定し、バイナリ ログを有効にし、Period プロパティを Weekly に設定し、ログ ファイルがローカル時刻を使用することを指定し、ログ サイズを 1GB に制限します。 ヘルパー関数は、変更の前後の設定を表示します。

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the log configuration section.  
Set oSection = oWebAdmin.Get("LogSection.Path=" & _  
   "'MACHINE/WEBROOT/APPHOST',Location=''")  
  
' Show the initial settings.  
DisplaySettings("Initial Values")  
  
' Set the log file mode to CentralBinary.  
oSection.CentralLogFileMode = 1  
  
' Enable central binary logging.  
oSection.CentralBinaryLogFile.Enabled = True  
  
' Set local time rollover to true.  
oSection.CentralBinaryLogFile.LocalTimeRollover = True  
  
' Set the Period property to Weekly.  
oSection.CentralBinaryLogFile.Period = 2  
  
' Set the log truncate size to 1 gigabyte.  
oSection.CentralBinaryLogFile.TruncateSize = 1073741824  
  
' Save the values to configuration.  
oSection.Put_  
  
' Refresh the oSection object variable with the new values.  
oSection.Refresh_  
  
' Show the changed settings.  
Call DisplaySettings("New Values")  
  
' ==== This section contains helper functions. ====  
Function DisplaySettings(HeadingText)  
   WScript.Echo String(Len(HeadingText), "=")  
   WScript.Echo HeadingText  
   WScript.Echo String(Len(HeadingText), "=")  
  
   ' Display the current central log file mode.  
   WScript.Echo "CentralLogFileMode: " & _  
      oSection.CentralLogFileMode  
  
   ' Display the current binary log file properties.  
   Call ShowPropVals(oSection.CentralBinaryLogFile)  
  
End Function  
  
' Display the property values.  
Function ShowPropVals(oObject)  
  
   For Each Prop In oObject.Properties_  
      WScript.Echo Prop.Name & ": " & Prop.Value  
   Next  
  
   WScript.Echo  
  
End Function  
  

継承階層

EmbeddedObject

CentralBinaryLogFile

要件

参照

CentralW3CLogFile クラス
EmbeddedObject クラス
LogSection クラス
SiteLogFile クラス