障害発生時点まで復元する方法 (Transact-SQL)

使用例

この例を実行する前に、次の準備作業を完了する必要があります。

1. AdventureWorks データベースの既定の復旧モデルは、単純復旧モデルです。この復旧モデルでは障害発生時点までの復旧がサポートされていないため、次の ALTER DATABASE ステートメントを実行して、完全復旧モデルが使用されるように AdventureWorks を設定します。

   USE master;
   GO
   ALTER DATABASE AdventureWorks SET RECOVERY FULL;
   

2. 次の BACKUP ステートメントを使用して、このデータベースの完全バックアップを作成します。

   BACKUP DATABASE AdventureWorks TO DISK = 'C:\AdventureWorks_Data.bck';
   

3. 次のように、定期的なログ バックアップを作成します。

   BACKUP LOG AdventureWorks TO DISK = 'C:\AdventureWorks_Log.bck';
   

次の例では、AdventureWorks データベースのログ末尾のバックアップを作成した後に、以前作成したバックアップを復元します (この手順は、ログ ディスクにアクセスできることを前提としています)。

まず、データベースのログ末尾のバックアップを作成して、アクティブなログをキャプチャし、データベースを復元中の状態にしておきます。次に、データベースのバックアップを復元し、以前作成した定期的なログ バックアップを適用し、ログ末尾のバックアップを適用します。最後に、別の手順でデータベースを復旧します。

注意
既定の動作では、最終的なバックアップを復元するステートメントに、データベースの復旧が含まれています。

/* Example of restoring a to the point of failure */
-- Step 1: Create a tail-log backup by using WITH NORECOVERY.
BACKUP LOG AdventureWorks
   TO DISK = 'C:\AdventureWorks_Log.bck'
   WITH NORECOVERY;
GO
-- Step 2: Restore the full database backup.
RESTORE DATABASE AdventureWorks
   FROM DISK = 'C:\AdventureWorks_Data.bck'
   WITH NORECOVERY;
GO
-- Step 3: Restore the first transaction log backup.
RESTORE LOG AdventureWorks
   FROM DISK = 'C:\AdventureWorks_Log.bck'
   WITH NORECOVERY;
GO
-- Step 4: Restore the tail-log backup.
RESTORE LOG AdventureWorks
   FROM  DISK = 'C:\AdventureWorks_Log.bck'
   WITH NORECOVERY;
GO
-- Step 5: Recover the database.
RESTORE DATABASE AdventureWorks
   WITH RECOVERY;
GO

関連項目

参照

概念

その他の技術情報