Selection.BoundingBox メソッド (Visio)

選択範囲の図形を隙間なく囲む四角形を返します。

構文

expression. BoundingBox( _Flags_ , _lpr8Left_ , _lpr8Bottom_ , _lpr8Right_ , _lpr8Top_ )

式Selection オブジェクトを表す変数。

パラメーター

戻り値

なし

解説

Shape オブジェクトの場合、BoundingBox メソッドによって、指定した図形とその下位図形を隙間なく囲む四角形が返されます。

Page オブジェクト、Master オブジェクト、または Selection オブジェクトの場合は、BoundingBox メソッドによって、指定したページ、マスター シェイプ、または選択範囲内の複数の図形とその下位図形を隙間なく囲む四角形が返されます。

BoundingBox メソッドがエラーを返す場合、または 0 個の図形を囲む四角形を返すように求められた場合、返される四角形は {left: 0、bottom: 0、right: -1、top: -1 } です。それ以外の場合、返される四角形の左が (<=) 右以下で、下が (<=) top 以下になります。 返される数値は、内部単位 (インチ) 単位です。

このメソッドによって返される各図形の境界を表す四角形は、その図形の Type プロパティによって異なります。

オブジェクト タイプが visTypeDoc の場合はメソッドにより例外が発生します。

引数 Flags には、図形ごとに取得する境界ボックスを制御するビットが含まれます。 次の表に示すビットを複数設定すると、図形に適用される四角形は、ビットで指定した条件をすべて満たす四角形になります。

範囲の四角形は、図形のストロークの中心に基づいて決定され、ストロークの幅は考慮されません。 またその四角形には、影や線の端点マーカーによって表される領域も含まれません。 Microsoft Office Visio には、図形の "黒い点" のボックス、つまりストロークの幅、影、線の端点などを考慮して調整された範囲ボックスを作成する機能がありません。

図形には、図形によって報告される境界の四角形の外側にあるコントロール ポイントまたは接続ポイントを含めることができます。 図形のセルの結果を照会することで、コントロール ポイントと接続ポイントの位置を決定できます。

例

次のプロシージャは、選択した図形の境界ボックスの寸法をイミディエイト ウィンドウに出力します。 アクティブなウィンドウで複数の図形が選択された場合は、エラーを示すメッセージ ボックスが表示されます。 いずれの場合も、結果は図形が属するページまたはマスター シェイプの図面単位で返されます。 つまり、図形がグループに属する場合は、visBBoxDrawingCoords がフラグとして BoundingBox メソッドに渡されます。

図形がガイドである場合は、プロシージャから visBBoxIncludeGuides メソッドに BoundingBox が渡され、図形に範囲があると解釈されます。 図形に対して次の 3 つの長方形が返されます。

• visBBoxUprightWH : 図形の幅と高さのボックスを囲む直立したボックス

• visBBoxUprightText : 図形のテキスト ボックスを囲む直立ボックス

• visBBoxExtents : 図形のパスを囲む直立ボックス

このマクロを実行するには、Visio 図面ページで必ず 1 つの図形を選択するようにします。

 
Public Sub BoundingBox_Example() 
 
 Dim vsoSelection As Visio.Selection 
 Set vsoSelection = ActiveWindow.Selection 
 vsoSelection.IterationMode = visSelModeSkipSub 
 
 If vsoSelection.Count <> 1 Then 
 MsgBox "BoundingBox_Example() expects exactly one selected shape." 
 
 Else 
 
 Dim vsoShape As Visio.Shape 
 Set vsoShape = vsoSelection(1) 
 Dim intFlags As Integer 
 intFlags = 0 
 
 If vsoShape.ContainingShape.Type = visTypeGroup Then 
 
 intFlags = visBBoxDrawingCoords 
 
 End If 
 
 If vsoShape.Type = visTypeGuide Then 
 
 intFlags = intFlags + visBBoxIncludeGuides 
 
 End If 
 
 Dim dblTop As Double 
 Dim dblBottom As Double 
 Dim dblLeft As Double 
 Dim dblRight As Double 
 
 vsoShape.BoundingBox intFlags + visBBoxUprightWH, dblLeft, dblBottom, dblRight, dblTop 
 Debug.Print "Upright WH "; _ 
 "dblLeft:" & Application.FormatResult(dblLeft, "in", "", "#0.00 u"); _ 
 "dblBottom:" & Application.FormatResult(dblBottom, "in", "", "#0.00 u"); _ 
 "dblRight:" & Application.FormatResult(dblRight, "in", "", "#0.00 u"); _ 
 "dblTop:" & Application.FormatResult(dblTop, "in", "", "#0.00 u") 
 
 vsoShape.BoundingBox intFlags + visBBoxUprightText, dblLeft, dblBottom, dblRight, dblTop 
 Debug.Print "Upright text "; _ 
 "dblLeft:" & Application.FormatResult(dblLeft, "in", "", "#0.00 u"); _ 
 "dblBottom:" & Application.FormatResult(dblBottom, "in", "", "#0.00 u"); _ 
 "dblRight:" & Application.FormatResult(dblRight, "in", "", "#0.00 u"); _ 
 "dblTop:" & Application.FormatResult(dblTop, "in", "", "#0.00 u") 
 
 vsoShape.BoundingBox intFlags + visBBoxExtents, dblLeft, dblBottom, dblRight, dblTop 
 Debug.Print "Bounding Box "; _ 
 "dblLeft:" & Application.FormatResult(dblLeft, "in", "", "#0.00 u"); _ 
 "dblBottom:" & Application.FormatResult(dblBottom, "in", "", "#0.00 u"); _ 
 "dblRight:" & Application.FormatResult(dblRight, "in", "", "#0.00 u"); _ 
 "dblTop:" & Application.FormatResult(dblTop, "in", "", "#0.00 u") 
 
 End If 
 
End Sub

次のマクロは、BoundingBox メソッドと ShapesOverlap() 関数を使用して、ある図形 (vsoShape2) がもう 1 つの図形 (vsoShape1) の上に重なって表示されているかどうかを判別します。

Public Sub OverlappingShapes_Example() 
 
 Dim vsoShape1 As Visio.Shape 
 Dim vsoShape2 As Visio.Shape 
 Dim blsIsOverlapping As Boolean 
 
 
 Set vsoShape1 = Application.ActiveWindow.Page.Drop(Application.Documents.Item("BASIC_U.VSS").Masters.ItemU("Square"), 3, 9) 
 
 Set vsoShape2 = Application.ActiveWindow.Page.Drop(Application.Documents.Item("BASIC_U.VSS").Masters.ItemU("Pentagon"), 3, 8) 
 
 blsIsOverlapping = ShapesOverlap(vsoShape2, vsoShape1) 
 
 If blsIsOverlapping Then 
 Debug.Print "Shapes overlap." 
 Else 
 Debug.Print "Shapes don't overlap." 
 End If 
 
End Sub 
 
 
Private Function ShapesOverlap(vsoShape1 As IVShape, vsoShape2 As IVShape) As Boolean 
 
 Dim dblLeft1 As Double 
 Dim dblLeft2 As Double 
 Dim dblBottom1 As Double 
 Dim dblBottom2 As Double 
 Dim dblRight1 As Double 
 Dim dblRight2 As Double 
 Dim dblTop1 As Double 
 Dim dblTop2 As Double 
 
 vsoShape1.BoundingBox Flags + visBBoxExtents, dblLeft1, dblBottom1, dblRight1, dblTop1 
 vsoShape2.BoundingBox Flags + visBBoxExtents, dblLeft2, dblBottom2, dblRight2, dblTop2 
 
 If ((dblLeft2 >= dblLeft1 And dblLeft2 <= dblRight1) Or _ 
 (dblRight2 >= dblLeft1 And dblRight2 <= dblRight1)) And _ 
 ((dblTop2 >= dblBottom1 And dblTop2 <= dblTop1) Or _ 
 (dblBottom2 >= dblBottom1 And dblBottom2 <= dblTop1)) Then 
 ShapesOverlap = True 
 Else 
 ShapesOverlap = False 
 End If 
 
End Function

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。