Max プロパティ、Min プロパティ、MaxLength プロパティの例

  • [アーティクル]

次の例では、スタンドアロン ScrollBar で使用する場合の Max プロパティと Min プロパティを示します。 ユーザーは、 Max および Min の値を、-1000 ～ 1000 の範囲の任意の整数に設定できます。 この例では、 MaxLength プロパティを使用して、 Max 値と Min 値に入力される文字数を制限します。

この例を使用するには、以下のサンプル コードをフォームの宣言部分にコピーします。 フォームに次が含まれていることを確認してください。

  • Label1 という名前の ラベル と TextBox1 という名前のテキスト ボックス。
  • Label2 という名前の Label と TextBox2 という名前の TextBox。
  • ScrollBar1 という名前の ScrollBar。
  • Label3 という名前の Label。
Dim TempNum As Integer 
 
Private Sub UserForm_Initialize() 
 Label1.Caption = "Min -1000 to 1000" 
 ScrollBar1.Min = -1000 
 TextBox1.Text = ScrollBar1.Min 
 TextBox1.MaxLength = 5 
 
 Label2.Caption = "Max -1000 to 1000" 
 ScrollBar1.Max = 1000 
 TextBox2.Text = ScrollBar1.Max 
 TextBox2.MaxLength = 5 
 
 ScrollBar1.SmallChange = 1 
 ScrollBar1.LargeChange = 100 
 ScrollBar1.Value = 0 
 Label3.Caption = ScrollBar1.Value 
End Sub 
 
Private Sub TextBox1_Change() 
 If IsNumeric(TextBox1.Text) Then 
 TempNum = CInt(TextBox1.Text) 
 If TempNum >= -1000 And TempNum <= 1000 Then 
 ScrollBar1.Min = TempNum 
 Else 
 TextBox1.Text = ScrollBar1.Min 
 End If 
 Else 
 TextBox1.Text = ScrollBar1.Min 
 End If 
End Sub 
 
Private Sub TextBox2_Change() 
 If IsNumeric(TextBox2.Text) Then 
 TempNum = CInt(TextBox2.Text) 
 If TempNum >= -1000 And TempNum <= 1000 Then 
 ScrollBar1.Max = TempNum 
 Else 
 TextBox2.Text = ScrollBar1.Max 
 End If 
 Else 
 TextBox2.Text = ScrollBar1.Max 
 End If 
End Sub 
 
Private Sub ScrollBar1_Change() 
Label3.Caption = ScrollBar1.Value 
End Sub

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。