Collection<T> Class

Type Parameters

• T
  The type of elements in the collection.

Imports System.Collections.Generic
Imports System.Collections.ObjectModel

Public Class Example

    Public Shared Sub Demo(ByVal outputBlock As System.Windows.Controls.TextBlock)

        Dim dinosaurs As New Collection(Of String)

        dinosaurs.Add("Psitticosaurus")
        dinosaurs.Add("Caudipteryx")
        dinosaurs.Add("Compsognathus")
        dinosaurs.Add("Muttaburrasaurus")

        outputBlock.Text += String.Format("{0} dinosaurs:", dinosaurs.Count) & vbCrLf
        Display(outputBlock, dinosaurs)

        outputBlock.Text &= vbLf & String.Format("IndexOf(""Muttaburrasaurus"") {0}", _
          dinosaurs.IndexOf("Muttaburrasaurus")) & vbCrLf

        outputBlock.Text &= vbLf & String.Format("Contains(""Caudipteryx"") {0}", _
          dinosaurs.Contains("Caudipteryx")) & vbCrLf

        outputBlock.Text += String.Format(vbLf & "Insert(2, ""Nanotyrannus"")") & vbCrLf
        dinosaurs.Insert(2, "Nanotyrannus")
        Display(outputBlock, dinosaurs)

        outputBlock.Text += String.Format(vbLf & "dinosaurs(2): {0}", dinosaurs(2)) & vbCrLf

        outputBlock.Text &= vbLf & "dinosaurs(2) = ""Microraptor""" & vbCrLf
        dinosaurs(2) = "Microraptor"
        Display(outputBlock, dinosaurs)

        outputBlock.Text &= vbLf & "Remove(""Microraptor"")" & vbCrLf
        dinosaurs.Remove("Microraptor")
        Display(outputBlock, dinosaurs)

        outputBlock.Text &= vbLf & "RemoveAt(0)" & vbCrLf
        dinosaurs.RemoveAt(0)
        Display(outputBlock, dinosaurs)

        outputBlock.Text &= vbLf & "dinosaurs.Clear()" & vbCrLf
        dinosaurs.Clear()
        outputBlock.Text += String.Format("Count: {0}", dinosaurs.Count) & vbCrLf

    End Sub

    Private Shared Sub Display(ByVal outputBlock As System.Windows.Controls.TextBlock, ByVal cs As Collection(Of String))
        outputBlock.Text &= vbCrLf
        For Each item As String In cs
            outputBlock.Text &= item & vbCrLf
        Next item
    End Sub
End Class

' This code example produces the following output:
'
'4 dinosaurs:
'
'Psitticosaurus
'Caudipteryx
'Compsognathus
'Muttaburrasaurus
'
'IndexOf("Muttaburrasaurus"): 3
'
'Contains("Caudipteryx"): True
'
'Insert(2, "Nanotyrannus")
'
'Psitticosaurus
'Caudipteryx
'Nanotyrannus
'Compsognathus
'Muttaburrasaurus
'
'dinosaurs(2): Nanotyrannus
'
'dinosaurs(2) = "Microraptor"
'
'Psitticosaurus
'Caudipteryx
'Microraptor
'Compsognathus
'Muttaburrasaurus
'
'Remove("Microraptor")
'
'Psitticosaurus
'Caudipteryx
'Compsognathus
'Muttaburrasaurus
'
'RemoveAt(0)
'
'Caudipteryx
'Compsognathus
'Muttaburrasaurus
'
'dinosaurs.Clear()
'Count: 0

using System;
using System.Collections.Generic;
using System.Collections.ObjectModel;

public class Example
{
   public static void Demo(System.Windows.Controls.TextBlock outputBlock)
   {
      Collection<string> dinosaurs = new Collection<string>();

      dinosaurs.Add("Psitticosaurus");
      dinosaurs.Add("Caudipteryx");
      dinosaurs.Add("Compsognathus");
      dinosaurs.Add("Muttaburrasaurus");

      outputBlock.Text += String.Format("{0} dinosaurs:", dinosaurs.Count) + "\n";
      Display(outputBlock, dinosaurs);

      outputBlock.Text += String.Format("\nIndexOf(\"Muttaburrasaurus\"): {0}",
          dinosaurs.IndexOf("Muttaburrasaurus")) + "\n";

      outputBlock.Text += String.Format("\nContains(\"Caudipteryx\"): {0}",
          dinosaurs.Contains("Caudipteryx")) + "\n";

      outputBlock.Text += String.Format("\nInsert(2, \"Nanotyrannus\")") + "\n";
      dinosaurs.Insert(2, "Nanotyrannus");
      Display(outputBlock, dinosaurs);

      outputBlock.Text += String.Format("\ndinosaurs[2]: {0}", dinosaurs[2]) + "\n";

      outputBlock.Text += "\ndinosaurs[2] = \"Microraptor\"" + "\n";
      dinosaurs[2] = "Microraptor";
      Display(outputBlock, dinosaurs);

      outputBlock.Text += "\nRemove(\"Microraptor\")" + "\n";
      dinosaurs.Remove("Microraptor");
      Display(outputBlock, dinosaurs);

      outputBlock.Text += "\nRemoveAt(0)" + "\n";
      dinosaurs.RemoveAt(0);
      Display(outputBlock, dinosaurs);

      outputBlock.Text += "\ndinosaurs.Clear()" + "\n";
      dinosaurs.Clear();
      outputBlock.Text += String.Format("Count: {0}", dinosaurs.Count) + "\n";
   }

   private static void Display(System.Windows.Controls.TextBlock outputBlock, Collection<string> cs)
   {
      outputBlock.Text += "\n";
      foreach (string item in cs)
      {
         outputBlock.Text += item + "\n";
      }
   }
}

/* This code example produces the following output:

4 dinosaurs:

Psitticosaurus
Caudipteryx
Compsognathus
Muttaburrasaurus

IndexOf("Muttaburrasaurus"): 3

Contains("Caudipteryx"): True

Insert(2, "Nanotyrannus")

Psitticosaurus
Caudipteryx
Nanotyrannus
Compsognathus
Muttaburrasaurus

dinosaurs[2]: Nanotyrannus

dinosaurs[2] = "Microraptor"

Psitticosaurus
Caudipteryx
Microraptor
Compsognathus
Muttaburrasaurus

Remove("Microraptor")

Psitticosaurus
Caudipteryx
Compsognathus
Muttaburrasaurus

RemoveAt(0)

Caudipteryx
Compsognathus
Muttaburrasaurus

dinosaurs.Clear()
Count: 0
 */

Imports System.Collections.Generic
Imports System.Collections.ObjectModel
Imports System.Windows.Controls

Public Class Dinosaurs
    Inherits Collection(Of String)

    Public Event Changed As EventHandler(Of DinosaursChangedEventArgs)

    Protected Overrides Sub InsertItem( _
        ByVal index As Integer, ByVal newItem As String)

        MyBase.InsertItem(index, newItem)

        RaiseEvent Changed(Me, New DinosaursChangedEventArgs( _
            ChangeType.Added, newItem, Nothing))
    End Sub

    Protected Overrides Sub SetItem(ByVal index As Integer, _
        ByVal newItem As String)

        Dim replaced As String = Items(index)
        MyBase.SetItem(index, newItem)

        RaiseEvent Changed(Me, New DinosaursChangedEventArgs( _
            ChangeType.Replaced, replaced, newItem))
    End Sub

    Protected Overrides Sub RemoveItem(ByVal index As Integer)

        Dim removedItem As String = Items(index)
        MyBase.RemoveItem(index)

        RaiseEvent Changed(Me, New DinosaursChangedEventArgs( _
            ChangeType.Removed, removedItem, Nothing))
    End Sub

    Protected Overrides Sub ClearItems()
        MyBase.ClearItems()

        RaiseEvent Changed(Me, New DinosaursChangedEventArgs( _
            ChangeType.Cleared, Nothing, Nothing))
    End Sub

End Class

' Event argument for the Changed event.
'
Public Class DinosaursChangedEventArgs
    Inherits EventArgs

    Public ReadOnly ChangedItem As String
    Public ReadOnly ChangeType As ChangeType
    Public ReadOnly ReplacedWith As String

    Public Sub New(ByVal change As ChangeType, ByVal item As String, _
        ByVal replacement As String)

        ChangeType = change
        ChangedItem = item
        ReplacedWith = replacement
    End Sub
End Class

Public Enum ChangeType
    Added
    Removed
    Replaced
    Cleared
End Enum

Public Class Example

    Private Shared _TextBlock As TextBlock

    Public Shared Sub Demo(ByVal outputBlock As System.Windows.Controls.TextBlock)

        Example._TextBlock = outputBlock

        Dim dinosaurs As New Dinosaurs

        AddHandler dinosaurs.Changed, AddressOf ChangedHandler

        dinosaurs.Add("Psitticosaurus")
        dinosaurs.Add("Caudipteryx")
        dinosaurs.Add("Compsognathus")
        dinosaurs.Add("Muttaburrasaurus")

        Display(outputBlock, dinosaurs)

        outputBlock.Text &= String.Format(vbLf & "IndexOf(""Muttaburrasaurus""): {0}" & vbCrLf, _
            dinosaurs.IndexOf("Muttaburrasaurus"))

        outputBlock.Text &= String.Format(vbLf & "Contains(""Caudipteryx""): {0}" & vbCrLf, _
            dinosaurs.Contains("Caudipteryx"))

        outputBlock.Text &= String.Format(vbLf & "Insert(2, ""Nanotyrannus"")") & vbCrLf
        dinosaurs.Insert(2, "Nanotyrannus")

        outputBlock.Text &= String.Format(vbLf & "dinosaurs(2): {0}" & vbCrLf, dinosaurs(2))

        outputBlock.Text &= vbLf & "dinosaurs(2) = ""Microraptor""" & vbCrLf
        dinosaurs(2) = "Microraptor"

        outputBlock.Text &= vbLf & "Remove(""Microraptor"")" & vbCrLf
        dinosaurs.Remove("Microraptor")

        outputBlock.Text &= vbLf & "RemoveAt(0)" & vbCrLf
        dinosaurs.RemoveAt(0)

        Display(outputBlock, dinosaurs)

    End Sub

    Private Shared Sub Display(ByVal outputBlock As System.Windows.Controls.TextBlock, ByVal cs As Collection(Of String))
        _TextBlock.Text &= vbCrLf
        For Each item As String In cs
            _TextBlock.Text &= item & vbCrLf
        Next item
    End Sub

    Private Shared Sub ChangedHandler(ByVal source As Object, _
        ByVal e As DinosaursChangedEventArgs)

        If e.ChangeType = ChangeType.Replaced Then
            _TextBlock.Text &= String.Format("{0} was replaced with {1}", _
                e.ChangedItem, e.ReplacedWith) & vbCrLf

        ElseIf e.ChangeType = ChangeType.Cleared Then
            _TextBlock.Text &= "The dinosaur list was cleared." & vbCrLf

        Else
            _TextBlock.Text &= String.Format("{0} was {1}.", _
                e.ChangedItem, e.ChangeType) & vbCrLf
        End If
    End Sub

End Class
' This code example produces the following output:
'
'Psitticosaurus was Added.
'Caudipteryx was Added.
'Compsognathus was Added.
'Muttaburrasaurus was Added.
'
'Psitticosaurus
'Caudipteryx
'Compsognathus
'Muttaburrasaurus
'
'IndexOf("Muttaburrasaurus"): 3
'
'Contains("Caudipteryx"): True
'
'Insert(2, "Nanotyrannus")
'Nanotyrannus was Added.
'
'dinosaurs(2): Nanotyrannus
'
'dinosaurs(2) = "Microraptor"
'Nanotyrannus was replaced with Microraptor
'
'Remove("Microraptor")
'Microraptor was Removed.
'
'RemoveAt(0)
'Psitticosaurus was Removed.
'
'Caudipteryx
'Compsognathus
'Muttaburrasaurus

using System;
using System.Collections.Generic;
using System.Collections.ObjectModel;
using System.Windows.Controls;

public class Dinosaurs : Collection<string>
{
    public event EventHandler<DinosaursChangedEventArgs> Changed;


    protected override void InsertItem(int index, string newItem)
    {
        base.InsertItem(index, newItem);

        EventHandler<DinosaursChangedEventArgs> temp = Changed;
        if (temp != null)
        {
            temp(this, new DinosaursChangedEventArgs(
                ChangeType.Added, newItem, null));
        }
    }

    protected override void SetItem(int index, string newItem)
    {
        string replaced = Items[index];
        base.SetItem(index, newItem);

        EventHandler<DinosaursChangedEventArgs> temp = Changed;
        if (temp != null)
        {
            temp(this, new DinosaursChangedEventArgs(
                ChangeType.Replaced, replaced, newItem));
        }
    }

    protected override void RemoveItem(int index)
    {
        string removedItem = Items[index];
        base.RemoveItem(index);

        EventHandler<DinosaursChangedEventArgs> temp = Changed;
        if (temp != null)
        {
            temp(this, new DinosaursChangedEventArgs(
                ChangeType.Removed, removedItem, null));
        }
    }

    protected override void ClearItems()
    {
        base.ClearItems();

        EventHandler<DinosaursChangedEventArgs> temp = Changed;
        if (temp != null)
        {
            temp(this, new DinosaursChangedEventArgs(
                ChangeType.Cleared, null, null));
        }
    }
}

// Event argument for the Changed event.
//
public class DinosaursChangedEventArgs : EventArgs
{
    public readonly string ChangedItem;
    public readonly ChangeType ChangeType;
    public readonly string ReplacedWith;

    public DinosaursChangedEventArgs(ChangeType change, string item,
        string replacement)
    {
        ChangeType = change;
        ChangedItem = item;
        ReplacedWith = replacement;
    }
}

public enum ChangeType
{
    Added,
    Removed,
    Replaced,
    Cleared
};

public class Example
{

    private static TextBlock _textblock;


    public static void Demo(TextBlock outputBlock)
    {

        Example._textblock = outputBlock;

        Dinosaurs dinosaurs = new Dinosaurs();

        dinosaurs.Changed += ChangedHandler;

        dinosaurs.Add("Psitticosaurus");
        dinosaurs.Add("Caudipteryx");
        dinosaurs.Add("Compsognathus");
        dinosaurs.Add("Muttaburrasaurus");

        Display(dinosaurs);

        outputBlock.Text += String.Format("\nIndexOf(\"Muttaburrasaurus\"): {0}\n",
            dinosaurs.IndexOf("Muttaburrasaurus"));

        outputBlock.Text += String.Format("\nContains(\"Caudipteryx\"): {0}\n",
            dinosaurs.Contains("Caudipteryx"));

        outputBlock.Text += String.Format("\nInsert(2, \"Nanotyrannus\")\n");
        dinosaurs.Insert(2, "Nanotyrannus");

        outputBlock.Text += String.Format("\ndinosaurs[2]: {0}\n", dinosaurs[2]);

        outputBlock.Text += "\ndinosaurs[2] = \"Microraptor\"" + "\n";
        dinosaurs[2] = "Microraptor";

        outputBlock.Text += "\nRemove(\"Microraptor\")\n";
        dinosaurs.Remove("Microraptor");

        outputBlock.Text += "\nRemoveAt(0)\n";
        dinosaurs.RemoveAt(0);

        Display(dinosaurs);
    }

    private static void Display(Collection<string> cs)
    {
        _textblock.Text += "\n";
        foreach (string item in cs)
        {
            _textblock.Text += item + "\n";
        }
    }

    private static void ChangedHandler(object source,
        DinosaursChangedEventArgs e)
    {

        if (e.ChangeType == ChangeType.Replaced)
        {
            _textblock.Text += String.Format("{0} was replaced with {1}\n", e.ChangedItem,
                e.ReplacedWith);
        }
        else if (e.ChangeType == ChangeType.Cleared)
        {
            _textblock.Text += "The dinosaur list was cleared." + "\n";
        }
        else
        {
            _textblock.Text += String.Format("{0} was {1}.\n", e.ChangedItem, e.ChangeType);
        }
    }
}


/* This code example produces the following output:

Psitticosaurus was Added.
Caudipteryx was Added.
Compsognathus was Added.
Muttaburrasaurus was Added.

Psitticosaurus
Caudipteryx
Compsognathus
Muttaburrasaurus

IndexOf("Muttaburrasaurus"): 3

Contains("Caudipteryx"): True

Insert(2, "Nanotyrannus")
Nanotyrannus was Added.

dinosaurs[2]: Nanotyrannus

dinosaurs[2] = "Microraptor"
Nanotyrannus was replaced with Microraptor

Remove("Microraptor")
Microraptor was Removed.

RemoveAt(0)
Psitticosaurus was Removed.

Caudipteryx
Compsognathus
Muttaburrasaurus
 */