パッケージ定義ファイル テンプレートを使用してパッケージを作成する方法

次の例では、Configuration Managerでパッケージ定義ファイル テンプレートを使用してパッケージとプログラムを作成する方法を示します。 パッケージ定義ファイル テンプレートには、オブジェクトと SMS_Program オブジェクトの作成SMS_Packageに使用される既定値が含まれています。 次の例では、 クラスと メソッドをSMS_PDF_PackageGetPDFData使用して、パッケージ定義ファイル テンプレート情報を読み込み、パッケージと関連プログラムを作成します。

パッケージ定義ファイル テンプレートを使用してパッケージを作成するには

1. SMS プロバイダーへの接続を設定します。

2. クラスを使用して、新しいパッケージ オブジェクトを SMS_PDF_Package 作成します。

3. 追加のパッケージ プロパティを設定します。

4. プログラム情報を読み込み、各プログラムをパッケージに関連付けます。

例

次のメソッドの例では、パッケージ定義ファイルを使用して新しいパッケージを作成します。

サンプル コードの呼び出しについては、「Configuration Manager コード スニペットの呼び出し」を参照してください。

Sub SWDCreatePDFPackage(connection, existingPDF_ID, newPackageSourceFlag, newPackageSourcePath)  
    ' The PDF_ID must be passed in.  
    ' The PDF_ID can be identified through the SMS_PDF_Package class.  

    Dim newPDFPackage  
    Dim returnCode  
    Dim newPackage  
    Dim newPackagePath  
    Dim packageID  
    Dim program  
    Dim arrayOfPrograms  

    ' Package Creation  
    ' ----------------       
    ' Create new SMS_PDF_Package instance.  
    Set newPDFPackage = connection.Get("SMS_PDF_Package")  

    ' Load the Package Definition File data using the GetPDFData method.  
    returnCode = newPDFPackage.GetPDFData(existingPDF_ID, newPackage, arrayOfPrograms)  

    ' Assign any additional package properties.  
    newPackage.PkgSourceFlag = newPackageSourceFlag  
    newPackage.PkgSourcePath = newPackageSourcePath  

    ' Save the package path and get the Package ID.  
    Set newPackagePath = newPackage.Put_  
    packageID = newPackagePath.Keys("PackageID")  

    ' Program Creation   
    ' -----------------      
    ' Enumerate through the program array and create the programs.  
    For Each program In arrayOfPrograms  
        program.PackageID = packageID  
        program.Put_  
    Next  

End Sub  

このメソッドの例には、次のパラメーターがあります。

堅牢なプログラミング

エラー処理の詳細については、「Configuration Manager エラーについて」を参照してください。

関連項目

サーバー WMI クラスSMS_SCI_Componentソフトウェア配布の概要