sp_describe_cursor (Transact-SQL)

サーバー カーソルの属性をレポートします。

Transact-SQL 構文表記規則

構文

sp_describe_cursor [ @cursor_return = ] output_cursor_variable OUTPUT 
     { [ , [ @cursor_source = ] N'local'
    , [ @cursor_identity = ] N'local_cursor_name' ] 
   | [ , [ @cursor_source = ] N'global'
    , [ @cursor_identity = ] N'global_cursor_name' ] 
   | [ , [ @cursor_source = ] N'variable'
     , [ @cursor_identity = ] N'input_cursor_variable' ] 
     } 

引数

[ @cursor_return = ] output_cursor_variable OUTPUT

カーソル出力を受け取るように宣言したカーソル変数の名前です。output_cursor_variable のデータ型は cursor で、既定値はありません。sp_describe_cursor の呼び出し時には、この名前をどのカーソルにも関連付けないでください。スクロール可能で動的な読み取り専用カーソルが返されます。

[ @cursor_source = ] { N'local' | N'global' | N'variable' }

レポート対象のカーソルをローカル カーソル、グローバル カーソル、カーソル変数のどの名前で指定するのかを指定します。このパラメータのデータ型は nvarchar(30) です。

[ @cursor_identity = ] N'local_cursor_name' ]

LOCAL キーワードを指定した DECLARE CURSOR ステートメント、または既定値が LOCAL になっている DECLARE CURSOR ステートメントによって作成されたカーソルの名前を指定します。local_cursor_name のデータ型は nvarchar(128) です。

[ @cursor_identity = ] N'global_cursor_name' ]

GLOBAL キーワードを指定した DECLARE CURSOR ステートメント、または既定値が GLOBAL になっている DECLARE CURSOR ステートメントによって作成されたカーソルの名前を指定します。global_cursor_name のデータ型は nvarchar(128) です。

global_cursor_name には、ODBC アプリケーションによってオープンされた API サーバー カーソルの名前も指定できます。この ODBC アプリケーションでは、SQLSetCursorName を呼び出すことによってカーソルが指定されます。

[ @cursor_identity = ] N'input_cursor_variable' ]

オープン カーソルに関連付けられたカーソル変数の名前を指定します。input_cursor_variable のデータ型は nvarchar(128) です。

解説

sp_describe_cursor は、カーソルがスクロール可能かどうか、更新可能かどうかなど、サーバー カーソルのグローバルな属性を説明します。カーソルから返された結果セットの属性の説明が必要な場合は、sp_describe_cursor_columns を使用します。カーソルが参照するベース テーブルのレポートが必要な場合は、sp_describe_cursor_tables を使用します。接続時に可視である Transact-SQL Server カーソルのレポートが必要な場合は、sp_cursor_list を使用します。

DECLARE CURSOR ステートメントは、SQL Server が DECLARE CURSOR ステートメントに含まれる SELECT ステートメントでサポートしていないカーソルの種類を要求する場合があります。SQL Server は、SELECT ステートメントでサポートする種類のカーソルに暗黙的に変換します。DECLARE CURSOR ステートメント内で TYPE_WARNING を指定した場合、SQL Server は変換の完了を知らせる情報メッセージをアプリケーションに送ります。sp_describe_cursor を呼び出して、インプリメントされたカーソルの種類を調べることができます。

権限

public ロールのメンバシップが必要です。

戻り値

なし

返されるカーソル

sp_describe_cursor は、その結果セットを Transact-SQL の cursor 型出力パラメータとしてカプセル化します。このため、Transact-SQL バッチ、ストアド プロシージャ、およびトリガは一度に 1 行ずつ、出力を処理できます。また、データベース API 関数からプロシージャを直接呼び出すことができなくなります。cursor 型出力パラメータはプログラム変数にバインドする必要がありますが、API では cursor 型パラメータまたは変数のバインドがサポートされません。

次の表に、sp_describe_cursor が返すカーソルの形式を示します。カーソルの形式は、sp_cursor_list を使用した場合に返される形式と同じです。

例

次の例では、グローバル カーソルをオープンし、sp_describe_cursor を使用してカーソルの属性をレポートします。

USE AdventureWorks;
GO
-- Declare and open a global cursor.
DECLARE abc CURSOR STATIC FOR
SELECT LastName
FROM Person.Contact

OPEN abc

-- Declare a cursor variable to hold the cursor output variable
-- from sp_describe_cursor.
DECLARE @Report CURSOR

-- Execute sp_describe_cursor into the cursor variable.
EXEC master.dbo.sp_describe_cursor @cursor_return = @Report OUTPUT,
        @cursor_source = N'global', @cursor_identity = N'abc'

-- Fetch all the rows from the sp_describe_cursor output cursor.
FETCH NEXT from @Report
WHILE (@@FETCH_STATUS <> -1)
BEGIN
    FETCH NEXT from @Report
END

-- Close and deallocate the cursor from sp_describe_cursor.
CLOSE @Report
DEALLOCATE @Report
GO

-- Close and deallocate the original cursor.
CLOSE abc
DEALLOCATE abc
GO

参照

関連項目

CURSOR_STATUS (Transact-SQL)
DECLARE CURSOR (Transact-SQL)
sp_cursor_list (Transact-SQL)
sp_describe_cursor_columns (Transact-SQL)
sp_describe_cursor_tables (Transact-SQL)

その他の技術情報

カーソル (データベース エンジン)

ヘルプおよび情報

SQL Server 2005 の参考資料の入手