RequestFilteringSection クラス
受信 URL 要求のスキャンを構成します。
構文
class RequestFilteringSection : ConfigurationSectionWithCollection
メソッド
次の表に、RequestFilteringSection クラスによって公開されるメソッドの一覧を示します。
| 名前 | 説明 |
|---|---|
| [追加] | (ConfigurationSectionWithCollection から継承。) |
| Clear | (ConfigurationSectionWithCollection から継承。) |
| Get | (ConfigurationSectionWithCollection から継承。) |
| GetAllowDefinition | (ConfigurationSection から継承。) |
| GetAllowLocation | (ConfigurationSection から継承。) |
| 削除 | (ConfigurationSectionWithCollection から継承。) |
| RevertToParent | (ConfigurationSection から継承。) |
| SetAllowDefinition | (ConfigurationSection から継承。) |
| SetAllowLocation | (ConfigurationSection から継承。) |
プロパティ
次の表は、RequestFilteringSection クラスによって公開されるプロパティの一覧です。
| 名前 | 説明 |
|---|---|
AllowDoubleEscaping |
読み取り/書き込みの boolean 値。 URL で二重エスケープ文字を許可する場合は true。それ以外の場合は false。 既定値は、false です。 |
AllowHighBitCharacters |
読み取り/書き込みの boolean 値。 URL で ASCII 以外の文字を許可する場合は true。それ以外の場合は false。 既定値は、true です。 |
DenyUrlSequences |
Web サーバーの攻撃に使用できるため拒否する URL シーケンスを含む UrlSequenceSettings 値。 |
FileExtensions |
要求で許可または拒否できるファイル拡張子を指定する、読み取り/書き込みの FileExtensionsSettings 値。 |
HiddenSegments |
コンテンツをクライアントに提供しないセグメントを指定する HiddenSegmentSettings 値。 注: セグメントとは、URL の 2 つのスラッシュに挟まれている部分、または最後のスラッシュの後に続く部分です。 たとえば、URL /segment1/segment2/segment3.asp には、segment1、segment2、segment3.aspの 3 つのセグメントがあります。 注: 既定では、次のセグメントはブロックされます: bin、App_code、App_GlobalResources、App_LocalResources、App_WebReferences、App_Data、App_Browsers。 |
Location |
(ConfigurationSection から継承。)キー プロパティ。 |
Path |
(ConfigurationSection から継承。)キー プロパティ。 |
RequestLimits |
受信 HTTP 要求に対するサイズ制限を指定する RequestLimitsElement 値。 |
SectionInformation |
(ConfigurationSection から継承。) |
Verbs |
許可または拒否する HTTP 動詞を指定する、読み取り/書き込みの VerbsSettings 値。 注: HTTP 動詞のワイルドカードはサポートされていません。 |
サブクラス
このクラスにはサブクラスが含まれていません。
解説
このクラスは、以前のバージョンの IIS で使用された URLScan ツールの機能を IIS 7 に統合します。
Note
RequestFilteringSection クラスの機能を動作させるには、要求フィルター モジュール (Modrqflt.dll) をインストールする必要があります。
例
次の例は、ApplicationHost.config ファイルの要求フィルター セクションのすべてのプロパティを表示します。
' Connect to the WMI WebAdministration namespace.
Set objWMIService = GetObject("winmgmts:root\WebAdministration")
' Get the request-filtering section.
Set oRequestFilteringSection = objWMIService.Get( _
"RequestFilteringSection.Path='MACHINE/WEBROOT/APPHOST',Location=''")
' Show the path.
WScript.Echo "[Request Filtering Path]"
WScript.Echo oRequestFilteringSection.Path_
WScript.Echo
' Show the AllowDoubleEscaping property as "True" or "False."
WScript.Echo "[AllowDoubleEscaping]"
WScript.Echo CStr(oRequestFilteringSection.AllowDoubleEscaping)
WScript.Echo
' Show the AllowHighBitCharacters property as "True" or "False."
WScript.Echo "[AllowHighBitCharacters]"
WScript.Echo CStr(oRequestFilteringSection.AllowHighBitCharacters)
WScript.Echo
' List the denied URL sequences.
WScript.Echo "[Denied Url Sequences]"
For Each oSequence In _
oRequestFilteringSection.DenyUrlSequences.DenyUrlSequences
WScript.Echo oSequence.Sequence
Next
WScript.Echo
' List the file extensions settings.
WScript.Echo "[File Extensions]"
' Show the AllowUnlisted property as "True" or "False."
WScript.Echo "Allow unlisted file extensions: " & _
oRequestFilteringSection.FileExtensions.AllowUnlisted
WScript.Echo
' List each file extension and show whether it is allowed.
For Each oFileExtension In _
oRequestFilteringSection.FileExtensions.FileExtensions
WScript.Echo "File extension: " & oFileExtension.FileExtension
WScript.Echo "File extension allowed: " & oFileExtension.Allowed
WScript.Echo
Next
WScript.Echo
' List the hidden segments.
WScript.Echo "[Hidden Segments]"
For Each oHiddenSegment In _
oRequestFilteringSection.HiddenSegments.HiddenSegments
WScript.Echo oHiddenSegment.Segment
Next
WScript.Echo
' Show the request limits settings.
WScript.Echo "[Request Limits]"
WScript.Echo "maxAllowedContentLength: " & _
oRequestFilteringSection.RequestLimits.maxAllowedContentLength
WScript.Echo "maxUrl: " & oRequestFilteringSection.RequestLimits.maxUrl
WScript.Echo "maxQueryString: " & oRequestFilteringSection.RequestLimits.maxQueryString
WScript.Echo
' Show the header limits settings.
WScript.Echo vbtab & "[Header Limits]"
For Each oHeaderLimit In _
oRequestFilteringSection.RequestLimits.HeaderLimits.HeaderLimits
WScript.Echo vbtab & "Header: " & oHeaderLimit.Header
WScript.Echo vbtab & "Header size limit: " & oHeaderLimit.SizeLimit
WScript.Echo
Next
' List the verbs settings.
WScript.Echo "[Verbs]"
WScript.Echo "Allow unlisted verbs: " & oRequestFilteringSection.Verbs.AllowUnlisted
WScript.Echo
' List each verb and show whether it is allowed.
For Each oVerb In oRequestFilteringSection.Verbs.Verbs
WScript.Echo "Verb: " & oVerb.Verb
WScript.Echo "Verb allowed: " & oVerb.Allowed
WScript.Echo
Next
継承階層
ConfigurationSectionWithCollection
RequestFilteringSection
要件
| 型 | 説明 |
|---|---|
| クライアント | - Windows Vista 上の IIS 7.0 - Windows 7 上の IIS 7.5 - Windows 8 上の IIS 8.0 - Windows 10 上の IIS 10.0 |
| [サーバー] | - Windows Server 2008 上の IIS 7.0 - Windows Server 2008 R2 上の IIS 7.5 - Windows Server 2012 上の IIS 8.0 - Windows Server 2012 R2 上の IIS 8.5 - Windows Server 2016 上の IIS 10.0 |
| Product | - IIS 7.0、IIS 7.5、IIS 8.0、IIS 8.5、IIS 10.0 |
| MOF ファイル | WebAdministration.mof |
参照
ConfigurationSectionWithCollection クラス
FileExtensionElement クラス
FileExtensionsSettings クラス
HeaderLimitsSettings クラス
HiddenSegmentSettings クラス
<requestFiltering>
RequestLimitsElement クラス
UrlSequence クラス
UrlSequenceSettings クラス
VerbElement クラス
VerbsSettings クラス