SET XACT_ABORT (Transact-SQL)
Transact-SQL ステートメントによってランタイム エラーが発生した場合に、SQL Server が自動的に現在のトランザクションをロールバックするかどうかを指定します。
.gif "トピック リンク アイコン")
構文
SET XACT_ABORT { ON | OFF }
説明
SET XACT_ABORT が ON の場合は、Transact-SQL ステートメントでランタイム エラーが発生すると、トランザクション全体が終了し、ロールバックされます。
SET XACT_ABORT が OFF の場合は、エラーが発生した Transact-SQL ステートメントのみがロールバックされ、トランザクションの処理は継続される場合があります。SET XACT_ABORT が OFF であっても、エラーの重大度によってはトランザクション全体がロールバックされる場合があります。OFF が既定の設定です。
構文エラーなどのコンパイル エラーは、SET XACT_ABORT の設定の影響を受けません。
SQL Server などのほとんどの OLE DB プロバイダに対する、明示的または暗黙的なトランザクションのデータ変更ステートメントでは、XACT_ABORT は必ず ON にします。このオプションが要求されないのは、入れ子になったトランザクションをプロバイダがサポートしている場合のみです。詳細については、「分散クエリと分散トランザクション」を参照してください。
SET XACT_ABORT は、解析時ではなく実行時に設定されます。
例
次の例では、他の Transact-SQL ステートメントを含むトランザクションで、外部キー違反エラーが発生します。最初のステートメント セットでは、エラーが生成されますが、他のステートメントは正常に実行され、トランザクションは正常にコミットされます。2 番目のステートメントでは、SET XACT_ABORT は ON に設定されます。このため、ステートメント エラーが発生すると、バッチが終了し、トランザクションはロールバックされます。
USE AdventureWorks;
GO
IF OBJECT_ID(N't2', N'U') IS NOT NULL
DROP TABLE t2;
GO
IF OBJECT_ID(N't1', N'U') IS NOT NULL
DROP TABLE t1;
GO
CREATE TABLE t1
(a INT NOT NULL PRIMARY KEY);
CREATE TABLE t2
(a INT NOT NULL REFERENCES t1(a));
GO
INSERT INTO t1 VALUES (1);
INSERT INTO t1 VALUES (3);
INSERT INTO t1 VALUES (4);
INSERT INTO t1 VALUES (6);
GO
SET XACT_ABORT OFF;
GO
BEGIN TRANSACTION;
INSERT INTO t2 VALUES (1);
INSERT INTO t2 VALUES (2); -- Foreign key error.
INSERT INTO t2 VALUES (3);
COMMIT TRANSACTION;
GO
SET XACT_ABORT ON;
GO
BEGIN TRANSACTION;
INSERT INTO t2 VALUES (4);
INSERT INTO t2 VALUES (5); -- Foreign key error.
INSERT INTO t2 VALUES (6);
COMMIT TRANSACTION;
GO
-- SELECT shows only keys 1 and 3 added.
-- Key 2 insert failed and was rolled back, but
-- XACT_ABORT was OFF and rest of transaction
-- succeeded.
-- Key 5 insert error with XACT_ABORT ON caused
-- all of the second transaction to roll back.
SELECT *
FROM t2;
GO