backupmediaset (Transact-SQL)

  • [アーティクル]

適用対象: SQL Server Azure SQL Managed Instance

バックアップ メディア セットごとに 1 行のデータを格納します。 このテーブルは msdb データベースに格納されます。

列名 データ型 説明
media_set_id int 一意のメディア セット ID 番号。 ID、主キー。
media_uuid uniqueidentifier メディア セットの UUID。 すべての Microsoft SQL Server メディア セットには UUID があります。

ただし、以前のバージョンの SQL Server では、メディア セットにメディア ファミリが 1 つだけ含まれている場合、 media_uuid 列は NULL (media_family_count は 1) である可能性があります。
media_family_count tinyint メディア セット内のメディア ファミリの数。 NULL にすることができます。
name nvarchar(128) メディア セットの名前。 NULL にすることができます。

詳細については、「 BACKUP (Transact-SQL)の MEDIANAME と MEDIADESCRIPTION」を参照してください。
説明 nvarchar (255) メディア セットの説明。 NULL にすることができます。

詳細については、「 BACKUP (Transact-SQL)の MEDIANAME と MEDIADESCRIPTION」を参照してください。
software_name nvarchar(128) メディア ラベルを書き込んだバックアップ ソフトウェアの名前。 NULL にすることができます。
software_vendor_id int バックアップ メディア ラベルを記述したソフトウェア ベンダーの識別番号。 NULL にすることができます。

Microsoft SQL Server の値は 16 進数の0x1200です。
MTF_major_version tinyint このメディア セットの生成に使用される Microsoft Tape Format のメジャー バージョン番号。 NULL にすることができます。
mirror_count tinyint メディア セット内のミラーの数。
is_password_protected bit メディア セットのパスワードは保護されていますか。

0 = 保護されていません

1 = 保護されています
is_compressed bit バックアップが圧縮されているかどうか。

0 = 圧縮されていません

1 = 圧縮

msdb のアップグレードの間、この値は NULL に設定されます。 これは圧縮されていないバックアップを示します。
is_encrypted Bit バックアップが暗号化されているかどうか。

0 = 暗号化なし

1 = 暗号化

解説

RESTORE VERIFYONLY FROM backup_device WITH LOADHISTORY は、 backupmediaset テーブルの列に、メディア セット ヘッダーの適切な値を設定します。

このテーブルおよび他のバックアップ テーブルと履歴テーブルの行数を減らすには、sp_delete_backuphistory ストアド プロシージャを実行します。

例

バックアップ履歴のクエリを実行する

次のクエリは、過去 2 か月間の正常なバックアップ情報を返します。

SELECT bs.database_name,
	backuptype = CASE
			WHEN bs.type = 'D'
			AND bs.is_copy_only = 0 THEN 'Full Database'
			WHEN bs.type = 'D'
			AND bs.is_copy_only = 1 THEN 'Full Copy-Only Database'
			WHEN bs.type = 'I' THEN 'Differential database backup'
			WHEN bs.type = 'L' THEN 'Transaction Log'
			WHEN bs.type = 'F' THEN 'File or filegroup'
			WHEN bs.type = 'G' THEN 'Differential file'
			WHEN bs.type = 'P' THEN 'Partial'
			WHEN bs.type = 'Q' THEN 'Differential partial'
		END + ' Backup',
	CASE bf.device_type
			WHEN 2 THEN 'Disk'
			WHEN 5 THEN 'Tape'
			WHEN 7 THEN 'Virtual device'
			WHEN 9 THEN 'Azure Storage'
			WHEN 105 THEN 'A permanent backup device'
			ELSE 'Other Device'
		END AS DeviceType,
	bms.software_name AS backup_software,
	bs.recovery_model,
	bs.compatibility_level,
	BackupStartDate = bs.Backup_Start_Date,
	BackupFinishDate = bs.Backup_Finish_Date,
	LatestBackupLocation = bf.physical_device_name,
	backup_size_mb = CONVERT(decimal(10, 2), bs.backup_size/1024./1024.),
	compressed_backup_size_mb = CONVERT(decimal(10, 2), bs.compressed_backup_size/1024./1024.),
	database_backup_lsn, -- For tlog and differential backups, this is the checkpoint_lsn of the FULL backup it is based on.
	checkpoint_lsn,
	begins_log_chain,
	bms.is_password_protected
FROM msdb.dbo.backupset bs
LEFT OUTER JOIN msdb.dbo.backupmediafamily bf ON bs.[media_set_id] = bf.[media_set_id]
INNER JOIN msdb.dbo.backupmediaset bms ON bs.[media_set_id] = bms.[media_set_id]
WHERE bs.backup_start_date > DATEADD(MONTH, -2, sysdatetime()) --only look at last two months
ORDER BY bs.database_name ASC, bs.Backup_Start_Date DESC;

参照

テーブルのバックアップと復元 (Transact-SQL)
backupfile (Transact-SQL)
backupfilegroup (Transact-SQL)
backupmediafamily (Transact-SQL)
backupset (Transact-SQL)
システム テーブル (Transact-SQL)