ConfigurationHistorySection クラス

ApplicationHost ヘルパー サービスの構成履歴設定を構成します。

構文

class ConfigurationHistorySection : ConfigurationSection  

メソッド

次の表に、ConfigurationHistorySection クラスによって公開されるメソッドの一覧を示します。

プロパティ

次の表は、ConfigurationHistorySection クラスによって公開されるプロパティの一覧です。

サブクラス

このクラスにはサブクラスが含まれていません。

解説

このクラスには、現在の状態が望ましくなくなった場合に以前の構成状態に復元する構成履歴機能が用意されています。

ApplicationHost ヘルパー サービスは、Period プロパティで指定された設定間隔で別個の構成履歴サブディレクトリに ApplicationHost.config ファイルを保存することで、構成履歴機能を有効にします。 サブディレクトリは、HistoryPath プロパティで指定されたディレクトリに存在します。

ApplicationHost.config ファイルを変更するときに間違った場合は、以前のバージョンを %windir%\system32\inetsrv\config ディレクトリにコピーすることで、構成履歴サブディレクトリから以前のバージョンのファイルを復元できます。

構成履歴機能は、ApplicationHost ヘルパー サービスによって異なります。 ApplicationHost ヘルパー サービスはランタイムに依存しないサービスであり、その動作には Windows プロセス アクティブ化サービス (WAS) や World Wide Web 発行サービス (WWW サービス) は必要はありません。 他のサービスに依存せず、スタートアップの種類は Automatic です。

例

次のコード例では、履歴サブディレクトリの最大数を 20 に設定し、変更がないか ApplicationHost.config ファイルを 4 分ごとにチェックするように指定します。 ヘルパー関数を使って、変更の前後の ConfigurationHistorySection 値を表示します。

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the configuration history section.  
Set oSection = oWebAdmin.Get( _  
    "ConfigurationHistorySection.Path=" & _  
    "'MACHINE/WEBROOT/APPHOST',Location=''")  
  
' Display the class name of the section.  
WScript.Echo "[ " & oSection.Path_.Class & " ]" & vbCrLf  
  
' Display the initial settings.  
Call DisplaySettings("Initial Values", oSection)  
  
' Set the maximum number of history subdirectories to 20.  
oSection.MaxHistories = 20  
  
' Check ApplicationHost.config for changes every 4 minutes.  
oSection.Period = "00000000000400.000000:000"  
  
' Save the values to configuration.  
oSection.Put_  
  
' Refresh the oSection object variable with the new values.  
oSection.Refresh_  
  
' Show the changed settings.  
Call DisplaySettings("New Values", oSection)  
  
' ==== DisplaySettings helper function. ====  
Function DisplaySettings(HeadingText, oSection)  
  
    ' Display a heading.  
    WScript.Echo String(Len(HeadingText), "-")  
    WScript.Echo HeadingText  
    WScript.Echo String(Len(HeadingText), "-")  
  
    ' Display configuration history section properties.  
    WScript.Echo "Path: " & oSection.Path  
    WScript.Echo "Location: " & oSection.Location  
    WScript.Echo "History Path: " & oSection.HistoryPath  
    WScript.Echo "Period: " & oSection.Period  
    WScript.Echo "MaxHistories: " & oSection.MaxHistories  
    WScript.Echo  
End Function  
  

継承階層

ConfigurationSection

ConfigurationHistorySection

要件

参照

ConfigurationSection クラス