OBJECT_SCHEMA_NAME (Transact-SQL)

  • [アーティクル]

スキーマ スコープ オブジェクトのデータベース スキーマ名を返します。 スキーマ スコープ オブジェクトの一覧については、「sys.objects (Transact-SQL)」を参照してください。

トピック リンク アイコン Transact-SQL 構文表記規則

構文

OBJECT_SCHEMA_NAME ( object_id [, database_id ] )

引数

  • object_id
    使用するオブジェクトの ID を指定します。 object_id のデータ型は int です。指定したデータベース コンテキスト、または現在のデータベース コンテキストのスキーマ スコープ オブジェクトと見なされます。

  • database_id
    オブジェクトを検索するデータベースの ID を指定します。 database_id のデータ型は int です。

戻り値の型

sysname

例外

エラーが発生した場合、または呼び出し元にオブジェクトの表示権限がない場合は、NULL が返されます。 呼び出し先データベースの AUTO_CLOSE オプションが ON に設定されている場合、データベースが開きます。

ユーザーが所有しているか、または権限を与えられている、セキュリティ保護可能なリソースのメタデータのみを表示できます。 つまり、オブジェクトに対する権限がユーザーに与えられていない場合、メタデータを生成する組み込み関数 (OBJECT_SCHEMA_NAME など) が NULL を返す可能性があります。 詳細については、「メタデータ表示の構成」を参照してください。

権限

オブジェクトに対する ANY 権限が必要です。 データベース ID を指定するには、そのデータベースの CONNECT 権限を持っているか、ゲスト アカウントが有効である必要があります。

説明

システム関数は、選択リストの中、WHERE 句の中、また、式を使える所ならどこにでも使用できます。 詳細については、「式」および「WHERE」を参照してください。

このシステム関数が返す結果セットには、現在のデータベースの照合順序が使用されます。

database_id を指定しない場合は、object_id が現在のデータベース コンテキストにあると見なされます。 別のデータベースにある object_id を参照するクエリでは、NULL または不適切な結果が返されます。 たとえば、次のクエリでは、現在のデータベースのコンテキストは AdventureWorks です。 データベース エンジンは、クエリの FROM 句に指定されたデータベースではなく、このデータベースの指定されたオブジェクト ID のオブジェクト スキーマ名を返します。 したがって、正しくない情報が返されます。

USE AdventureWorks2012;
GO
SELECT DISTINCT OBJECT_SCHEMA_NAME(object_id)
FROM master.sys.objects;
GO

次の例では、OBJECT_SCHEMA_NAME 関数で master データベースのデータベース ID を指定し、正確な結果を返します。

USE AdventureWorks2012;
GO
SELECT DISTINCT OBJECT_SCHEMA_NAME(object_id, 1) AS schema_name
FROM master.sys.objects;
GO

使用例

A. オブジェクト スキーマ名とオブジェクト名を取得する

この例では、アドホック ステートメントでも準備されたステートメントでもない、キャッシュされたすべてのクエリ プランについて、オブジェクト スキーマ名、オブジェクト名、SQL テキストを返します。

SELECT DB_NAME(st.dbid) AS database_name, 
    OBJECT_SCHEMA_NAME(st.objectid, st.dbid) AS schema_name,
    OBJECT_NAME(st.objectid, st.dbid) AS object_name, 
    st.text AS query_statement
FROM sys.dm_exec_query_stats AS qs
CROSS APPLY sys.dm_exec_sql_text(qs.sql_handle) AS st
WHERE st.objectid IS NOT NULL;
GO

B. 3 つの要素で構成されたオブジェクト名を取得する

この例では、データベース名、スキーマ名、およびオブジェクト名と共に、すべてのデータベースのすべてのオブジェクトの統計を示す sys.dm_db_index_operational_stats 動的管理ビューの残りのすべての列を返します。

SELECT QUOTENAME(DB_NAME(database_id)) 
    + N'.' 
    + QUOTENAME(OBJECT_SCHEMA_NAME(object_id, database_id)) 
    + N'.' 
    + QUOTENAME(OBJECT_NAME(object_id, database_id))
    , * 
FROM sys.dm_db_index_operational_stats(null, null, null, null);
GO

関連項目

参照

メタデータ関数 (Transact-SQL)

OBJECT_DEFINITION (Transact-SQL)

OBJECT_ID (Transact-SQL)

OBJECT_NAME (Transact-SQL)

概念

セキュリティ保護可能なリソース