• [アーティクル]

sp_dropmergearticle (Transact-SQL)

アーティクルをマージ パブリケーションから削除します。このストアド プロシージャは、パブリッシャ側でパブリケーション データベースについて実行されます。

トピック リンク アイコンTransact-SQL 構文表記規則

構文

sp_dropmergearticle [ @publication= ] 'publication'
        , [ @article= ] 'article' 
    [ , [ @ignore_distributor= ] ignore_distributor 
    [ , [ @reserved= ] reserved 
    [ , [ @force_invalidate_snapshot= ] force_invalidate_snapshot ]
    [ , [ @force_reinit_subscription = ] force_reinit_subscription ]
    [ , [ @ignore_merge_metadata = ] ignore_merge_metadata ]

引数

  • [ @publication=] 'publication'
    アーティクルを削除するパブリケーションの名前を指定します。publication のデータ型は sysname で、既定値はありません。

  • [ @article = ] 'article'
    指定したパブリケーションから削除するアーティクルの名前を指定します。article のデータ型は sysname で、既定値はありません。all の場合、指定したマージ パブリケーションにあるすべての既存のアーティクルが削除されます。article に all を指定した場合でも、パブリケーションはアーティクルとは別に削除する必要があります。

  • [ @ignore_distributor =] ignore_distributor
    ディストリビュータに接続せずに、このストアド プロシージャを実行するかどうかを指定します。ignore_distributor のデータ型は bit で、既定値は 0 です。

  • [ @reserved=] reserved
    将来の使用のために予約されています。reserved のデータ型は nvarchar(20) で、既定値は NULL です。

  • [ @force_invalidate_snapshot = ] force_invalidate_snapshot
    スナップショットを無効にする機能を有効または無効にします。force_invalidate_snapshot のデータ型は bit で、既定値は 0 です。

    0 に設定すると、マージ アーティクルへの変更によってスナップショットが無効になることはありません。

    1 に設定すると、マージ アーティクルへの変更によってスナップショットが無効になることがあります。この場合、1 の値によって、新しいスナップショットを作成する権限が与えられます。

  • [ @force_reinit_subscription = ] force_reinit_subscription
    アーティクルを削除したとき、既存のサブスクリプションが必ず再初期化されるようにします。force_reinit_subscription のデータ型は bit で、既定値は 0 です。

    0 の場合は、アーティクルを削除してもサブスクリプションは再初期化されません。

    1 は、アーティクルを削除すると既存のサブスクリプションが再初期化されることを示し、サブスクリプションの再初期化を許可します。

  • [ @ignore_merge_metadata= ] ignore_merge_metadata
    内部使用のみです。

戻り値

成功した場合は 0 を、失敗した場合は 1 をそれぞれ返します。

説明

sp_dropmergearticle は、マージ レプリケーションで使用します。アーティクルの削除の詳細については、「既存のパブリケーションへのアーティクルの追加および削除」を参照してください。

sp_dropmergearticle を実行してパブリケーションからアーティクルを削除しても、パブリケーション データベースからオブジェクトが削除されたり、サブスクリプション データベースから対応するオブジェクトが削除されるわけではありません。必要であれば DROP <object> を使用して、手動でこれらのオブジェクトを削除します。

使用例

DECLARE @publication AS sysname;
DECLARE @table1 AS sysname;
DECLARE @table2 AS sysname;
DECLARE @table3 AS sysname;
DECLARE @salesschema AS sysname;
DECLARE @hrschema AS sysname;
DECLARE @filterclause AS nvarchar(1000);
SET @publication = N'AdvWorksSalesOrdersMerge'; 
SET @table1 = N'Employee'; 
SET @table2 = N'SalesOrderHeader'; 
SET @table3 = N'SalesOrderDetail'; 
SET @salesschema = N'Sales';
SET @hrschema = N'HumanResources';
SET @filterclause = N'Employee.LoginID = HOST_NAME()';

-- Drop the merge join filter between SalesOrderHeader and SalesOrderDetail.
EXEC sp_dropmergefilter 
  @publication = @publication, 
  @article = @table3, 
  @filtername = N'SalesOrderDetail_SalesOrderHeader', 
  @force_invalidate_snapshot = 1, 
  @force_reinit_subscription = 1;

-- Drops the merge join filter between Employee and SalesOrderHeader.
EXEC sp_dropmergefilter 
  @publication = @publication, 
  @article = @table2, 
  @filtername = N'SalesOrderHeader_Employee', 
  @force_invalidate_snapshot = 1, 
  @force_reinit_subscription = 1;

-- Drops the article for the SalesOrderDetail table.
EXEC sp_dropmergearticle 
  @publication = @publication, 
  @article = @table3,
  @force_invalidate_snapshot = 1, 
  @force_reinit_subscription = 1;

-- Drops the article for the SalesOrderHeader table.
EXEC sp_dropmergearticle 
  @publication = @publication, 
  @article = @table2, 
  @force_invalidate_snapshot = 1, 
  @force_reinit_subscription = 1;

-- Drops the article for the Employee table.
EXEC sp_dropmergearticle 
  @publication = @publication, 
  @article = @table1,
  @force_invalidate_snapshot = 1, 
  @force_reinit_subscription = 1;
GO

DECLARE @publication AS sysname;
DECLARE @article1 AS sysname;
DECLARE @article2 AS sysname;
SET @publication = N'AdvWorksSalesOrdersMerge';
SET @article1 = N'SalesOrderDetail'; 
SET @article2 = N'SalesOrderHeader'; 

-- Remove articles from a merge publication.
USE [AdventureWorks]
EXEC sp_dropmergearticle 
  @publication = @publication, 
  @article = @article1,
  @force_invalidate_snapshot = 1;
EXEC sp_dropmergearticle 
  @publication = @publication, 
  @article = @article2,
  @force_invalidate_snapshot = 1;
GO

権限

sp_dropmergearticle を実行できるのは、固定サーバー ロール sysadmin または固定データベース ロール db_owner のメンバだけです。