トレースを作成する方法 (Transact-SQL)
このトピックでは、ストアド プロシージャを使用してトレースを作成する方法について説明します。
トレースを作成するには
必要なパラメータを指定して sp_trace_create を実行し、新しいトレースを作成します。新しいトレースは停止状態 (status の値が 0) になります。
必要なパラメータを指定して sp_trace_setevent を実行し、トレースするイベントおよび列を選択します。
必要に応じて、sp_trace_setfilter を実行し、フィルタまたはフィルタの組み合わせを設定します。
sp_trace_setevent と sp_trace_setfilter は、停止状態の既存のトレースに対してのみ実行できます。
.gif "重要な注意事項")
重要通常のストアド プロシージャとは異なり、すべての SQL Server Profiler ストアド プロシージャ (sp_trace_xx) のパラメータでは、データ型が厳密に定義されており、データ型の自動変換はサポートされていません。引数の記述で指定されている入力パラメータの正しいデータ型でパラメータを呼び出さないと、ストアド プロシージャからエラーが返されます。
使用例
Transact-SQL を使用してトレースを作成するコードを次に示します。トレースの作成、トレース ファイルの設定、およびトレースの停止の、3 つのセクションで構成されています。トレースするイベントを追加して、トレースをカスタマイズしてください。イベントと列の一覧については、「sp_trace_setevent (Transact-SQL)」を参照してください。
次のコードでは、トレースを作成してイベントを追加し、トレースを開始します。
DECLARE @RC int, @TraceID int, @on BIT
EXEC @rc = sp_trace_create @TraceID output, 0, N'C:\SampleTrace'
-- Select the return code to see if the trace creation was successful.
SELECT RC = @RC, TraceID = @TraceID
-- Set the events and data columns you need to capture.
SELECT @on = 1
-- 10 is RPC:Completed event. 1 is TextData column.
EXEC sp_trace_setevent @TraceID, 10, 1, @on
-- 13 is SQL:BatchStarting, 11 is LoginName
EXEC sp_trace_setevent @TraceID, 13, 11, @on
-- 13 is SQL:BatchStarting, 14 is StartTime
EXEC sp_trace_setevent @TraceID, 13, 14, @on
-- 12 is SQL:BatchCompleted, 15 is EndTime
EXEC sp_trace_setevent @TraceID, 12, 15, @on
-- 13 is SQL:BatchStarting, 1 is TextData
EXEC sp_trace_setevent @TraceID, 13, 1, @on
-- Set any filter. Not provided in this example
--EXEC sp_trace_setfilter 1, 10, 0, 6, N'%Profiler%'
-- Start Trace (status 1 = start)
EXEC @RC = sp_trace_setstatus @TraceID, 1
GO
トレースが作成および開始されたので、次のコードを実行して、トレースにアクティビティを設定します。
SELECT * FROM master.sys.databases
GO
SELECT * FROM ::fn_trace_getinfo(default)
GO
トレースは、いつでも停止および再開できます。この例では次のコードを実行して、トレースを停止し、閉じ、トレース定義を削除します。
DECLARE @TraceID int
-- Populate a variable with the trace_id of the current trace
SELECT @TraceID = TraceID FROM ::fn_trace_getinfo(default) WHERE VALUE = N'C:\SampleTrace.trc'
-- First stop the trace.
EXEC sp_trace_setstatus @TraceID, 0
-- Close and then delete its definition from SQL Server.
EXEC sp_trace_setstatus @TraceID, 2
トレース ファイルを調べるには、SQL Server Profiler を使用して SampleTrace.trc ファイルを開きます。