HandlersSection クラス

URL のハンドラーを格納します。

構文

class HandlersSection : ConfigurationSectionWithCollection  

メソッド

次の表に、HandlersSection クラスによって公開されるメソッドの一覧を示します。

プロパティ

次の表は、HandlersSection クラスによって公開されるプロパティの一覧です。

サブクラス

このクラスにはサブクラスが含まれていません。

解説

このクラスは、ApplicationHost.config ファイルの <handlers> セクションに対応します。

次の表に、AccessPolicy プロパティとして使用できる値の一覧を示します。 既定値は 1 (Read) です。

例

次の例は、<handlers> セクションに対してハンドラーを追加および削除します。

' ----------------------------------------------------------  
' The first example adds a handler to the <handlers> section.  
' ----------------------------------------------------------  
' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the <handlers> section.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "HandlersSection", oHandlersSection  
  
' Display the old handler names.  
WScript.Echo "---[Old Handler List]---"  
Call DisplayHandlers  
  
' Create a new handler.  
Set oHandler = oWebAdmin.Get("HandlerAction").SpawnInstance_  
oHandler.Name = "NewHandler"   
oHandler.Path="*.stm"   
oHandler.Verb="GET,POST"   
oHandler.Modules="ServerSideIncludeModule"   
  
' Add the handler to the <handlers> section.  
oHandlersSection.Add "Handlers", oHandler  
  
' Call the WMI Refresh_ method to update the oHandlersSection object.  
oHandlersSection.Refresh_  
  
' Display the new handler names.   
WScript.Echo "---[New Handler List]---"  
Call DisplayHandlers  
  
' ----------------------------------------------------------------  
' The second example removes a handler by using the handler name.  
' ----------------------------------------------------------------  
' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the <handlers> section.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "HandlersSection", oHandlersSection  
  
' Display the old handler names.  
WScript.Echo "---[Old Handler List]---"  
Call DisplayHandlers  
  
' Remove the CGI-exe handler by name.  
For Each oHandler In oHandlersSection.Handlers  
     If oHandler.Name = "CGI-exe" Then  
        oHandlersSection.Remove "Handlers", oHandler  
    End If   
Next  
  
' Call the WMI Refresh_ method to update the oHandlersSection object.  
oHandlersSection.Refresh_  
  
' Display the new list of handler names.   
WScript.Echo "---[New Handler List]---"  
Call DisplayHandlers  
  
' This is the sub that displays the handler names.  
Sub DisplayHandlers  
    WScript.Echo   
    For Each oHandler In oHandlersSection.Handlers  
        WScript.Echo "Handler Name: " & oHandler.Name  
    Next  
End Sub  
  

継承階層

ConfigurationSection

ConfigurationSectionWithCollection

HandlersSection

要件

参照

ConfigurationSectionWithCollection クラス
HandlerAction クラス