OutlineCodes オブジェクト (Project)

  • [アーティクル]

Contains a collection of OutlineCode objects.

注釈

アウトライン コードは、階層構造のテキスト参照テーブルを持つローカルのユーザー定義フィールドの一種です。 階層構造のテキスト参照テーブルを持つテキスト型のエンタープライズ ユーザー設定フィールドがアウトライン コードとして機能します。 OutlineCodes コレクションを取得するには、OutlineCodes プロパティを使用します。 ローカル アウトライン コードを OutlineCodes コレクションに追加するには、 Add メソッドを使用します。 エンタープライズ ユーザー設定フィールドを追加するには、Project Web Appまたは Project Server Interface (PSI) を使用する必要があります。

例

OutlineCodes コレクション オブジェクトの使い方

次の例では、ユーザー設定のアウトライン コードを追加してリソースの位置を格納します。さらに、そのアウトライン コードを設定して、参照テーブルに指定されている値のみをリソースと関連付けるようにします。

注:

[!メモ] OnlyLookUpTableCodes プロパティは、参照テーブルにエントリが含まれている後にのみ設定できます。 ルックアップ テーブルのエントリを作成する前に OnlyLookUpTableCodes を設定しようとすると、結果が実行時エラー 7 がメモリ不足です。

Sub CreateLocationOutlineCode() 

 

 Dim objOutlineCode As OutlineCode 

 

 Set objOutlineCode = ActiveProject.OutlineCodes.Add( _ 

 pjCustomResourceOutlineCode1, "Location") 

 

 DefineLocationCodeMask objOutlineCode.CodeMask 

 EditLocationLookupTable objOutlineCode.LookupTable 

 

 objOutlineCode.OnlyLookUpTableCodes = True 

 

End Sub 

 

 

Sub DefineLocationCodeMask(objCodeMask As CodeMask) 

 objCodeMask.Add _ 

 Sequence:=pjCustomOutlineCodeUppercaseLetters, _ 

 Length:=2, Separator:="." 

 

 objCodeMask.Add _ 

 Sequence:=pjCustomOutlineCodeUppercaseLetters, _ 

 Separator:="." 

 

 objCodeMask.Add _ 

 Sequence:=pjCustomOutlineCodeUppercaseLetters, _ 

 Length:=3, Separator:="." 

End Sub 

 

 

Sub EditLocationLookupTable(objLookupTable As LookupTable) 

 Dim objStateEntry As LookupTableEntry 

 Dim objCountyEntry As LookupTableEntry 

 Dim objCityEntry As LookupTableEntry 

 

 Set objStateEntry = objLookupTable.AddChild("WA") 

 objStateEntry.Description = "Washington" 

 

 Set objCountyEntry = objLookupTable.AddChild("KING", _ 

 objStateEntry.UniqueID) 

 objCountyEntry.Description = "King County" 

 

 Set objCityEntry = objLookupTable.AddChild("SEA", _ 

 objCountyEntry.UniqueID) 

 objCityEntry.Description = "Seattle" 

 

 Set objCityEntry = objLookupTable.AddChild("RED", _ 

 objCountyEntry.UniqueID) 

 objCityEntry.Description = "Redmond" 

 

 Set objCityEntry = objLookupTable.AddChild("KIR", _ 

 objCountyEntry.UniqueID) 

 objCityEntry.Description = "Kirkland" 

End Sub

メソッド

名前
Add

プロパティ

名前
アプリケーション
Count
アイテム
Parent

関連項目

Project オブジェクト モデル

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。