Application.Name プロパティ (Visio)

  • [アーティクル]

オブジェクトの名前を指定します。 読み取り専用です。

構文

式。名前

expressionApplication オブジェクトを 表す変数。

戻り値

文字列

注釈

Document オブジェクトの Name プロパティは取得できますが、設定できません。 図面にまだ名前が付いていない場合、このプロパティは Drawing1 または Stencil1 など、図面の仮の名前を返します。

Addon オブジェクトまたは Font オブジェクトの Name プロパティは取得できますが、設定できません。

Cell オブジェクトの Name プロパティは取得できますが、設定することはできません。 一部のセルは名前付き行に含まれています。 RowName プロパティを使用して、名前付き行の名前を取得して設定できます。

Style オブジェクトが既定の Microsoft Office Visio スタイル以外のスタイルを表している場合は、その Name プロパティを設定できます。 既定の Visio スタイルの Name プロパティを設定しようとするとエラーが発生します。

セルにはローカル名と汎用名の両方があります。 ローカル名は、ユーザーのシステムに Microsoft Windows をインストールしたときの使用言語によって異なります。 汎用名はインストールされた使用言語に関係なく同じです。 セルの汎用名を取得するには、Name プロパティを使用します。 ローカル名を取得するには、LocalName プロパティを使用します。

注:

Microsoft Visio 2000 以降では、ローカル名とユニバーサル名の両方を使用して、Visio の図形、マスター、ドキュメント、ページ、行、アドオン、セル、ハイパーリンク、スタイル、フォント、マスター ショートカット、UI オブジェクト、レイヤーを参照できます。 たとえば、ユーザーが図形に名前を付けると、ユーザーはローカル名を指定します。 Visio 2003 以降、シェイプシート スプレッドシートには、セルの数式と値にユニバーサル名のみが表示されます。 (以前のバージョンでは、ユニバーサル名はユーザー インターフェイスに表示されませんでした)。

汎用名をプログラム内で使用すると、ソリューションをローカライズするたびに名前を変更する必要がなくなります。 Hyperlink、Layer、Master、MasterShortcut、Page、Shape、Style、または Row オブジェクトのローカル名を取得または設定するには Name プロパティを使用します。 汎用名を取得または設定するには NameU プロパティを使用します。

例

次の Microsoft Visual Basic for Applications (VBA) マクロは、Name プロパティを使用してレイヤー名を表示する方法を示しています。 さらに、Layer プロパティを使用して特定のレイヤーに対する参照を取得し、LayerCount プロパティを使用して図形が割り当てられているレイヤー数を判別します。

 
Public Sub Name_Example() 
 
 Dim vsoPage As Visio.Page 
 Dim vsoShape As Visio.Shape 
 Dim vsoLayers As Visio.Layers 
 Dim vsoLayer As Visio.Layer 
 
 If ActiveDocument Is Nothing Then 
 Documents.Add ("") 
 End If 
 
 Set vsoPage = ActivePage 
 If vsoPage Is Nothing Then 
 Set vsoPage = ActiveDocument.Pages(1) 
 End If 
 
 'Draw a rectangle. 
 Set vsoShape = vsoPage.DrawRectangle(1, 5, 5, 1) 
 
 'Get the Layers collection. 
 Set vsoLayers = vsoPage.Layers 
 
 'Create a layer named ExampleLayer1 and add the shape to it. 
 Set vsoLayer = vsoLayers.Add("ExampleLayer1") 
 vsoLayer.Add vsoShape, 1 
 
 'Create a layer named ExampleLayer2 and add the shape to it. 
 Set vsoLayer = vsoLayers.Add("ExampleLayer2") 
 vsoLayer.Add vsoShape, 1 
 
 'Verify that the shape has been assigned to 2 layers. 
 Debug.Print "The page has " & vsoShape.LayerCount & " layers." 
 
 'Get a reference to the first layer. 
 Set vsoLayer = vsoShape.Layer(1) 
 
 'Verify by using the Name property. 
 Debug.Print "Current vsoLayer name is """ & vsoLayer.Name & ".""" 
 
End Sub

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。