Application.MouseUp イベント (Visio)
マウス ボタンを離したときに発生するイベントです。
構文
式。MouseUp (Button, KeyButtonState, x, y, CancelDefault)
expressionApplication オブジェクトを 表す変数。
パラメーター
| 名前 | 必須 / オプション | データ型 | 説明 |
|---|---|---|---|
| Button | 必須 | 長整数型 (Long) | 押されたマウス ボタンが渡されます。 VisKeyButtonFlags では、使用可能な値が宣言されています。 |
| KeyButtonState | 必須 | Long | イベントのマウス ボタンと Shift キーと Ctrl キーの状態。 使用できる値は、 VisKeyButtonFlags で宣言された値の組み合わせです。 たとえば、 KeyButtonState が 9 を返した場合、Ctrl キーを押しながらユーザーがマウスの左ボタンをクリックしたことを示します。 |
| x | 必須 | Double | マウス ポインターの x 座標です。 |
| y | 必須 | Double | マウス ポインターの y 座標です。 |
| CancelDefault | 必須 | ブール型 (Boolean) | Microsoft Visio がこのイベントから受け取ったメッセージを処理する必要がある場合は False、それ以外の場合は True です。 |
注釈
CancelDefault を True に設定すると、マウス ボタンがクリックされたときに受け取ったメッセージは処理されません。
他の Visio イベントとは異なり、 MouseUp にはプレフィックス Query はありませんが、クエリ イベントです。 つまり、CancelDefault を True に設定するか、VisEventProc メソッドを使用してイベントを処理する場合は、True を返すことで、MouseUp によって送信されたメッセージの処理を取り消すことができます。 詳細については、この『Visio オートメーション リファレンス』の VisEventProc メソッドとクエリ イベント (QueryCancelSuspend イベントなど) のトピックを参照してください。
Microsoft Visual Basic または Visual Basic for Applications (VBA) を使用している場合、このトピックの構文を使用して、イベントを一般的な方法で効率的に処理できます。
独自の Event オブジェクトを作成する場合は、Add メソッドまたは AddAdvise メソッドを使用します。
アドオンを実行する Event オブジェクトを作成するには、EventList コレクションに対して Add メソッドを使用します。
通知を受け取る Event オブジェクトを作成するには、AddAdvise メソッドを使用します。
作成するイベントのイベント コードについては、「イベント コード」を参照してください。
例
次のクラス モジュールは、MouseListener という名前のシンク クラスを定義する方法を示しており、作業中のウィンドウでのマウス操作によって発生したイベントをリッスンします。 このクラス モジュールでは、WithEvents キーワードを使用してオブジェクト変数 vsoWindow が宣言されています。 クラス モジュールには、 MouseDown、 MouseMove、 および MouseUp イベントのイベント ハンドラーも含まれています。
この例を実行するには、VBA プロジェクトに新しいクラス モジュールを挿入し、 MouseListener という名前を付けて、モジュールに次のコードを挿入します。
Dim WithEvents vsoWindow As Visio.Window
Private Sub Class_Initialize()
Set vsoWindow = ActiveWindow
End Sub
Private Sub Class_Terminate()
Set vsoWindow = Nothing
End Sub
Private Sub vsoWindow_MouseDown(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean)
If Button = 1 Then
Debug.Print "Left mouse button clicked"
ElseIf Button = 2 Then
Debug.Print "Right mouse button clicked"
ElseIf Button = 16 Then
Debug.Print "Center mouse button clicked"
End If
End Sub
Private Sub vsoWindow_MouseMove(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean)
Debug.Print "x-position is "; x
Debug.Print "y-position is "; y
End Sub
Private Sub vsoWindow_MouseUp(ByVal Button As Long, ByVal KeyButtonState As Long, ByVal x As Double, ByVal y As Double, CancelDefault As Boolean)
If Button = 1 Then
Debug.Print "Left mouse button released"
ElseIf Button = 2 Then
Debug.Print "Right mouse button released"
ElseIf Button = 16 Then
Debug.Print "Center mouse button released"
End If
End Sub
次に、 ThisDocument プロジェクトに次のコードを挿入します。
Dim myMouseListener As MouseListener
Private Sub Document_DocumentSaved(ByVal doc As IVDocument)
Set myMouseListener = New MouseListener
End Sub
Private Sub Document_BeforeDocumentClose(ByVal doc As IVDocument)
Set myMouseListener = Nothing
End Sub
クラスを初期化するためにドキュメントを保存し、アクティブウィンドウ内の任意の場所をクリックして MouseUp イベントを発生させます。 イミディエイト ウィンドウに、クリックされてイベントが発生したマウス ボタンの名前が表示されます。
サポートとフィードバック
Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。