LIKE (Transact-SQL)

指定された文字列が指定されたパターンと一致するかどうかを判断します。パターンは、標準の文字とワイルドカード文字を含むことができます。パターン検索時に、標準の文字は文字列に指定された文字と正確に一致する必要があります。しかし、ワイルドカード文字は文字列の任意の部分と一致することができます。= や != などの文字列比較演算子を使用する場合と比べて、ワイルドカード文字を使用する方がより柔軟に LIKE 演算子を使用できます。引数が文字列データ型でない場合、SQL Server 2005 データベース エンジン は可能な限り文字列データ型に変換します。

Transact-SQL 構文表記規則

構文

match_expression [ NOT ] LIKE pattern [ ESCAPE escape_character ]

引数

match_expression

文字型の任意の有効な式です。

pattern

match_expression で検索する特定の文字列であり、次の有効なワイルドカード文字を含めることができます。pattern は、最大 8,000 バイトにすることができます。

escape_character

特定のワイルドカードがワイルドカードとしてではなく標準の文字として解釈されるようにするために、そのワイルドカードの前に配置される文字です。escape_character は、既定値を持たない文字式であり、1 文字に評価される必要があります。

戻り値の型

Boolean

解説

LIKE を使用して文字列の比較を行うときは、パターン文字列中のすべての文字が比較の対象になります。これには、パターンの先頭の空白や後続する空白も含まれます。クエリ内の比較で LIKE 'abc ' 文字列 (abc に空白が 1 つ続く) を含むすべての行が返される場合、列の値が"abc" (abc の後ろに空白がない) の行は返されません。ただし、パターンが一致する式の中の後続する空白は無視されます。クエリ内の比較で LIKE 'abc' 文字列 (abc の後ろに空白がない) を含むすべての行が返される場合、"abc" で始まり、0 または空白が後続するすべての行が返されます。

char および varchar データのパターンを使用した文字列比較では、データの格納方法に制約があるため、LIKE 比較を渡すことができません。各データ型の格納方法や、LIKE 比較ができない場合について理解しておく必要があります。次の例では、ローカル変数 char をストアド プロシージャに渡し、パターン検索を使用して、姓が指定された文字列で始まるすべての従業員を検索します。

USE AdventureWorks;
GO
CREATE PROCEDURE FindEmployee @EmpLName char(20)
AS
SELECT @EmpLName = RTRIM(@EmpLName) + '%';
SELECT c.FirstName, c.LastName, a.City
FROM Person.Contact c JOIN Person.Address a ON c.ContactID = a.AddressID
WHERE c.LastName LIKE @EmpLName;
GO
EXEC FindEmployee @EmpLName = 'Barb';
GO

FindEmployee プロシージャでは、20 文字未満の名前の場合、必ず char 変数 (@EmpLName) に後続する空白が含まれるため、行は返されません。LastName 列は varchar であるため、後続する空白は含まれていません。後続する空白が意味を持つため、このプロシージャは失敗します。

次の例では、後続する空白は varchar 変数に追加されないので、検索は成功します。

USE AdventureWorks;
GO
CREATE PROCEDURE FindEmployee @EmpLName varchar(20)
AS
SELECT @EmpLName = RTRIM(@EmpLName) + '%';
SELECT c.FirstName, c.LastName, a.City
FROM Person.Contact c JOIN Person.Address a ON c.ContactID = a.AddressID
WHERE c.LastName LIKE @EmpLName;
GO
EXEC FindEmployee @EmpLName = 'Barb';

以下に結果セットを示します。 

FirstName         LastName              City       
---------- ----------------------------------------
Angela             Barbariol            Snohomish
David              Barber               Snohomish

(2 row(s) affected)

LIKE を使用するパターン検索

LIKE では、ASCII パターン検索と Unicode パターン検索を行えます。すべての引数 (match_expression、pattern、および escape_character) が ASCII 文字型の場合は、ASCII パターン検索が行われます。引数のいずれかが Unicode データ型の場合は、すべての引数が Unicode に変換され、Unicode パターン検索が行われます。LIKE で Unicode データ (nchar または nvarchar 型) を使用する場合、後続する空白は意味を持ちます。しかし、Unicode 以外のデータの場合、後続する空白は意味を持ちません。Unicode LIKE は、SQL-92 標準と互換性があります。ASCII LIKE は、以前のバージョンの SQL Server と互換性があります。

次の一連の例では、ASCII LIKE パターン検索と Unicode LIKE パターン検索で返される行の違いを示します。

-- ASCII pattern matching with char column
CREATE TABLE t (col1 char(30));
INSERT INTO t VALUES ('Robert King');
SELECT * 
FROM t 
WHERE col1 LIKE '% King'   -- returns 1 row

-- Unicode pattern matching with nchar column
CREATE TABLE t (col1 nchar(30));
INSERT INTO t VALUES ('Robert King');
SELECT * 
FROM t 
WHERE col1 LIKE '% King'   -- no rows returned

-- Unicode pattern matching with nchar column and RTRIM
CREATE TABLE t (col1 nchar (30));
INSERT INTO t VALUES ('Robert King');
SELECT * 
FROM t 
WHERE RTRIM(col1) LIKE '% King'   -- returns 1 row

メモ :
LIKE 比較は、照合順序の影響を受けます。詳細については、「COLLATE (Transact-SQL)」を参照してください。

% ワイルドカード文字の使用

LIKE '5%' と指定すると、データベース エンジン は数字の 5 を先頭に 0 個以上の文字が続く文字列を検索します。

たとえば、次のクエリは、AdventureWorks データベース内のすべての動的管理ビューを表示します。これらのすべての動的管理ビューは、文字 dm で始まるためです。

USE AdventureWorks;
GO
SELECT Name
FROM sys.system_views
WHERE Name LIKE 'dm%';
GO

動的管理ビュー以外のすべてのオブジェクトを表示するには、NOT LIKE 'dm%' を使用します。仮に、オブジェクトの総数が 32、LIKE パターンに一致する名前が 13 件発見されるとすると、NOT LIKE では、LIKE パターンに一致しないオブジェクトを 19 件発見します。

LIKE '[^d][^m]%' のようなパターンと一致する名前が検索されるとは限りません。NOT LIKE の 19 件に対して、このパターンでは 14 件しか検索できません。d で始まる名前、または 2 文字目が m の名前は、すべて結果および動的管理ビュー名から削除されます。これは、否定ワイルドカード文字を使用した検索文字列は 1 文字ずつ順番に評価されるために生じます。評価のいずれかの段階で一致しなければ、削除されます。

リテラルとしてのワイルドカード文字の使用

ワイルドカード パターン検索文字をリテラル文字として使用できます。ワイルドカード文字をリテラル文字として使用するには、ワイルドカード文字をかっこで囲みます。次の表は、LIKE キーワードと [ ] ワイルドカード文字の使用例を示しています。

ESCAPE 句を使用するパターン検索

1 文字以上の特殊なワイルドカード文字を含む文字列を検索できます。たとえば、customers データベース内の discounts テーブルには、パーセント記号 (%) を含む割引の値が格納されています。ワイルドカード文字ではなく、文字としてパーセント記号を検索するには、ESCAPE キーワードとエスケープ文字を指定する必要があります。たとえば、サンプル データベースには、"30%" というテキストを含んでいる comment という名前の列があります。comment 列内の任意の場所で文字列 "30%" を含んでいる任意の行を検索するには、WHERE comment LIKE '%30!%%' ESCAPE '!' などの WHERE 句を指定します。ESCAPE とエスケープ文字を指定していない場合、データベース エンジン は文字列 "30" を含む行を返します。

LIKE パターンでエスケープ文字の後に文字がない場合、そのパターンは無効になり、LIKE は FALSE を返します。エスケープ文字の後にある文字がワイルドカード文字ではない場合、このパターンの中ではエスケープ文字は破棄され、エスケープ文字の次の文字が通常の文字として扱われます。これには、2 つの角かっこ ([ ]) に囲まれたパーセント記号 (%)、アンダースコア (_)、および左角かっこ ([) の各ワイルドカード文字が含まれます。また、2 つの角かっこ ([ ]) で囲んだ場合は、エスケープ文字は使用することができ、カレット (^)、ハイフン (-)、および右角かっこ (]) はエスケープできます。

戻り値

match_expression が、指定された pattern と一致する場合、LIKE は TRUE を返します。

例

A. LIKE を % ワイルドカード文字と共に使用する

次の例では、Contact テーブルで市外局番 415 を持つすべての電話番号を検索します。

USE AdventureWorks;
GO
SELECT FirstName, LastName, Phone
FROM Person.Contact
WHERE phone LIKE '415%'
ORDER by LastName;
GO

以下に結果セットを示します。 

FirstName               LastName              phone
-----------------       ----------------      ------------
Ruben                   Alonso                415-555-0124
Shelby                  Cook                  415-555-0121
Karen                   Hu                    415-555-0114
John                    Long                  415-555-0147
David                   Long                  415-555-0123
Gilbert                 Ma                    415-555-0138
Meredith                Moreno                415-555-0131
Alexandra               Nelson                415-555-0174
Taylor                  Patterson             415-555-0170
Gabrielle               Russell               415-555-0197
Dalton                  Simmons               415-555-0115

(11 row(s) affected)

B. NOT LIKE を % ワイルドカード文字と共に使用する

次の例では、Contact テーブルで 415 以外の市外局番を持つすべての電話番号を検索します。

USE AdventureWorks;
GO
SELECT FirstName, LastName, Phone
FROM Person.Contact
WHERE Phone NOT LIKE '415%' AND FirstName = 'Gail'
ORDER BY LastName;
GO

以下に結果セットを示します。 

FirstName              LastName         Phone
---------              ----------       -------------------
Gail                   Alexander        1 (11) 500 555-0120
Gail                   Butler           1 (11) 500 555-0191
Gail                   Erickson         834-555-0132
Gail                   Erickson         849-555-0139
Gail                   Griffin          450-555-0171
Gail                   Moore            155-555-0169
Gail                   Russell          334-555-0170
Gail                   Westover         305-555-0100

(8 row(s) affected)

C. ESCAPE 句を使用する

次の例では、ESCAPE 句とエスケープ文字を使用して、mytbl2 テーブルの列 c1 内にある文字列 10-15% と完全に一致する文字列を検索します。

USE tempdb;
GO
IF EXISTS(SELECT TABLE_NAME FROM INFORMATION_SCHEMA.TABLES
      WHERE TABLE_NAME = 'mytbl2')
   DROP TABLE mytbl2;
GO
USE tempdb;
GO
CREATE TABLE mytbl2
(
 c1 sysname
);
GO
INSERT mytbl2 VALUES ('Discount is 10-15% off');
INSERT mytbl2 VALUES ('Discount is .10-.15 off');
GO
SELECT c1 
FROM mytbl2
WHERE c1 LIKE '%10-15!% off%' ESCAPE '!';
GO

D. [ ] ワイルドカード文字を使用する

次の例では、Cheryl または Sheryl という名を持つ Contacts を検索します。

USE AdventureWorks;
GO
SELECT ContactID, FirstName, LastName 
FROM Person.Contact 
WHERE FirstName LIKE '[CS]heryl';
GO

次の例では、姓が Zheng または Zhang である Contacts の行を検索します。

USE AdventureWorks;
GO
SELECT LastName, FirstName, Phone
FROM Person.Contact
WHERE LastName LIKE 'Zh[ae]ng'
ORDER BY LastName ASC, FirstName ASC;
GO

参照

関連項目

式 (Transact-SQL)
関数 (Transact-SQL)
SELECT (Transact-SQL)
WHERE (Transact-SQL)

ヘルプおよび情報

SQL Server 2005 の参考資料の入手