SET NOEXEC (Transact-SQL)

構文

SET NOEXEC { ON | OFF }

説明

SET NOEXEC が ON のとき、SQL Server では Transact-SQL ステートメントの各バッチがコンパイルされますが、実行されません。SET NOEXEC が OFF の場合は、すべてのバッチがコンパイル後に実行されます。

SQL Server のステートメントの実行には、コンパイルと実行の 2 つのフェーズがあります。この設定は、SQL Server で実行時に Transact-SQL コード内の構文とオブジェクト名を検証する場合に便利です。また、多数のステートメントで構成されたより大きなバッチ内のステートメントを部分的にデバッグする際にも利用できます。

SET NOEXEC は、解析時ではなく実行時に設定されます。

権限

public ロールのメンバーシップが必要です。

例

次の例では、有効なクエリ、有効でないオブジェクト名を持つクエリ、および無効な構文を持つクエリを使用して、NOEXEC を実行します。

USE AdventureWorks2008R2;
GO
PRINT 'Valid query';
GO
-- SET NOEXEC to ON.
SET NOEXEC ON;
GO
-- Inner join.
SELECT e.BusinessEntityID, e.JobTitle, v.Name
FROM HumanResources.Employee AS e 
   INNER JOIN Purchasing.PurchaseOrderHeader AS poh
   ON e.BusinessEntityID = poh.EmployeeID
   INNER JOIN Purchasing.Vendor AS v
   ON poh.VendorID = v.BusinessEntityID;
GO
-- SET NOEXEC to OFF.
SET NOEXEC OFF;
GO

PRINT 'Invalid object name';
GO
-- SET NOEXEC to ON.
SET NOEXEC ON;
GO
-- Function name uses is a reserved keyword.
USE AdventureWorks2008R2;
GO
CREATE FUNCTION dbo.Values(@BusinessEntityID int)
RETURNS TABLE
AS
RETURN (SELECT PurchaseOrderID, TotalDue
   FROM dbo.PurchaseOrderHeader
   WHERE VendorID = @BusinessEntityID);
   
-- SET NOEXEC to OFF.
SET NOEXEC OFF;
GO

PRINT 'Invalid syntax';
GO
-- SET NOEXEC to ON.
SET NOEXEC ON;
GO
-- Built-in function incorrectly invoked.
SELECT *
FROM fn_helpcollations;
-- Reset SET NOEXEC to OFF.
SET NOEXEC OFF;
GO

関連項目

参照