Session.Put メソッド

リソースを更新します。

構文

Session.Put( _
  ByVal resourceUri, _
  ByVal resource, _
  [ ByVal flags ] _
)

パラメーター

resourceUri [in]

更新するリソースの識別子。

このパラメーターには、次の一覧に含まれる要素のいずれかを含めることができます。

• セレクターの有無にかかわらず URI。 Put メソッドを呼び出して WMI リソースを取得する場合は、オブジェクトのキー プロパティまたはプロパティを使用します。 たとえば、次の Visual Basic Scripting Edition (VBScript) コード例では、 で Win32_Service?Name=winmgmtキーが指定されています。

  strResourceUri = "http://schemas.microsoft.com/" & _ 
    "wbem/wsman/1/wmi/root/cimv2/Win32_Service?Name=winmgmt"
  

• セレクター、フラグメント、またはオプションを含む ResourceLocator オブジェクト。

• WS-Management Protocol 標準で説明されているように、 WS-Addressing エンドポイントリファレンス。 WS-Management プロトコルのパブリック仕様の詳細については、「 管理仕様のインデックス ページ」を参照してください。

resource [in]

更新されたリソースコンテンツ。

flags [in, optional]

予約済み。 0 に設定する必要があります。

戻り値

更新されたリソース コンテンツを含む XML。

例

次の VBScript コード例では、 Win32_WMISetting オブジェクトにデータを書き込みます。 Resource パラメーターの XML には、オブジェクトのすべての配列以外のプロパティを含める必要があります。 プロパティの順序は重要ではありません。

'Create a WSMan object.
Set objWsman = CreateObject( "WSMAN.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

'Create a Session object.
Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

'Change the property value by putting
'the new XML content into the resource.
Dim strResourceUri, strReturnedResourceUri, newXmlContent
strResourceUri = "http://schemas.microsoft.com/wbem/wsman/1/" _
  & "wmi/root/cimv2/Win32_WMISetting"
newXmlContent = _
  "<p:Win32_WMISetting xmlns:p=""http://schemas.microsoft.com/" & _
  "wbem/wsman/1/wmi/root/cimv2/Win32_WMISetting"">" & _
  "<p:LoggingLevel>2</p:LoggingLevel></p:Win32_WMISetting>" 

On Error Resume Next
strReturnedResourceUri = objSession.Put(reourceUri, newXmlContent)
WScript.Echo "Returned resource Uri:" & Chr(10) & _
  strReturnedResourceUri
If Err.Number <> 0 Then
    DisplayErrorInfo
End If
On Error Goto 0

Sub DisplayErrorInfo()
    WScript.Echo "An error has occurred."     
    WScript.Echo
    WScript.Echo "Error Info"
    WScript.Echo "-----------"
    WScript.Echo "Number      : 0x" & hex(Err.number)
    WScript.Echo "Description : " & Err.Description
    WScript.Echo "Source      : " & Err.Source
    WScript.Echo "HelpFile    : " & Err.helpfile
    WScript.Echo "HelpContext : " & Err.HelpContext    
    WScript.Echo Err.Clear    
End Sub

要件

こちらもご覧ください

Session