Application.MouseDown イベント (Visio)

マウス ボタンをクリックしたときに発生するイベントです。

構文

式。MouseDown (Button, KeyButtonState, x, y, CancelDefault)

expressionApplication オブジェクトを 表す変数。

パラメーター

注釈

CancelDefault を True に設定すると、マウス ボタンがクリックされたときに受け取ったメッセージは処理されません。

他の Visio イベントとは異なり、 MouseDown にはプレフィックス Query はありませんが、クエリ イベントです。 つまり、CancelDefault を True に設定するか、VisEventProc メソッドを使用してイベントを処理する場合は、True を返すことによって、MouseDown によって送信されたメッセージの処理を取り消すことができます。 詳細については、この『Visio オートメーション リファレンス』の VisEventProc メソッドとクエリ イベント (QueryCancelSuspend イベントなど) のトピックを参照してください。

Microsoft Visual Basic または Visual Basic for Applications (VBA) を使用している場合、このトピックの構文を使用して、イベントを一般的な方法で効率的に処理できます。

独自の Event オブジェクトを作成する場合は、Add メソッドまたは AddAdvise メソッドを使用します。

アドオンを実行する Event オブジェクトを作成するには、EventList コレクションに対して Add メソッドを使用します。

通知を受け取る Event オブジェクトを作成するには、AddAdvise メソッドを使用します。

作成するイベントのイベント コードについては、「イベント コード」を参照してください。

例

このクラス モジュールでは、アクティブ ウィンドウでマウス アクションによって発生するイベントをリッスンする MouseListener という同期クラスを定義する方法を示します。 このクラス モジュールでは、WithEvents キーワードを使用してオブジェクト変数 vsoWindow が宣言されています。 クラス モジュールには、 MouseDown、 MouseMove、 および MouseUp イベントのイベント ハンドラーも含まれています。

この例を実行するには、VBA プロジェクトに新しいクラス モジュールを挿入し、 MouseListener という名前を付けて、モジュールに次のコードを挿入します。

Dim WithEvents vsoWindow As Visio.Window 
 
Private Sub Class_Initialize() 
 
 Set vsoWindow = ActiveWindow 
 
End Sub 
 
Private Sub Class_Terminate() 
 
 Set vsoWindow = Nothing 
 
End Sub 
 
Private Sub vsoWindow_MouseDown(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean) 
 
 If Button = 1 Then 
 
 Debug.Print "Left mouse button clicked" 
 
 ElseIf Button = 2 Then 
 
 Debug.Print "Right mouse button clicked" 
 
 ElseIf Button = 16 Then 
 
 Debug.Print "Center mouse button clicked" 
 
 End If 
 
End Sub 
 
Private Sub vsoWindow_MouseMove(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean) 
 
 Debug.Print "x-position is "; x 
 Debug.Print "y-position is "; y 
 
End Sub 
 
Private Sub vsoWindow_MouseUp(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean) 
 
 If Button = 1 Then 
 
 Debug.Print "Left mouse button released" 
 
 ElseIf Button = 2 Then 
 
 Debug.Print "Right mouse button released" 
 
 ElseIf Button = 16 Then 
 
 Debug.Print "Center mouse button released" 
 
 End If 
 
End Sub

次に、 ThisDocument プロジェクトに次のコードを挿入します。

Dim myMouseListener As MouseListener 
 
Private Sub Document_DocumentSaved(ByVal doc As IVDocument) 
 
 Set myMouseListener = New MouseListener 
 
End Sub 
 
Private Sub Document_BeforeDocumentClose(ByVal doc As IVDocument) 
 
 Set myMouseListener = Nothing 
 
End Sub

図面を保存してクラスを初期化し、アクティブ ウィンドウの任意の場所をクリックして、MouseDown イベントを発生させます。 イミディエイト ウィンドウに、クリックされてイベントが発生したマウス ボタンの名前が表示されます。

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。