• [アーティクル]

マージ アーティクルに対してパラメーター化した行フィルターを定義および変更する方法 (レプリケーション Transact-SQL プログラミング)

テーブル アーティクルを作成する際には、パラメーター化された行フィルターを使用できます。このフィルターでは WHERE 句を使用して、パブリッシュする適切なデータを選択します。静的行フィルターのように句でリテラル値を指定するのではなく、システム関数である SUSER_SNAME または HOST_NAME の一方、あるいは両方を指定します。詳細については、「パラメーター化された行フィルター」を参照してください。パラメーター化された行フィルターは、レプリケーション ストアド プロシージャを使用してプログラムから作成し、変更できます。

マージ パブリケーション内のアーティクルにパラメーター化された行フィルターを定義するには

  • パブリッシャー側のパブリケーション データベースに対して、sp_addmergearticle (Transact-SQL) を実行します。@publication を指定し、アーティクルの名前を @article に、パブリッシュするテーブルを @source_object に、パラメーター化されたフィルターを定義する WHERE 句 (WHERE は含めません) を @subset_filterclause に指定します。@partition_options に次のいずれかの値を指定します。これにより、パラメーター化された行フィルターによって行われるパーティション分割の種類が指定されます。

    • 0 - アーティクルのフィルター選択が静的であるか、各パーティションに対して一意なデータのサブセットは生成されません ("重複する" パーティション)。

    • 1 - 生成されるパーティションは重複しており、サブスクライバーでの更新によって行が属しているパーティションを変更することはできません。

    • 2 - アーティクルのフィルター選択によって重複しないパーティションが生成されますが、複数のサブスクライバーが同じパーティションを受け取ることができます。

    • 3 - アーティクルのフィルター選択によって、各サブスクリプションで一意な重複しないパーティションが生成されます。

マージ パブリケーション内のアーティクルに適用するパラメーター化された行フィルターを変更するには

  1. パブリッシャーのパブリケーション データベースに対して、sp_changemergearticle を実行します。@publication と @article を指定し、subset_filterclause を @property に、パラメーター化されたフィルターを定義する式 (WHERE は含めません) を @value に指定し、@force_invalidate_snapshot および @force_reinit_subscription に 1 を指定します。

  2. この変更によって別のパーティション分割が発生した場合、sp_changemergearticle を再び実行します。@publication と @article を指定し、partition_options を @property に指定します。次の中から最も適切なパーティション分割オプションを @value に指定します。

    • 0 - アーティクルのフィルター選択が静的であるか、各パーティションに対して一意なデータのサブセットは生成されません ("重複する" パーティション)。

    • 1 - 生成されるパーティションは重複しており、サブスクライバーでの更新によって行が属しているパーティションを変更することはできません。

    • 2 - アーティクルのフィルター選択によって重複しないパーティションが生成されますが、複数のサブスクライバーが同じパーティションを受け取ることができます。

    • 3 - アーティクルのフィルター選択によって、各サブスクリプションで一意な重複しないパーティションが生成されます。

使用例

次の例では、Employee テーブルに対して一連の結合フィルターを使用してアーティクルがフィルター選択されるマージ パブリケーションで、アーティクルのグループを定義します。このテーブル自体はパラメーター化された行フィルターを LoginID 列に使用してフィルター選択されています。同期の間、HOST_NAME 関数により返される値は上書きされます。詳細については、「パラメーター化された行フィルター」の「HOST_NAME() 値のオーバーライド」を参照してください。

-- To avoid storing the login and password in the script file, the value 
-- is passed into SQLCMD as a scripting variable. For information about 
-- how to use scripting variables on the command line and in SQL Server
-- Management Studio, see the "Executing Replication Scripts" section in
-- the topic "Programming Replication Using System Stored Procedures".

--Add a new merge publication.
DECLARE @publicationdb AS sysname;
DECLARE @publication AS sysname;
DECLARE @table1 AS sysname;
DECLARE @table2 AS sysname;
DECLARE @filter AS sysname;
DECLARE @schema_hr AS sysname;
DECLARE @schema_sales AS sysname;

SET @publicationdb = N'AdventureWorks2008R2';
SET @publication = N'AdvWorksSalesPersonMerge';
SET @table1 = N'Employee';
SET @table2 = N'SalesPerson';
SET @filter = N'SalesPerson_Employee';
SET @schema_hr = N'HumanResources';
SET @schema_sales = N'Sales';

USE [AdventureWorks2008R2];

-- Enable AdventureWorks2008R2 for merge replication.
EXEC sp_replicationdboption
  @dbname = @publicationdb,
  @optname = N'merge publish',
  @value = N'true';  

-- Create new merge publication with Subscriber requested snapshot
-- and using the default agent schedule. 
EXEC sp_addmergepublication 
  @publication = @publication, 
  @description = N'Merge publication of AdventureWorks2008R2.', 
  @allow_subscriber_initiated_snapshot = N'true',
  @publication_compatibility_level = N'90RTM';

-- Create a new snapshot job for the publication, using the default schedule.
-- Pass credentials at runtime using sqlcmd scripting variables.
EXEC sp_addpublication_snapshot 
  @publication = @publication, 
  @job_login = $(login), 
  @job_password = $(password);

-- Add an article for the Employee table, 
-- which is horizontally partitioned using 
-- a parameterized row filter.
EXEC sp_addmergearticle 
  @publication = @publication, 
  @article = @table1, 
  @source_owner = @schema_hr, 
  @source_object = @table1, 
  @type = N'table', 
  @description = 'contains employee information', 
  @subset_filterclause = N'[LoginID] = HOST_NAME()';

-- Add an article for the SalesPerson table, 
-- which is partitioned based on a join filter.
EXEC sp_addmergearticle 
  @publication = @publication, 
  @article = @table2, 
  @source_owner = @schema_sales, 
  @source_object = @table2, 
  @type = N'table', 
  @description = 'contains salesperson information';

-- Add a join filter between the two articles.
EXEC sp_addmergefilter 
  @publication = @publication, 
  @article = @table1, 
  @filtername = @filter, 
  @join_articlename = @table2, 
  @join_filterclause = N'[Employee].[BusinessEntityID] = [SalesPerson].[SalesPersonID]', 
  @join_unique_key = 1, 
  @filter_type = 1;
GO

-- Start the agent job to generate the full snapshot for the publication.
-- The filtered data snapshot is generated automatically the first time 
-- the subscription is synchronized. 
DECLARE @publication AS sysname;
SET @publication = N'AdvWorksSalesPersonMerge';

EXEC sp_startpublication_snapshot 
  @publication = @publication;
GO